Anyone know a simple way to reject a PO in background?

Question

G'Day folks,
Does anyone have a shortcut, secret function module or equivalent to BAPI_PO_RELEASE to reject a Purchase Order on 4.7? There's BAPI_PO_RESETRELEASE, but alas no reject.
I admit I'm being a little bit lazy here but
a) an hour searching/debugging has been fruitless
b) this seems normal enough that someone's come across this before, and
c) it's hometime and I'm hoping someone has a simple answer
Any input appreciated,
Mike
(Crossposted to WUG and SDN)

Answer 1

Take a look at this:
method reject_po.
  data: lc_po       type ref to cl_po_header_handle_mm,
        ls_document type mepo_document.
*  prepare creation of PO instance
  ls_document-doc_type    = 'F'.
  ls_document-process     = mmpur_po_process.
  ls_document-trtyp       = 'V'.
  ls_document-doc_key(10) = po_number.
  ls_document-initiator-initiator = mmpur_initiator_rel.
*  object creation and initialization
  create object lc_po.
  lc_po->for_bapi = mmpur_yes.
  call method lc_po->po_initialize( im_document = ls_document ).
  call method lc_po->set_po_number( im_po_number = po_number ).
  call method lc_po->set_state( cl_po_header_handle_mm=>c_available ).
*  read purchase order from database
  call method lc_po->po_read
    exporting
      im_tcode     = 'ME29N'
      im_trtyp     = ls_document-trtyp
      im_aktyp     = ls_document-trtyp
      im_po_number = po_number
      im_document  = ls_document.
  if lc_po->if_releasable_mm~is_rejection_allowed( ) = mmpur_yes.
    call method lc_po->if_releasable_mm~reject
      exporting
        im_reset = space
      exceptions
        failed   = 1
        others   = 2.
  endif.
  call method lc_po->po_post
    exceptions
      failure = 1
      others  = 2.
endmethod.