AppleScript 10.9.0 System Events -10006 Update property list file item

Question

Have AppleScript that runs without error on Mountain Lion 10.8.5, but errors out on Mavericks  10.9.0.
At end of script, property list items need to be updated and this is when error occurs.
Put together a subset of the script, see below) that get the error
Statement reads "set value of property list item "ArrayList001" to ArrayList001"
Text of error:
     error "System Events got an error: 'xxx.plist' is not a property list file."
     number -10006 from contents of property list file "xxx05.plist"
=============================================================================
property myPListFile : "cbmck05.plist"
property myPListFilePath : ""
property constPreviousRunDay : "PreviousRunDay"
on run
   set today to "Date01" as string
          set List001 to {}
          set List002 to {}
          set myPListFilePath to ""
          repeat with i from 1 to 8
                    set end of List001 to (i * 2) as string
          end repeat
          set myPListFilePath to path to desktop folder from user domain as string
          set fileMyPList to (myPListFilePath & myPListFile) as string
clear_file(fileMyPList)
-- First time! need to initalize
          tell application "System Events"
  -- create an empty property list dictionary item
                    set the parent_dictionary to make new property list item with properties {kind:record}
  -- create new property list file using the empty dictionary list item as contents
                    set new_plistfile to ¬
  make new property list file with properties {contents:parent_dictionary, name:fileMyPList}
  make new property list item at end of property list items of contents of new_plistfile ¬
  with properties {kind:string, name:constPreviousRunDay, value:today}
  make new property list item at end of property list items of contents of new_plistfile ¬
                              with properties {kind:list, name:"ArrayList001"}
  make new property list item at end of property list items of contents of new_plistfile ¬
                              with properties {kind:list, name:"ArrayList002"}
          end tell
          set previousRunDate to today
          set xxList to (repopulate_lists())
          set ArrayList001 to List001
          set ArrayList002 to List002
-- save info in the plist file
          tell application "System Events"
                    tell property list file fileMyPList
                              tell contents
                                        set value of property list item constPreviousRunDay to previousRunDate
                                        set value of property list item "ArrayList001" to ArrayList001     --   <<< ------- error caused by the statement
                                        set value of property list item "ArrayList002" to ArrayList002
                              end tell
                    end tell
          end tell
end run
-- ==========================================
on repopulate_lists()
          set newList to {}
          set List002 to {}
          repeat with i from 1 to 8
                    set end of newList to i as string
          end repeat
          set List001 to newList
          return List001
end repopulate_lists
-- ==========================================
-- Does the file exist?
on fileExists(f)
          try
  f as string as alias
                    return true
          on error errMsg number errNum
                    return false
          end try
end fileExists
-- Delete the  files if exist
on clear_file(aFile)
          if fileExists(aFile) then
                    tell application "Finder"
                              set resultObject to delete aFile
                    end tell
          end if
end clear_file

Answer 1

Here's an AppleScript handler that partially works around this bug (warning: it turns each list item into a string).
on plistWrite(plistPath, plistItemName, plistItemValue)
  -- version 1.1, Daniel A. Shockley
  -- 1.1 - rough work-around for Mavericks bug where using a list for property list item value wipes out data
          if class of plistItemValue is class of {"a", "b"} and AppleScript version of (system info) as number ≥ 2.3 then
  -- Convert each list item into a string and escape it for the shell command:
  -- This will fail for any data types that AppleScript cannot coerce directly into a string.
                    set plistItemValue_forShell to ""
                    repeat with oneItem in plistItemValue
                              set plistItemValue_forShell to plistItemValue_forShell & space & quoted form of (oneItem as string)
                    end repeat
                    set shellCommand to "defaults write " & quoted form of POSIX path of plistPath & space & plistItemName & space & "-array" & space & plistItemValue_forShell
  do shell script shellCommand
                    return true
          else -- handle normally, since we aren't dealing with Mavericks list bug:
                    tell application "System Events"
  -- create an empty property list dictionary item
                              set the parent_dictionary to make new property list item with properties {kind:record}
                              try
                                        set plistFile to property list file plistPath
                              on error errMsg number errNum
                                        if errNum is -1728 then
                                                  set plistFile to make new property list file with properties {contents:parent_dictionary, name:plistPath}
                                        else
                                                  error errMsg number errNum
                                        end if
                              end try
                              tell plistFile
                                        try
                                                  tell property list item plistItemName
                                                            set value to plistItemValue
                                                  end tell
                                        on error errMsg number errNum
                                                  if errNum is -10006 then
  make new property list item at ¬
                                                                      end of property list items of contents of plistFile ¬
  with properties ¬
                                                                      {kind:class of plistItemValue, name:plistItemName, value:plistItemValue}
                                                  else
                                                            error errMsg number errNum
                                                  end if
                                        end try
                              end tell
                              return true
                    end tell
          end if
end plistWrite