XML escape sequences for brackets and xmltype.extract

Question

G'day gang, I'm hoping somebody would be kind enough to help me with the following query please.
I have a web service that is returning the following XML stream into an XMLType in the database:
<OutOfStockAdviceResponse xmlns="http://abc.org/abcWebServices">
  <OutOfStockAdviceResult>
  & lt;Response& lt;ResponseCode& gt;0& lt;/ResponseCode& gt;
  & lt;ResponseMessage& gt;Successful& lt;/ResponseMessage& gt;
  & lt;/Response& gt;
  </OutOfStockAdviceResult>
</OutOfStockAdviceeResponse>You'll note the & lt; and & gt; characters (note to display these strings in OTN I've had to add a space between the & and the lt; or gt;. The spaces don't actually occur in the real XML data coming back).
What's odd about this XML stream coming back is it is mixing the use of the XML angle brackets with the escape character equivalents (eg. & lt; and & gt;) half way through the XML stream. Is this valid for an XML stream to do this? Any idea what would cause this? Is it possible the source is creating 2 separate XML streams using different character sets and then concatenating them to get this result?
The reason I'm asking is I'm attempting via PL/SQL to extract the ResponseCode and ResponseMessage tags with the following code:
  v_response_code := XMLType.extract(v_response,
      '/OutOfStockAdviceResponse/OutOfStockAdviceResult/Response/ResponseCode/text()',
      'xmlns="http://abc.org/abcWebServices"').getnumberval;
  v_response_msg  := XMLType.extract(v_response,
      '/OutOfStockAdviceResponse/OutOfStockAdviceResult/Response/ResponseMessage/text()',
      'xmlns="http://abc.org/abcWebServices"').getstringval;Both calls are failing with:
ORA-30625: method dispatch on NULL SELF argument is disallowedCan anybody point me in the right direction for solving this issue? Is there a way to get the xmltype.extract function to recognize the different character encoding schemes (if they do indeed actually exist)?
Any help appreciated.
CM.
PS. Apologize for the weak subject line.

Answer 1

Chris
Since that Serviceis actually returning the escaped representation of '<' and '>' inside OutOfStocAdviceResult, the XML Parser considers that whole block of text to be simply a text node child the parent element, not valid XML. Hence the result of your XPath expressions is null and you get the ORA-30625 when you try to invoke the getNumberVal() and getStringVal() methods, which is the PL/SQL equivilant of a Java Null Pointer Exception.
You can solve it as follows...
set define off
set serveroutput on
declare
  v_response xmltype;
  v_response_code number(4);
  v_response_msg varchar2(64);
  v_xmltext varchar2(256);
  v_OutOfStockResponse xmltype := xmltype(
'<OutOfStockAdviceResponse xmlns="http://abc.org/abcWebServices"> 
  <OutOfStockAdviceResult>
    & lt;Response& gt;& lt;ResponseCode& gt;0& lt;/ResponseCode& gt;& lt;ResponseMessage& gt;Successful& lt;/ResponseMessage& gt;& lt;/Response& gt; 
  </OutOfStockAdviceResult>
</OutOfStockAdviceResponse>');
begin
  select extractValue(v_OutOfStockResponse,'/OutOfStockAdviceResponse/OutOfStockAdviceResult','xmlns="http://abc.org/abcWebServices"')
    into v_xmltext
    from dual;
   dbms_output.put_line('Text = ' || v_xmlText);
   v_response := xmltype(v_xmltext);
   v_response_code := v_response.extract('/Response/ResponseCode/text()').getnumberval();
   v_response_msg  := v_response.extract('/Response/ResponseMessage/text()').getstringval();
   dbms_output.put_line('Code = ' || v_response_code);
   dbms_output.put_line('Msg = ' || v_response_msg);
end;Note that like you I had to insert space characters between in the 'lt' and 'gt' escape sequences...
When this is run you get the following
SQL> set define off
SQL> set serveroutput on
SQL> --
SQL> declare
  2    v_response xmltype;
  3    v_response_code number(4);
  4    v_response_msg varchar2(64);
  5    v_xmltext varchar2(256);
  6    v_OutOfStockResponse xmltype := xmltype(
  7  '<OutOfStockAdviceResponse xmlns="http://abc.org/abcWebServices">
  8    <OutOfStockAdviceResult>
  9      & lt;Response& gt;& lt;ResponseCode& gt;0& lt;/ResponseCode& gt;& lt;ResponseMessage& gt;Successful& lt;/ResponseMessage& gt;& lt;/Response& gt;
10    </OutOfStockAdviceResult>
11  </OutOfStockAdviceResponse>');
12  begin
13    select extractValue(v_OutOfStockResponse,'/OutOfStockAdviceResponse/OutOfStockAdviceResult','xmlns="http://abc.org/abcWebServices"')
14      into v_xmltext
15      from dual;
16     dbms_output.put_line('Text = ' || v_xmlText);
17     v_response := xmltype(v_xmltext);
18     v_response_code := v_response.extract('/Response/ResponseCode/text()').getnumberval();
19     v_response_msg  := v_response.extract('/Response/ResponseMessage/text()').getstringval();
20     dbms_output.put_line('Code = ' || v_response_code);
21     dbms_output.put_line('Msg = ' || v_response_msg);
22  end;
23  /
Text =
<Response><ResponseCode>0</ResponseCode><ResponseMessage>Successful</ResponseMes
sage></Response>
Code = 0
Msg = Successful
PL/SQL procedure successfully completed.
SQL>Basically we extract the encoded text using extractValue() which will de-escape the escapted characters and then create a new XMLType which we can operate on