Add Image in ABAP Report

Question

Hi All,
I want add image in ABAP Report.
Please let me know how it can be done?
Regards,
Jagdish More

Answer 1

Hi Jagdish,
to upload the image follow these steps.
1. Upload image in web repository.
Go to Transaction SMW0 to upload the image in SAP web Repository. elect second radiobutton u201DBinary data for WebRFC applicationsu201D and click on find.
2.     Click on Execute.
3.     Click on Create and give the obj.name and description and click on import.
once the image gets uploaded.in your program do the following
1.     Create a Screen.Go to Layout and create Custom Control.I have named it as u2018CONTAINERu2019.
2.     Declare container(Custom Control name),picture(child of Container) and url in Top of the program.
data container type ref to cl_gui_custom_container.
data picture type ref to cl_gui_picture.
data url(256).
3.     Now create the object Container and Picture.
create object container
       exporting container_name = 'CONTAINER'.//name of the custom control
    create object picture
       exporting  parent = container
       exceptions error = 1.
4.     Now we have to load the picture from the database which we have uploaded. For this we need to declare the following:-
  data query_table like w3query occurs 1 with header line.
  data html_table like w3html occurs 1.
  data return_code like  w3param-ret_code.
  data content_type like  w3param-cont_type.
  data content_length like  w3param-cont_len.
  data pic_data like w3mime occurs 0.
  data pic_size type i.
5.     Refresh the Query table and give the name of Query table as u2018_OBJECT_ID_u2019 and value as the name of logo/Image which u have uploaded.Append the value in the Query Table.
  refresh query_table.
  query_table-name = '_OBJECT_ID'.
  query_table-value = 'ZLOGO.GIF'."name of logo
  append query_table.
6.     Now call the function WWW_GET_MIME_OBJECT to get the logo/image which u have uploaded and call the function DP_CREATE_URL to create the url where the image is present.
call function 'WWW_GET_MIME_OBJECT'
    tables
      query_string        = query_table
      html                = html_table
      mime                = pic_data
    changing
      return_code         = return_code
      content_type        = content_type
      content_length      = content_length
    exceptions
      object_not_found    = 1
      parameter_not_found = 2
      others              = 3.
  if sy-subrc = 0.
    pic_size = content_length.
  endif.
  call function 'DP_CREATE_URL'
    exporting
      type     = 'image'
      subtype  = cndp_sap_tab_unknown
      size     = pic_size
      lifetime = cndp_lifetime_transaction
    tables
      data     = pic_data
    changing
      url      = url
    exceptions
      others   = 1.
7.     Finally we have to upload the image from the URL, this can be done by calling the method: picture->load_picture_from_url
call method picture->load_picture_from_url
exporting
url = url.
Now Save,Activate and Execute the Program , Image/Logo got successfully uploaded.
I have already done this program and uploaded the image...
this will surely help you
Thanks and regards,
Tanmaya