Applescript: filenames from folder to append to csv

Question

For my bookkeeping I need to scan and store my receipts as a PDF file, but transfer some information (like amount and category) to an Numbers (Excel)-sheet as well. I'm using TextExpender to include al information needed for the Numberssheet inside the filename, which looks something like this:
UIT4,20130401,23,categoryA,.pdf
I want to transfer all the pdf-filenames in the folder to append to a csv file, so I get:
test.csv
UIT4,201304001,23,categoryA
UIT5,201305002,25,categoryB
UIT2,201306001,22,categoryA
etc.
I can import the csv in Numbers and all is well.
My question for you is how can I use applescript to get all the pdf-filenames in a folder to append to a csv-file?
I've tried this modified script by Pierre L, but I get a error regarding the ending of the file??
set theFolder to choose folder
set theTextFile to POSIX file "/Users/user_name/Desktop/test.csv" -- for example
set theText to read theTextFile
tell application "Finder"
    set theFileNames to name of files of theFolder whose name extension is "pdf"
    repeat with thisName in theFileNames
        try
            set xx to (text 1 through 2 of thisName) as integer
            set theNewFileName to paragraph (xx + 1) of theText
            if character 3 of thisName is "-" then
                set theNewFileName to theNewFileName & character 4 of thisName
            end if
            set name of file thisName of theFolder to theNewFileName & ".pdf"
        end try
    end repeat
end tell
If you'd like to help out, that would be great!

Answer 1

Or perhaps you could write the replacement for "_" into ";" in the Applescript itself.
That's pretty easy using AppleScript - that way you could leave the file names intact and just change them before writing the data to the file. There are several ways of doing this and, unless you really want, I won't delve deep into the process of using text item delimiters, but an example script is below.
- the script lets me choose a folder in a dialog box, is it also possible to direct it to a pre-specified folder?
Of course. The first line is the one that triggers the Choose Folder dialog:
set theFolder to (choose folder)
You can just change this to any folder on disk by providing its path:
set theFolder to "Macintosh HD:Users:username:Desktop:My folder"
and making sure you tell the Finder that this represents a folder path:
          set theFiles to every file of folder theFolder whose name extension is "pdf"
(note the addition of the 'folder' keyword.
- is it possible to let the script create a new CSV-file named OUT4_[current date].csv?
Yes, but....
The third line in the script creates the output file.
          set csvFile to open for access (file ((path to desktop as text) & "my.csv")) with write permission
You can call it whatever you like - replace 'my.csv' with the desired file name. Just be careful in putting formatted dates into filenames since characters like the '/' in '11/24/2013' will be confusing since the / is used as a directory delimiter ('11/24/2013' would normally indicate the file called '2013' inside the '24' folder that is inside the '11' folder). Date formatting in AppleScript can be tricky, but its certainly do-able. How do you want it formatted?
Revised script that incorporates replacing underscores with commas:
set theFolder to "Macintosh HD:Users:you:Desktop:Some folder"
tell application "Finder"
          set csvFile to open for access (file ((path to desktop as text) & "my.csv")) with write permission
  set eof csvFile to 0 -- remove this line to append data
          set theFiles to every file of folder theFolder whose name extension is "pdf"
          repeat with eachFile in theFiles
                    set fn to name of eachFile
                    set csvData to my replaceChars(fn, "_", ",")
  write (csvData & return) as text to csvFile
          end repeat
  close access csvFile
end tell
on replaceChars(inputFileName, oldChar, newChar)
          set {tid, my text item delimiters} to {my text item delimiters, oldChar}
          set newfilename to text items of inputFileName
          set my text item delimiters to newChar
          set newfilename to newfilename as text
          set my text item delimiters to tid
          return newfilename
end replaceChars