BAPI_USER_CHANGE "named argument not found" error in VBA

Question

Folks,
I'm trying to update SAP users' email addresses en masse via a VBA routine.  The subroutine I'm trying to run is here, at least in skeletal form (it still needs MAPI code to pick up the email information, but that's outside the scope of the question:)
Sub UpdateUsers()
Dim gConnection As Object 'global connection object
Dim boUser As Object
Dim oAddress As Object, oPOHeader As Object, oAddressX As Object, oReturn As Object
Dim oCommitReturn As Object, oBAPIService As Object
Dim db As Database, rs As Recordset
Dim strDbName As String
Dim oBAPICtrl As New SAPBAPIControl
    'Database file name
    strDbName = CurrentDb.Name
    'Open database file
    Set db = DBEngine.OpenDatabase(strDbName)
    'Database table/query to take data from
    Set rs = db.OpenRecordset("users", dbOpenDynaset, dbSeeChanges)
    'Set up connection object for SAP.  Note that the SAP BAPI ActiveX object must be available on the form or otherwise.
    Set gConnection = oBAPICtrl.Connection
    'Log in to SAP.  Seems like passwords must be in uppercase.  There are examples of people defaulting some (or all)
    'of the login values
    gConnection.logon
    'Set up the transaction commit.  You need this for the effects of an update BAPI to actually take effect.
    Set oBAPIService = oBAPICtrl.GetSAPObject("BapiService")
    'This table object contains error message data regarding how well the commit worked.
    Set oCommitReturn = oBAPICtrl.DimAs(oBAPIService, "TransactionCommit", "Return")
    'Buzz through the Access table.
    With rs
    .MoveFirst
    Do While .EOF <> True
    'Initialize all BAPI objects for each transaction.
    Set boUser = Nothing
    Set oPOHeader = Nothing
    Set oAddress = Nothing
    Set oAddressX = Nothing
    Set oReturn = Nothing
    'Initialize all BAPI object structures to what is required.
    'To see what BAPI's are available and how to call them, go to http://ifr.sap.com/catalog/query.asp
    'Note that the first line actually establishes a primary key (PO, in this example.)
    Set boUser = oBAPICtrl.GetSAPObject("USER", !Uname)
    Set oAddress = oBAPICtrl.DimAs(boUser, "Change", "Address")
    Set oAddressX = oBAPICtrl.DimAs(boUser, "Change", "Addressx")
    Set oReturn = oBAPICtrl.DimAs(boUser, "Change", "Return")
    'Populate all tabular BAPI structures with appropriate information, as required by the BAPI.
'    oAddress.rows.Add
    oAddress.Value("E_MAIL") = "[email protected]"
'   oAddressX.rows.Add
    oAddressX.Value("E_MAIL") = "X"
    'Actually call the BAPI here.
    boUser.Change UserName:=!Uname, _
                   Address:=oAddress, _
                   Addressx:=oAddressX, _
                   Return:=oReturn
    'See how things worked by checking the first line of the "return" object.  Type code of "S" means success.
    If oReturn.Value(1, "TYPE") <> "S" Then
    'If we had a non-successful return code, pop up a message box here indicating what went wrong.
        MsgBox ("Error changing user" + !User + vbCrLf + oReturn.Value(1, "MESSAGE"))
    Else
    'If we received a successful return code, do a commit.  You have to do this in order for the update to work.
        oBAPIService.TransactionCommit Wait:="X", _
                                         Return:=oCommitReturn
       .Edit
       !done = True
       .Update
    End If
    .MoveNext
    Loop
End With
'Log out of SAP.
gConnection.logoff
MsgBox ("Done.")
End Sub
Can anyone see what's going on with the BAPI call to BAPI_USER_CHANGE and what I'm not providing it that it wants (or am providing it wrong?)
Thanks,
Eric

Answer 1

<b>Got it working--if you ever want to do this (or something similar,) here's how:</b>
Option Compare Database
     Public objSession As MAPI.Session
     Public txtFirstName As String
     Public txtMiddleInit As String
     Public txtLastName As String
     Public txtTitle As String
     Public txtPhoneNumber As String
     Public txtFaxNumber As String
     Public txtOFCName As String
     Public txtEmailAddress As String
Sub UpdateUsers()
Dim gConnection As Object 'global connection object
Dim boUser As Object
Dim oAddress As Object, oPOHeader As Object, oAddressX As Object, oAdSMTP As Object, oReturn As Object
Dim oCommitReturn As Object, oBAPIService As Object
Dim db As Database, rs As Recordset
Dim strDbName As String
Dim oBAPICtrl As New SAPBAPIControl
    'Database file name
    strDbName = CurrentDb.Name
    'Open database file
    Set db = DBEngine.OpenDatabase(strDbName)
    'Database table/query to take data from
    Set rs = db.OpenRecordset("users", dbOpenDynaset, dbSeeChanges)
    'Set up connection object for SAP.  Note that the SAP BAPI ActiveX object must be available on the form or otherwise.
    Set Functions = CreateObject("SAP.Functions")
    Set FUNC = Functions.Add("BAPI_USER_CHANGE")
    Set eUsername = FUNC.exports("USERNAME")
    FUNC.exports("ADDRESSX").Value("E_MAIL") = "X"
    'Buzz through the Access table.
    With rs
    .MoveFirst
    Do While .EOF <> True
       eUsername.Value = !uname
       GetProperties (!uname)
       FUNC.exports("ADDRESS").Value("E_MAIL") = txtEmailAddress
       FUNC.Call
       .MoveNext
    Loop
End With
MsgBox ("Done.")
End Sub
Sub GetProperties(strUserid As String)
       Dim objAddrEntries As AddressEntries
       Dim objAddressEntry As AddressEntry
       Dim objFilter As AddressEntryFilter
       Dim strCompareUserid As String
       Dim collAddressLists As AddressLists
       Dim objAddressList As AddressList
       Dim collAddressEntries As AddressEntries
       ' create a session and log on
       Set objSession = CreateObject("MAPI.Session")
       objSession.Logon , , , False
       Set objAddrEntries = objSession.AddressLists("Global Address List").AddressEntries
       Set objFilter = objAddrEntries.Filter
       objFilter.Fields.Add CdoPR_ACCOUNT, strUserid
       objFilter.Or = False
       strUserid = LCase(strUserid)
       'Initializing
       txtFirstName = ""
       txtMiddleInit = ""
       txtLastName = ""
       txtTitle = ""
       txtPhoneNumber = ""
       txtFaxNumber = ""
       txtEmailAddress = ""
       On Error Resume Next
        For Each objAddressEntry In objAddrEntries
            strCompareUserid = objAddressEntry.Fields(CdoPR_ACCOUNT).Value
            strCompareUserid = LCase(strCompareUserid)
            If strCompareUserid = strUserid Then
                txtFirstName = objAddressEntry.Fields(CdoPR_GIVEN_NAME).Value
                txtMiddleInit = objAddressEntry.Fields(CdoPR_INITIALS).Value
                txtLastName = objAddressEntry.Fields(CdoPR_SURNAME).Value
                txtTitle = objAddressEntry.Fields(CdoPR_TITLE).Value
                txtPhoneNumber = objAddressEntry.Fields(CdoPR_BUSINESS_TELEPHONE_NUMBER).Value
                txtFaxNumber = objAddressEntry.Fields(CdoPR_PRIMARY_FAX_NUMBER).Value
                txtEmailAddress = objAddressEntry.Fields(&H39FE001F).Value
                Exit Sub
          End If
       Next
End Sub