Script to import contacts from CSV file into Address Book

Question

Hi,
I am wondering if it would be possible to import contacts from a CSV file into a group in Address Book using applescript, and if so, if anyone is aware of a script that does this or something similar.
I have a CSV file with three columns 'First Name', 'Last Name' and 'Email Address'.  I would like these to correspond with  'First', 'Last' and (Work) 'Email' in Address Book.
Ideally the script would also check to see if entries already exist for the people being imported, but this is less crucial.
Thanks in advance for any assistance,
Nick

Answer 1

Hi,
Test this on a very small csv file (four or five contacts) to see if it works for you. It will not de-duplicate. You don't give the name of the group, so you'll need to replace Name of group in the second line with your group name, enclosed in double quotes.
--begin script
set the_people to read (choose file with prompt "Choose your CSV file")
set the_group to "Name of group"
set old_tids to AppleScript's text item delimiters
set AppleScript's text item delimiters to ","
set par_count to (count paragraphs in the_people)
repeat with x from 1 to par_count
          set next_par to paragraph x of the_people
          set first_name to text item 1 of next_par
          set last_name to text item 2 of next_par
          set e_mail to text item 3 of next_par
          tell application "Address Book"
                    set nu_person to make new person with properties {first name:first_name, last name:last_name}
  make new email at end of emails of nu_person with properties {label:"Work", value:e_mail}
                    add nu_person to group the_group
  save
          end tell
end repeat
set AppleScript's text item delimiters to old_tids
--end script
Watch out for bad line breaks in the lines beginning "set nu_person..." and "make new email..."