ALV Hierarchical Display

Question

Hi,
    Can any one of you tell  me how do we use ALV Hierarchical display.
In this I want to display only the header details,then only when the user clicks on any one of the field on the header,I want the details to be displayed.I know that we have to set some parameter,but whci parameter we have to set,I am not able to find out.Pls help me out.This is very urgent.
Ramya

Answer 1

HI,
just copy and paste the following program .
REPORT ZALV_HIER .
type-pools:slis.
tables: ekko,ekpo.
DATA:  alv_layout       TYPE slis_layout_alv.
data:begin of it_ekko occurs 0,
        EXPA  type FLAG,
        ebeln like ekko-ebeln,
        bukrs like ekko-bukrs,
        lifnr like ekko-lifnr,
        bedat like ekko-bedat,
      end of it_ekko.
data: begin of it_ekpo occurs 0,
        sno like ekpo-ebeln,
        ebelp like ekpo-ebelp,
        menge like ekpo-menge,
        netwr like ekpo-netwr,
      end of it_ekpo.
data v_repid like sy-repid.
data it_fieldcat type slis_fieldcat_alv occurs 0 with header line.
data x_keyinfo type slis_keyinfo_alv.
select-options:s_ebeln for ekko-ebeln.
initialization.
  v_repid = sy-repid.
  s_ebeln-low = '1000'.
  s_ebeln-sign = 'I'.
  s_ebeln-option = 'EQ'.
  S_ebeln-high = '5000'.
  append s_ebeln.
start-of-selection.
  perform get_data.
  perform get_field.
  perform get_key.
  perform key_modify.
  perform display.
*& Form get_data
* text
* --> p1 text
* <-- p2 text
form get_data.
  select ebeln  bukrs
         lifnr  bedat
  from ekko
  into corresponding fields of table it_ekko.
  it_ekko-expa = 'X'.
  MODIFY it_ekko transporting expa
  WHERE expa = space.
  select ebeln ebelp
         menge netwr
  from ekpo
  into table it_ekpo.
endform. " get_data
*& Form get_field
* text
* --> p1 text
* <-- p2 text
form get_field.
  call function 'REUSE_ALV_FIELDCATALOG_MERGE'
       EXPORTING
            i_program_name     = v_repid
            i_internal_tabname = 'IT_EKKO'
            i_inclname         = v_repid
       CHANGING
            ct_fieldcat        = it_fieldcat[].
  call function 'REUSE_ALV_FIELDCATALOG_MERGE'
       EXPORTING
            i_program_name     = v_repid
            i_internal_tabname = 'IT_EKPO'
            i_inclname         = v_repid
       CHANGING
            ct_fieldcat        = it_fieldcat[].
endform. " get_field
*& Form get_key
* text
* --> p1 text
* <-- p2 text
form get_key.
  x_keyinfo-header01 = 'EBELN'.
  x_keyinfo-item01 = 'SNO'.
endform. " get_key
*& Form DISPLAY
* text
* --> p1 text
* <-- p2 text
form display.
  alv_layout-detail_popup      = 'X'.
  alv_layout-group_change_edit = 'X'.
  alv_layout-EXPAND_FIELDNAME  = 'EXPA'.
  CALL FUNCTION 'REUSE_ALV_HIERSEQ_LIST_DISPLAY'
       EXPORTING
            i_callback_program = v_repid
            IS_LAYOUT          = alv_layout
            it_fieldcat        = it_fieldcat[]
            i_tabname_header   = 'IT_EKKO'
            i_tabname_item     = 'IT_EKPO'
            is_keyinfo         = x_keyinfo
       TABLES
            t_outtab_header    = it_ekko
            t_outtab_item      = it_ekpo.
endform. " DISPLAY
*& Form key_modify
* text
* --> p1 text
* <-- p2 text
form key_modify.
  loop at it_fieldcat. "Avoid Repitiotion of data.
    case it_fieldcat-fieldname.
      when 'SNO'.
        if it_fieldcat-tabname = 'IT_EKPO'.
          it_fieldcat-no_out = 'X'.
          it_fieldcat-key = space.
        endif.
    endcase.
    modify it_fieldcat index sy-tabix.
  endloop.
endform.