What are the function modules used in CRM_ORDER_STATUS

Question

Hi,
what are the function modules used in CRM_ORDER_STATUS(BADI) IN THIS METHOD AFTER_CHANGE...

Answer 1

Hi,
http://scn.sap.com/thread/3202739
AFTER_CHANGE
ABAP ABAP Code
Follow-Up Action After Status Change
BEFORE_CHANGE
ABAP ABAP Code
Checks for Status Changeability
Sample code to set date on status change ------
INCLUDE crm_direct.
   DATA : ls_status       TYPE crmt_status_wrk.
   DATA : lv_process_type TYPE crmt_process_type.
   DATA : lit_appointment TYPE crmt_appointment_wrkt.
   DATA : wa_appointment  TYPE crmt_appointment_wrk.
   DATA : ls_appoint      TYPE crmt_appointment_com.
   DATA : lt_appoint      TYPE  crmt_appointment_comt.
   DATA : ls_input_field  TYPE crmt_input_field.
   DATA : lt_input_field  TYPE crmt_input_field_tab.
   DATA : ls_fieldnames   TYPE crmt_input_field_names.
   DATA : lt_fieldnames   TYPE crmt_input_field_names_tab.
   DATA : lt_exception    TYPE crmt_exception_t.
   DATA : lv_timestamp    TYPE sc_tstfro.
   DATA : lt_header_guid  TYPE crmt_object_guid_tab.
   DATA : lt_req_objects  TYPE crmt_object_name_tab.
   ls_status = is_status_wrk.
*Get process type
   CALL FUNCTION 'CRM_INTLAY_GET_PROCESS_TYPE'
     EXPORTING
       iv_orderadm_h_guid = ls_status-guid
     IMPORTING
       ev_process_type    = lv_process_type.
* Check process type
   IF lv_process_type = 'ZZZ'.
     INSERT ls_status-guid INTO TABLE lt_header_guid.
     INSERT gc_object_name-appointment INTO TABLE lt_req_objects.
**Get appoinment data
     CALL FUNCTION 'CRM_ORDER_READ'
       EXPORTING
         it_header_guid            = lt_header_guid
         iv_mode                     = gc_mode-display
         it_requested_objects   = lt_req_objects
       IMPORTING
         et_appointment       = lit_appointment
       EXCEPTIONS
         document_not_found   = 1
         error_occurred       = 2
         document_locked      = 3
         no_change_authority  = 4
         no_display_authority = 5
         no_change_allowed    = 6
         OTHERS               = 7.
     IF sy-subrc NE 0.
       EXIT.
     ENDIF.
*read item level data
     READ TABLE lit_appointment INTO wa_appointment WITH KEY ref_kind = 'B'.
     IF sy-subrc = 0.
*      *Time-stamp set to as per current date and time.
       CONVERT DATE sy-datum TIME sy-uzeit INTO TIME STAMP lv_timestamp
         TIME ZONE sy-zonlo.
*Fill appoinment structure
       ls_appoint-ref_guid = wa_appointment-ref_guid."appoinment gid
       ls_appoint-ref_kind = 'B'."Item
       ls_appoint-ref_handle  = '0000000000'.
       ls_appoint-appt_type = 'ZSERV_CLOSE'."c_appt_type .
       ls_appoint-timestamp_from = lv_timestamp.
       ls_appoint-timezone_from   = 'GMTUK'."time zone
       ls_appoint-mode = ''.
       ls_appoint-rule_name   = 'TODAY'.
       INSERT ls_appoint INTO TABLE lt_appoint.
       ls_input_field-ref_guid = wa_appointment-ref_guid.
       ls_input_field-ref_kind = 'B'.
       ls_input_field-objectname = 'APPOINTMENT'.
       ls_input_field-logical_key = 'ZSTATUS_NEW'.
*Fill input fields
       ls_fieldnames-fieldname = 'TIMESTAMP_FROM'.
       INSERT ls_fieldnames INTO TABLE ls_input_field-field_names.
       INSERT ls_input_field INTO TABLE lt_input_field.
       CLEAR lt_fieldnames[].CLEAR ls_fieldnames. CLEAR ls_input_field.
*To update date
       CALL FUNCTION 'CRM_APPT_MAINTAIN_MULTI_OW'
         EXPORTING
           iv_ref_guid        = wa_appointment-ref_guid
           iv_ref_kind        = 'B'
           it_appointment_com = lt_appoint
         CHANGING
           ct_input_fields    = lt_input_field
         EXCEPTIONS
           OTHERS             = 1.
     ENDIF.
   ENDIF.
Standard BADI Order_Save will take care to save into database.
Regards,
Sumeet