Applescript to modify contacts custom field?

Question

Hi-
I want to be able to search my address book the way I used to on my palm... by first initial followed by last name. For instance, if I wanted to search for John Smith, I'd enter "jsm". It's a highly efficient way to search, and I miss it dearly.
So, I would like to write an applscript that I could run on a nightly basis that would go through my entire contact list and look at the "Maiden Name" field. If the field is empty, the script would fill it with the first letter of the first name, followed by the entire last name (if a last name exists). Obviously, it would skip businesses where no names existed.
Bonus points would be doing this in a custom field, but I can't figure out how to get Applescript to read custom field labels at all!
Thoughts?
Thanks!

Answer 1

HI,
This may help you to write your script.
tell application "Contacts"
activate
          set the_people to every person
          repeat with tp in the_people
                    try -- lazy way of skipping companies
                              set fn to first name of tp
                              set l_n to last name of tp -- ln is apparently a reserved variable name
                              if l_n is not missing value then -- it's probably a person and not a business
                                        if maiden name of tp is in {"", missing value} then -- this person doesn't already have a maiden name
                                                  set mn to text 1 of fn & l_n
                                                  set maiden name of tp to mn
                                        end if
                              end if
                    end try
          end repeat
save
end tell
If you decide you don't like it, this will remove all maiden names - including real ones.
tell application "Contacts"
set the_people to every person
repeat with tp in the_people
          try
                    set maiden name of tp to ""
          end try
end repeat
save
end tell
I have a vague memory of trying and failing to get anywhere with scripting custom fields. I'll give it a go though.