Adding new search field in IC web client

Question

Hi experts,
I need to add two search fields search term1 and search term2 in IC web client for the view 'search for Employees'  as that is present in GUI with transaction BP.Please send me step by step details how to do that.
Thanks in advance
Koustav

Answer 1

Hi Koustav,
If you have added an append to the BuilEmpSearch BOL object, than the parameters are added to the query_service automaticaly.
Here is an example of the eh_OnSearch method for the search on business partners. (B2C scenario). The principle is the same. You can add you pre-search checks here. Don't fire the query before all required data is in the query_search object. (standard all parameters from the BuilEmpSearch object are in there).
METHOD eh_onsearch .
* 2. Business Partner Search
    lv_wrapper = typed_context->SearchCustomer->get_collection_wrapper( ).
    query_service ?= lv_wrapper->get_current( ).
    lv_country =
          query_service->IF_BOL_BO_PROPERTY_ACCESS~GET_PROPERTY_AS_STRING( 'COUNTRY' ).
    IF NOT lv_country IS INITIAL.
      CALL METHOD query_service->if_bol_bo_property_access~set_property
        EXPORTING
          iv_attr_name = 'COUNTRY_FOR_TEL'
          iv_value     = lv_country.
    ENDIF.
* MVNI(EX00885)21022006: Begin of Insert
    lv_firstname =
          query_service->IF_BOL_BO_PROPERTY_ACCESS~GET_PROPERTY_AS_STRING( 'MC_NAME2' ).
    lv_lastname =
          query_service->IF_BOL_BO_PROPERTY_ACCESS~GET_PROPERTY_AS_STRING( 'MC_NAME1' ).
    lv_insz =
          query_service->IF_BOL_BO_PROPERTY_ACCESS~GET_PROPERTY_AS_STRING( 'ZZINSZ' ).
    lv_birthdate =
          query_service->IF_BOL_BO_PROPERTY_ACCESS~GET_PROPERTY_AS_STRING( 'ZBIRTHDATE' ).
    replace all occurrences of '.' in lv_insz with ''.
    replace all occurrences of '-' in lv_insz with ''.
    condense lv_insz no-gaps.
* MVNI(EX00885)21022006: End of Insert
*     check customizing for role
      IF NOT ls_profile-customer_role IS INITIAL.
        CALL METHOD query_service->if_bol_bo_property_access~set_property
          EXPORTING
            iv_attr_name = 'ROLE'
            iv_value     = ls_profile-customer_role.
      ENDIF.
*     limit search to maximum number of hits.
      CALL METHOD query_service->if_bol_bo_property_access~set_property
        EXPORTING
          iv_attr_name = 'MAX_HIT'
          iv_value     = lv_bupacontroller->max_hits.
*     fire query
        TRY.
            bo_col        ?= query_service->get_query_result( ).
          CATCH cx_sy_ref_is_initial.
        ENDTRY.
        entity_col ?= bo_col.
* set result into context
  typed_context->customers->set_collection( entity_col ).
* navigate
  IF entity_col->if_bol_bo_col~size( )  EQ 1.
    op_showbupa( ).
  ELSEIF entity_col->if_bol_bo_col~size( ) GT 1.
    op_listcustomers( ).
    if entity_col->if_bol_bo_col~size( ) eq lv_bupacontroller->max_hits.
      lv_msgsrv = cl_bsp_wd_message_service=>get_instance( ).
      lv_max_hit = lv_bupacontroller->MAX_HITS .
      lv_msgsrv->add_message( iv_msg_type   = 'I'
                            iv_msg_id     = 'CRM_IC_APPL_UI_BPID'
                            iv_msg_number = '009'
                            IV_MSG_V1      = lv_max_hit  ).
    endif.
  ELSE.
    lv_msgsrv = cl_bsp_wd_message_service=>get_instance( ).
    lv_msgsrv->add_message( iv_msg_type   = 'I'
                          iv_msg_id     = 'CRM_IC_APPL_UI_BPID'
                          iv_msg_number = '011' ).
*   clear result list
    view_manager->navigate(
               SOURCE_REP_VIEW = rep_view
               OUTBOUND_PLUG   = 'showEmpty' ).
  ENDIF.
ENDMETHOD.
In the class CL_BUIL_EMP (which has the superclass CL_BUIL_HEADER) you need to do a repair (changing of a standard SAP class) of method get_result_table.
What I have done is I've read the parameters that were added (automatically) to the query_service and added them to my FM to do the search.
You also need to take a copy of the BUPA_SEARCH_2 FM and add the parameters as importing parameters. Now you can add your search logic to the FM.
Here is the coding of the GET_RESULTS_TABLE:
METHOD get_result_table.
*    CHANGES BY MVNI ON 03/07/2007.
*    MARKER: MVNI(EX00885)03072007
*    REASON: SPAU Upgrade 5.0.
*    CHANGES BY MVNI ON 12/02/2008.
*    MARKER: MVNI(EX00885)12022008
*    REASON: CLM
  DATA:   ls_header_search TYPE crmst_header_search_buil,
          lv_mc_name1      TYPE bu_mcname1,
          lv_mc_name2      TYPE bu_mcname2,
          ls_address       TYPE bupa_addr_search,
          ls_fax_data      TYPE bapibus1006_fax_data,
          lt_return        TYPE TABLE OF bapiret2,
          lv_xaddrversion  TYPE abap_bool,
          lv_no_hits       TYPE i.
  DATA:   lt_but100        TYPE TABLE OF but100.
  DATA:   lv_role_category TYPE          bu_role.
  FIELD-SYMBOLS: <fs_result> LIKE LINE OF et_bupa_search_result.
* MVNI(EX00885)03072007: Begin of Insert
  DATA: iv_birthdate               TYPE bu_birthdt,
        iv_insz                    TYPE ZBU_00000000,
        lv_insz(15)                TYPE c,
        lv_bednr(15)               TYPE c,
        lv_vestnr(15)              TYPE c,
        ls_parameters TYPE crmt_name_value_pair.
* MVNI(EX00885)03072007: End of Insert
* MVNI(EX00885)03072007: Begin of Insert
  CONSTANTS: C_IDENTIFICATIONTYPE TYPE BU_ID_TYPE VALUE 'ZINSZ'.
* MVNI(EX00885)03072007: End of Insert
* define structure we use for input parameters
  MOVE-CORRESPONDING is_parameters TO ls_header_search.
  MOVE-CORRESPONDING is_parameters TO ls_address.
  MOVE-CORRESPONDING is_parameters TO ls_fax_data.
  IF ls_header_search-fax IS NOT INITIAL.
    IF ls_fax_data-country_for_fax IS NOT INITIAL.
      ls_fax_data-fax_no = ls_header_search-fax.
    ELSE.
      ls_fax_data-fax_no = ls_header_search-fax.
      ls_fax_data-country_for_fax = ls_header_search-country.
    ENDIF.
  ENDIF.
  lv_mc_name1 = ls_header_search-mc_name1.
  lv_mc_name2 = ls_header_search-mc_name2.
** MVNI(EX00885)03072007: Begin of Replace
*  LOOP AT is_parameters INTO ls_parameters.
*  ENDLOOP.
*        ls_parameters-name = 'BIRTHDATE'.
*          MOVE   ls_parameters-value TO iv_birthdate.
*        ELSEIF ls_parameters-name = 'ZZINSZ'.
*          MOVE   ls_parameters-value TO iv_insz.
*        endif.
* Remove all allowed non-digits
        lv_insz = ls_header_search-zzinsz.
        replace all occurrences of '.' in lv_insz with space.
        replace all occurrences of '-' in lv_insz with space.
        condense lv_insz no-gaps.
        ls_header_search-zzinsz = lv_insz.
* MVNI(EX00885)03072007: End of Replace
* MVNI(EX00885)12022008: Begin of insert
        lv_bednr = ls_header_search-zzbednr.
        replace all occurrences of '.' in lv_bednr with space.
        replace all occurrences of '-' in lv_bednr with space.
        condense lv_bednr no-gaps.
        ls_header_search-zzbednr = lv_bednr.
        lv_vestnr = ls_header_search-zzvestnr.
        replace all occurrences of '.' in lv_vestnr with space.
        replace all occurrences of '-' in lv_vestnr with space.
        condense lv_vestnr no-gaps.
        ls_header_search-zzvestnr = lv_vestnr.
* MVNI(EX00885)12022008: End of insert
* check if international address versions are active:
  IF address_version_id IS INITIAL.
    CALL METHOD check_for_int_add_versions( ).
  ENDIF.
* check for customizing in IC WebClient
  IF ls_header_search-no_trex IS INITIAL.
    ls_header_search-no_trex = cl_crm_buil_services=>check_for_trex( ).
  ENDIF.
  CLASS crm_saf_get_settings DEFINITION LOAD.
  IF NOT address_version_id IS INITIAL.
    lv_xaddrversion = abap_true.
  ENDIF.
* Optimization for combined search, Refer note 962864
  IF ls_address-country IS NOT INITIAL
     AND ls_address-city1 IS INITIAL
     AND ls_address-post_code1 IS INITIAL
     AND ls_address-region IS INITIAL
     AND ls_address-street IS INITIAL
     AND ls_address-house_num1 IS INITIAL.
    IF ls_header_search-telephone IS NOT INITIAL OR
       ls_header_search-email IS NOT INITIAL.
      CLEAR ls_address-country.
    ENDIF.
    IF ls_header_search-email IS NOT INITIAL.
      CLEAR ls_header_search-country_for_tel.
    ENDIF.
    IF ls_fax_data-fax_no IS INITIAL.
      CLEAR ls_fax_data-country_for_fax.
    ENDIF.
  ENDIF.
* MVNI(EX00885)03072007: Begin of Replace
*  CALL FUNCTION 'TREX_BUPA_SEARCH'
*    EXPORTING
*      iv_application     = crm_saf_get_settings=>gc_app_name_bp
*      iv_telephone       = ls_header_search-telephone
*      iv_email           = ls_header_search-email
*      iv_url             = ls_header_search-url
*      is_address         = ls_address
*      iv_mc_name1        = lv_mc_name1
*      iv_mc_name2        = lv_mc_name2
*      iv_fax_data        = ls_fax_data
*      iv_partner         = ls_header_search-partner
*      iv_partnerrole     = ls_header_search-role
*      iv_country_for_tel = ls_header_search-country_for_tel
*      iv_category        = ls_header_search-category
*      iv_max_partners    = ls_header_search-max_hit
*      iv_xaddrversion    = lv_xaddrversion
*      iv_not_trex        = ls_header_search-no_trex
*    TABLES
*      et_search_result   = et_bupa_search_result
*      et_return          = lt_return.
* MVNI(EX00885)12022008: Begin of insert
   CALL FUNCTION 'ZBUPA_SEARCH_2'
     EXPORTING
       IV_TELEPHONE                 = ls_header_search-telephone
       IV_EMAIL                     = ls_header_search-email
       IV_URL                       = ls_header_search-url
       IS_ADDRESS                   = ls_address
       IV_MC_NAME1                  = lv_mc_name1
       IV_MC_NAME2                  = lv_mc_name2
       IV_PARTNER                   = ls_header_search-partner
       IV_PARTNERROLE               = ls_header_search-role
*   IV_X_ALL_PARTNERROLES        =
*   IV_PARTNERROLE               =
*   IV_SORT1                     =
*   IV_SORT2                     =
*   IV_COUNTRY_FOR_TEL           =
*   IV_CATEGORY                  =
       IV_FAX_DATA                  = ls_fax_data
       IV_XADDRVERSION              = lv_xaddrversion
       IV_MAX_PARTNERS              = ls_header_search-max_hit
*   IV_NATION_VERS               =
*   IV_OLD_ROLE_PROCESS          =
*   IV_NO_SEARCH_FOR_CONTP       =
*   IV_VALID_DATE                = SY-DATLO
*   IV_TIME_INDEPENDENT          =
       IV_RRNR                      = ls_header_search-zzinsz
       IV_BIRTHDATE                 = ls_header_search-zbirthdate
       IV_BEDNR                     = ls_header_search-zzbednr
       IV_VESTNR                    = ls_header_search-zzvestnr
     TABLES
       ET_SEARCH_RESULT             = et_bupa_search_result
       ET_RETURN                    = lt_return.
* MVNI(EX00885)12022008: End of insert
* MVNI(EX00885)12022008: Begin of delete
*    CALL FUNCTION 'ZBUPA_SEARCH'
*     EXPORTING
*       IV_TELEPHONE                 = ls_header_search-telephone
*       IV_EMAIL                     = ls_header_search-email
*       IV_URL                       = ls_header_search-url
*       IS_ADDRESS                   = ls_address
*       IV_MC_NAME1                  = lv_mc_name1
*       IV_MC_NAME2                  = lv_mc_name2
*       IV_PARTNER                   = ls_header_search-partner
*       IV_PARTNERROLE               = ls_header_search-role
*       IV_SORT1                     =
*       IV_SORT2                     =
*       IV_COUNTRY_FOR_TEL           =
*       IV_CATEGORY                  =
*       IV_FAX_DATA                  = ls_fax_data
*       IV_XADDRVERSION              = 'X'
*       IV_MAX_PARTNERS              = '50'
*       IV_NATION_VERS               =
*       IV_NO_SEARCH_FOR_CONTP       =
*       IV_BIRTHDATE                 = ls_header_search-zbirthdate
*       IV_INSZ                      = ls_header_search-zzinsz
*     TABLES
*       ET_SEARCH_RESULT             = et_bupa_search_result
*       ET_RETURN                    = lt_return.
* MVNI(EX00885)03072007: End of Replace
* MVNI(EX00885)12022008: End of delete
  IF lt_return IS NOT INITIAL.
* no error handling
  ENDIF.
* filter out real employees if role is not 'Employee'
* (and if category is not specified)
  IF NOT et_bupa_search_result[] IS INITIAL
     AND ls_header_search-category IS INITIAL
     AND NOT ls_header_search-role IS INITIAL.
* function module has a buffer
    CALL FUNCTION 'BUCP_EMPLOYEE_ROLE_GET'
      IMPORTING
        e_employee_role = lv_role_category.
    IF NOT ls_header_search-role EQ lv_role_category.
      SELECT * FROM but100 INTO TABLE lt_but100
                           FOR ALL ENTRIES IN et_bupa_search_result
                           WHERE partner = et_bupa_search_result-partner
                           ORDER BY PRIMARY KEY.
      LOOP AT et_bupa_search_result ASSIGNING <fs_result>.
        READ TABLE lt_but100 WITH KEY partner = <fs_result>-partner
                             TRANSPORTING NO FIELDS
                             BINARY SEARCH.
        IF sy-subrc NE 0.
          CONTINUE.
        ENDIF.
        DELETE lt_but100 WHERE partner = <fs_result>-partner
                         AND   rltyp   = lv_role_category.
        READ TABLE lt_but100 WITH KEY partner = <fs_result>-partner
                             TRANSPORTING NO FIELDS
                             BINARY SEARCH.
        IF sy-subrc NE 0.
          DELETE et_bupa_search_result.
        ENDIF.
      ENDLOOP.
    ENDIF.
  ENDIF.
* if TREX is disabled and addressversions are active -> MAX_HIT does not work
* workaround:
  DESCRIBE TABLE et_bupa_search_result LINES lv_no_hits.
  IF lv_no_hits GT ls_header_search-max_hit.
    ev_max_hits = ls_header_search-max_hit.
  ENDIF.
ENDMETHOD.
Hope this helps!
Kind regards,
Micha