Using nested BEGIN..END Block....

Question

Hi,
I am unable to use nested BEGIN..ENF Block.See error defined below
BEGIN
        BEGIN
                SELECT xcod_code INTO v_cmpy_xcod_code
                FROM   ext_code_type
                WHERE  xcod_code = sdiStruct.cmpy_xcod_code
                AND    inst_borg_ind = 'B';
        EXCEPTION WHEN NO_DATA_FOUND
        THEN
             erm := 'CMPY XCOD CODE not found with indicator of B';
             RAISE err;
        END;
        BEGIN
                SELECT  borg_num,borg_code INTO v_borg_num,v_borg_code
                FROM    borg_code
                WHERE   borg_code  = sdiStruct.cmpy_id
                AND     xcod_code  = sdiStruct.cmpy_xcod_code;
        EXCEPTION WHEN NO_DATA_FOUND
        THEN
                erm:= 'No borg num or borg code found for CMPY ID and CMPY XCODE CODE entered.';
                RAISE err;
        END;
     EXCEPTION
     WHEN err THEN
     RAISE_APPLICATION_ERROR(-20001,erm);
END;The ERROR I get is this
LINE/COL ERROR
113/3    PLS-00103: Encountered the symbol "RAISE" when expecting one of
         the following:
         . ( * @ % & = - + ; < / > at in is mod not rem
         <an exponent (**)> <> or != or ~= >= <= <> and or like
         between ||If I remove the 2nd nested BEGIN..END BLOCK,It works fine.
Cant I write multiple BEGIN..END BLOCK??

Answer 1

The error that you are receiving indicates that it happened on line 113 of your code, so you have obviously left out a whole lot. The portion of the code that you posted works fine, as long as you have all of the correspoinding pieces. I don't know if sdistruct is a package or a row of a cursor or what and I don't know your table structure, so I have just made something up, in order to demonstrate below. In the future, it helps if you include things like complete code and table structure and Oracle version.
scott@ORA92> CREATE TABLE ext_code_type
  2    (xcod_code     NUMBER,
  3       inst_borg_ind VARCHAR2(1))
  4  /
Table created.
scott@ORA92> CREATE TABLE borg_code
  2    (borg_num      NUMBER,
  3       borg_code     NUMBER,
  4       xcod_code     NUMBER)
  5  /
Table created.
scott@ORA92> CREATE OR REPLACE PACKAGE sdiStruct
  2  AS
  3    cmpy_xcod_code NUMBER := 1;
  4    cmpy_id           NUMBER := 1;
  5  END;
  6  /
Package created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> CREATE OR REPLACE PROCEDURE your_proc
  2  AS
  3    v_cmpy_xcod_code ext_code_type.xcod_code%TYPE;
  4    v_borg_num     borg_code.borg_num%TYPE;
  5    v_borg_code     borg_code.borg_code%TYPE;
  6    erm          VARCHAR2(80);
  7    err          EXCEPTION;
  8  BEGIN
  9    BEGIN
10        SELECT xcod_code
11        INTO     v_cmpy_xcod_code
12        FROM     ext_code_type
13        WHERE     xcod_code = sdiStruct.cmpy_xcod_code
14        AND     inst_borg_ind = 'B';
15    EXCEPTION
16        WHEN NO_DATA_FOUND THEN
17          erm := 'CMPY XCOD CODE not found with indicator of B';
18          RAISE err;
19    END;
20    --
21    BEGIN
22        SELECT  borg_num,borg_code
23        INTO      v_borg_num,v_borg_code
24        FROM      borg_code
25        WHERE      borg_code  = sdiStruct.cmpy_id
26        AND      xcod_code  = sdiStruct.cmpy_xcod_code;
27    EXCEPTION
28        WHEN NO_DATA_FOUND THEN
29          erm:= 'No borg num or borg code found for CMPY ID and CMPY XCODE CODE entered.';
30          RAISE err;
31    END;
32  EXCEPTION
33    WHEN err THEN
34        RAISE_APPLICATION_ERROR(-20001, erm);
35  END your_proc;
36  /
Procedure created.
scott@ORA92> SHOW ERRORS
No errors.
scott@ORA92> EXECUTE your_proc
BEGIN your_proc; END;
ERROR at line 1:
ORA-20001: CMPY XCOD CODE not found with indicator of B
ORA-06512: at "SCOTT.YOUR_PROC", line 34
ORA-06512: at line 1
scott@ORA92> INSERT INTO ext_code_type VALUES (1, 'B')
  2  /
1 row created.
scott@ORA92> EXECUTE your_proc
BEGIN your_proc; END;
ERROR at line 1:
ORA-20001: No borg num or borg code found for CMPY ID and CMPY XCODE CODE entered.
ORA-06512: at "SCOTT.YOUR_PROC", line 34
ORA-06512: at line 1
scott@ORA92> INSERT INTO borg_code VALUES (1, 1, 1)
  2  /
1 row created.
scott@ORA92> EXECUTE your_proc
PL/SQL procedure successfully completed.