Append Field symbols

Question

Hi all,
how can we move internal tables data to field symbol table.
i am new to field symbol, can any one guide me in detail.. i have searched in forums but i am unable understand..
i have defined fields symbols like this.
FIELD-SYMBOLS: <F_TAB>   TYPE STANDARD TABLE,
               <F_LINE>  TYPE ANY,
               <F_FIELD> TYPE ANY.
and i have data in ITAB1, ITAB2 & ITAB3.
this tables data i need to move to final internal table i.e. <F_TAB>, whose structure is created dynamically..
in this way i have created the dynamical internal table structure
LOOP AT IT_WDAYS INTO WA_WDAYS.
      PERFORM MONTH_TEXT USING WA_WDAYS-PERIODAT CHANGING V_FNAME.
*   Element Description
      LO_ELEMENT ?= CL_ABAP_ELEMDESCR=>DESCRIBE_BY_NAME( 'CHAR5' ).
      MOVE V_FNAME TO LA_COMP-NAME.
*   Field type
      LA_COMP-TYPE = CL_ABAP_ELEMDESCR=>GET_P(
                        P_LENGTH   = LO_ELEMENT->LENGTH
                        P_DECIMALS = LO_ELEMENT->DECIMALS ).
*   Filling the component table
      APPEND LA_COMP TO LT_TOT_COMP.
      CLEAR: LA_COMP.
    ENDLOOP.
* 3. Create a New Type
    LO_NEW_TYPE = CL_ABAP_STRUCTDESCR=>CREATE( LT_TOT_COMP ).
* 4. New Table type
    LO_NEW_TAB = CL_ABAP_TABLEDESCR=>CREATE(
                    P_LINE_TYPE  = LO_NEW_TYPE
                    P_TABLE_KIND = CL_ABAP_TABLEDESCR=>TABLEKIND_STD
                    P_UNIQUE     = ABAP_FALSE ).
* 5. data to handle the new table type
    CREATE DATA LO_DATA TYPE HANDLE LO_NEW_TAB.
* 6. New internal table in the fieldsymbols
    ASSIGN LO_DATA->* TO <F_TAB>.
i dont want to create thru fieldcatalog method...
just i want know how to pass 2 internal tables data into one final field symbol table..
thanks
Edited by: Matt on Mar 23, 2009 10:52 AM - added  tags

Answer 1

Hi,
Check this code:
*& Report  Z_RTTS_TABLE
REPORT  z_rtts_table.
TYPE-POOLS: abap.
DATA: gs_comp TYPE abap_componentdescr,
      gt_comp TYPE abap_component_tab.
"example table
DATA: BEGIN OF it OCCURS 3,   "<- your ITAB1
        pernr TYPE persno,
        kostl TYPE kostl,
        endda TYPE endda,
      END OF it.
"data references
DATA: r_type_struct TYPE REF TO cl_abap_structdescr,
      r_type_table  TYPE REF TO cl_abap_tabledescr,
      r_data_tab    TYPE REF TO data,
      r_data_str    TYPE REF TO data.
* 1. ------------- filling example table IT  -> i.e your ITAB1
it-pernr = '12345678'.
it-kostl = '0112345678'.
it-endda = sy-datum.
APPEND it.
it-pernr = '45678909'.
it-kostl = '3452345678'.
it-endda = sy-datum - 1.
APPEND it.
* 2. ------------ components structure type
gs_comp-name = 'PERNR'.
gs_comp-type ?= cl_abap_elemdescr=>describe_by_name( 'PERSNO' ).
APPEND gs_comp TO gt_comp.
gs_comp-name = 'KOSTL'.
gs_comp-type ?= cl_abap_elemdescr=>describe_by_name( 'KOSTL' ).
APPEND gs_comp TO gt_comp.
gs_comp-name = 'BEGDA'.
gs_comp-type ?= cl_abap_elemdescr=>describe_by_name( 'BEGDA' ).
APPEND gs_comp TO gt_comp.
* 3. ------------- create structure type
TRY.
    r_type_struct = cl_abap_structdescr=>create(
                              p_components = gt_comp ).
  CATCH cx_sy_struct_creation .
ENDTRY.
* 4. ------------- create table type
TRY.
    r_type_table = cl_abap_tabledescr=>create( r_type_struct ).
  CATCH cx_sy_table_creation .
ENDTRY.
" 5. -------------- create table based on RTTS types
CREATE DATA: r_data_tab TYPE HANDLE r_type_table,
             r_data_str TYPE HANDLE r_type_struct.
FIELD-SYMBOLS: <fs_table> TYPE INDEX TABLE,    "-> here table must by type INDEX TABLE in order to append to it
                           <fs_wa>    TYPE ANY.
ASSIGN: r_data_tab->* TO <fs_table>,
        r_data_str->* TO <fs_wa>.         "work area for dynamic table (based on your dynamic structure)     
" 6. ---------------- move internal table data (IT) to dynamic table
LOOP AT it.
  MOVE-CORRESPONDING it TO <fs_wa>.
  APPEND <fs_wa> TO <fs_table>.
ENDLOOP.
Do the same with ITAB2 and ITAB3.
Regards
Marcin