Applescript and InDesign: Packaging/exporting -- can you help?

Question

I found and tweaked a droplet script that isn't quite working right. I tried and failed to learn to do this myself. Any help is greatly appreciated! This is for InDesign CS6 -- you don't really need to know InDesign in order to help (at least I don't think so).
For the moment, I simply drag multiple InDesign files (for this example, "filename1.indd" and "filename2.indd") onto the droplet. InDesign packages them separately and outputs PDFs into each output folder. The problem is that it's creating too many folders and not putting things where I want.
Another thing: when InDesign packages a file, it creates a "Instructions.txt" file for each package that I need deleted. I'd really like this added to the script as well. Is it possible?
Current output (messy!)
Desired output (perfect!)
"exports" folder
     "filename1" folder
          filename1.pdf
          "filename1" folder
               filename1.indd
               Instructions.txt
     "filename2" folder
          filename2.pdf
          "filename2" folder
               filename2.indd
               Instructions.txt
baseFolder <--- directory of original files
     "filename1" folder
          filename1.indd
          "PDF" folder
               filename1.pdf
     "filename2" folder
          filename2.indd
          "PDF" folder
               filename2.pdf
Here's the script I have so far:
property baseFolder : (path to desktop as text) & "exports:"
on open mgItems
     repeat with mgThisItem in mgItems
          tell application id "com.adobe.InDesign"
               try
          open mgThisItem
               set mgDocName to name of active document
               set text item delimiters of AppleScript to ".indd"
               set mgShortName to text item 1 of mgDocName
               set targetFolderPath to my createFolder(mgShortName)
               set text item delimiters of AppleScript to ""
               set mgPackageFilePath to targetFolderPath & mgShortName as string
               set mgProofFilePath to mgPackageFilePath & ".pdf" as string
               set properties of PDF export preferences to properties of PDF export preset "[Smallest File Size]"
               tell the active document to export format PDF type to mgProofFilePath without showing options
               tell the active document to package to mgPackageFilePath with copying fonts, ignore preflight errors, copying profiles, updating graphics, including hidden layers,copying linked graphics and creating report
  close active document saving no
               on error e
                    display dialog e
               end try
          end tell
     end repeat
     display dialog "PDFs created and InDesign file packaged"
end open
on createFolder(nameString)
     set macFolderPath to baseFolder & nameString
     do shell script "mkdir -p " & quoted form of POSIX path of macFolderPath
     return macFolderPath & ":"
end createFolder
Thanks very much!

Answer 1

Easy enough. Note that I've moved things around a little to make a nicer flow:
on open mgItems
  --make a date slug
          set shortDateString to short date string of (current date)
          set {oldTID, my text item delimiters} to {my text item delimiters, "/"}
          set dateBits to (text items of shortDateString)
          set my text item delimiters to ""
          set datePrefixString to (text item 3 of dateBits & text items 1 thru 2 of dateBits & "_Release") as text
          set my text item delimiters to oldTID
          repeat with mgThisItem in mgItems
                    tell application "System Events"
  --get path of the container of the passed in object
                              set targetFolderPath to path of container of disk item (mgThisItem as text)
                    end tell
                    tell application id "com.adobe.InDesign"
                              try
                                        open mgThisItem
                                        set mgDocName to name of active document
                                        set text item delimiters of AppleScript to ".indd"
                                        set mgShortName to text item 1 of mgDocName
  -- set up folder and file references
                                        set mgPackageFilePath to targetFolderPath & datePrefixString & ":" & mgShortName & ":"
                                        set mgProofFilePath to mgPackageFilePath & "PDF:" & mgShortName & ".pdf" as string
                                        set text item delimiters of AppleScript to ""
  -- create dat folder, main folder and internal PDF folder; passing in POSIX path, though most everything ele uses HFS paths
                                        my createFolders(POSIX path of file (mgPackageFilePath & "PDF:"))
                                        set properties of PDF export preferences to properties of PDF export preset "[Smallest File Size]"
                                        tell the active document to export format PDF type to mgProofFilePath without showing options
                                        tell the active document to package to mgPackageFilePath with copying fonts, ignore preflight errors, copying profiles, updating graphics, including hidden layers, copying linked graphics and creating report
                                        close active document saving no
                              on error e
                                        display dialog e
                              end try
                    end tell
  -- delete the instructions file
                    tell application "System Events"
                              delete file (mgPackageFilePath & "instructions.txt")
                    end tell
          end repeat
          display dialog "PDFs created and InDesign file packaged"
end open
on createFolders(pathString)
          do shell script "mkdir -p " & quoted form of pathString
end createFolders