BDC for FB01 Transaction.

Question

Hi Experts,
I am having the bdc recording of the transaction FB01 in shdb transaction.I have converted the recording into an program.I am finding difficulty in Line items posting. As I am new to FI module.
How to go about for the line item positng with respect to  psoting key is NEWBS.
Thanks in Advance
Irfan Hussain

Answer 1

Hi,
FB01 is a transaction very nice to learn BDC
Here a code (with french comment)
report z_fi_in_01 no standard page heading
                  line-size 80
                  line-count 65.
*-------------------------------- DATA --------------------------------*
data : v_infile(200) type c ,              " Chemin physique fich.
       v_periode(4)  type n ,              " Periode
       v_t_code(20)  type c value 'FB01' , " Code transaction.
       v_count(3)    type n ,              " Compteur de poste piec
       v_decimal(1)  type c ,              " Representation decimal
       v_nb_blanc(6) type n ,              " Nb ligne montant nul
       v_date(8)     type c .              " Date comptable
data : begin of itab_fichier_in occurs 0,
         societe(4)   type c ,                  " Société
         poste(2)     type c ,                  " Poste -> type piece
         centre(8)    type c ,                  " Centre de couts
         compte(10)   type c ,                  " Compte comptable
         code_dc(1)   type c ,                  " Code debit/credit C/D
         montantc(13) type p decimals 2 ,       " Montant credit
         montantd(13) type p decimals 2 ,       " Montant debit
       end of itab_fichier_in.
data: begin of bdc_tab occurs 100.
        include structure bdcdata.
data: end of bdc_tab.
data : begin of itab_piece occurs 0 ,
         typepiece(2) type c ,
         montantc(13) type p decimals 2 ,       " Montant credit
         montantd(13) type p decimals 2 ,       " Montant debit
         solde(13)    type p decimals 2 ,       " Solde
       end of itab_piece.
*--------------------------- PARAMETERS -------------------------------*
parameters : p_infile(100) type c
                           default '.dat'
                           lower case
                           obligatory ,
             p_nom(12) type c
                        default 'Z_PAIE'
                        obligatory ,
             p_waers like t001-waers
                        obligatory .
*-------------------------------- MAIN --------------------------------*
start-of-selection.
* Recherche des chemins physique à partir des chemins logiques.
  perform p_recherche_chemin.
* Copie du contenu du fichier dans la table interne ITAB_FICHIER_IN.
  perform p_lecture_input.
* Test si les données sont bien equilibrées.
  perform p_test_donnee.
* Ouverture du dossier.
  perform open_bdc using p_nom.
* Transformation des données type pleiade au format SAP.
  perform p_creation_batch.
* Fermeture du dossier.
  perform close_bdc.
* Edition.
  perform p_edition.
end-of-selection.
*------------------------------ PROCEDURE -----------------------------*
*   Procédure P_RECHERCHE_CHEMIN.                                      *
*   Recherche des chemins de fichiers physiques à partir des chemins   *
*   de fichiers logiques.                                              *
form p_recherche_chemin.
* Fonction de recherche du chemin physique depuis le chemin logique
* On passe en parametre le nom du fichier.
  call function 'FILE_GET_NAME'
       exporting
            client           = sy-mandt
            logical_filename = 'Z_FI_PAIE_PLEIADE_FILE'
            operating_system = sy-opsys
            parameter_1      = p_infile
       importing
            file_name        = v_infile
       exceptions
            file_not_found   = 1
            others           = 2.
* Si probleme d ouverture message et on arrete tout.
  if sy-subrc <> 0.
    message id sy-msgid type sy-msgty number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    stop.
  endif.
endform.                               " P_RECHERCHE_CHEMIN
*   Procédure P_LECTURE_INPUT.                                         *
*   Ouverture, lecture, fermeture du fichier de paie.                  *
form p_lecture_input.
  data : v_msg(100)    type c ,     " Message d erreur ouverture fichier
         v_buffer(200) type c.      " Buffer lecture fichier
* Ouverture du fichier en entrée.
  open dataset v_infile for input in text mode message v_msg.
  if sy-subrc ne space.
    write : /1 'ERREUR FATALE !' color 3,
               'IMPOSSIBLE D OUVRIR LE FICHIER EN ENTREE :',
               p_infile ,
            /1 v_msg.
    stop.
  endif.
* Lecture sequentiele du fichier en entrée.
  do.
    read dataset v_infile into v_buffer.
*   Test fin de fichier.
    if sy-subrc ne space.
      exit.
    endif.
*   Transfert du buffer dans la table interne.
    move : v_buffer+6(4)   to v_periode ,
           v_buffer+10(8)  to itab_fichier_in-centre ,
           v_buffer+18(10) to itab_fichier_in-compte ,
           v_buffer+28(2)  to itab_fichier_in-poste ,
           v_buffer+32(1)  to itab_fichier_in-code_dc ,
           v_buffer+33(18) to itab_fichier_in-montantc ,
           v_buffer+51(18) to itab_fichier_in-montantd .
*   Allimente le code société.
    if     v_buffer+0(2) eq '04'.
      move '1614' to itab_fichier_in-societe.
    elseif v_buffer+0(2) eq '09'.
      move '2826' to itab_fichier_in-societe.
    else.
      write : /1 'Société inconnue ! traitement interrompu !' ,
                 v_buffer+0(2) .
    endif.
*   On replace la decimale sur le montant.
    itab_fichier_in-montantc = itab_fichier_in-montantc / 100.
    itab_fichier_in-montantd = itab_fichier_in-montantd / 100.
*   Enregistrement de la ligne dans la table interne ITAB_FICHIER_IN.
    append itab_fichier_in.
    clear  itab_fichier_in.
  enddo.
* Fermeture du fichier en entrée.
  close dataset v_infile.
* Trie de la table interne ITAB_FICHIER_IN.
  sort itab_fichier_in by societe poste compte centre.
endform.                               " P_LECTURE_INPUT.
*   Procédure P_TEST_DONNEE.                                           *
*   Verifie si la somme des debits est egale a la somme des credits.   *
*   Verifie si n y a pas de montant nul.                               *
*   Verifie que les differents type de piece sont equilibrés entre     *
*   eux.                                                               *
*   Force le centre de cout à 91001038 pour les comptes comptables     *
*   commencent par 481801.                                             *
form p_test_donnee.
  data : v_montantc(13) type p decimals 2 ,
         v_montantd(13) type p decimals 2 .
* Cumul les montants debit et credit.
  loop at itab_fichier_in.
    v_montantc = v_montantc + itab_fichier_in-montantc.
    v_montantd = v_montantd + itab_fichier_in-montantd.
  endloop.
* Test si debit = credit.
  if v_montantc ne v_montantd.
    skip 2.
    write : /1 'ATTENTION LE FICHIER N EST PAS EQUILIBRE !!' color 3.
    skip 2.
    write : /5 'Total montant debit  :',
               v_montantd ,
            /5 'Total montant credit :' ,
               v_montantc .
    stop.
  endif.
* Verifie s il n y a pas de montant nul. Si oui on efface.
  loop at itab_fichier_in.
    if itab_fichier_in-montantc eq space and
       itab_fichier_in-montantd eq space.
      v_nb_blanc = v_nb_blanc + 1.
      delete itab_fichier_in.
    endif.
  endloop.
* Verifie que les differents postes sont equilibrés.
  clear : v_montantc, v_montantd.
  loop at itab_fichier_in.
    v_montantc = v_montantc + itab_fichier_in-montantc.
    v_montantd = v_montantd + itab_fichier_in-montantd.
    at end of poste.
      if v_montantc ne v_montantd.
        skip 2.
        write : /1 'ATTENTION LE FICHIER N EST PAS EQUILIBRE !!'
                    color 3 ,
                /1 'Au moins un type de piece n''est pas equilibré.'.
        skip 2.
        write : /5 'Montant debit  :',
                   v_montantd ,
                /5 'Montant credit :' ,
                   v_montantc .
        stop.
      endif.
      clear : v_montantc, v_montantd.
    endat.
  endloop.
* Si le compte comptable commence par 481801 on force le centre de
* couts à 91001038.
  loop at itab_fichier_in
       where compte(6) = '481801'.
    move '91001038' to itab_fichier_in-centre.
    modify itab_fichier_in.
  endloop.
endform.                               " P_TEST_DONNEE.
*   Procédure P_CREATION_BATCH.                                        *
*   Application de regle de gestion :                                  *
*     - La date est obtenue à partir de la zone période. On prend le   *
*       dernier jour du mois indiqué dans le fichier en entrée.        *
*     - Si le poste est PR alors le type de document est AC sinon il   *
*       est SA.                                                        *
*     - Si c est un debit la clé est 40, si c est un credit 50.        *
*     - Le montant du fichier en entrée est exprimé en centime.        *
form p_creation_batch.
  data : v_totald(13)  type p decimals 2 ,   " Total debit
         v_totalc(13)  type p decimals 2 ,   " Total credit
         v_total(13)   type p decimals 2 ,   " Total general
         v_clef(2)     type n ,              " Clef 50/40
         v_montant(13) type p decimals 2 ,   " Montant temporaire
         v_flag_fin(1) type n .              " Indicateur fin piece
* Recherche de la date de fin de mois de la periode
  perform p_last_day_of_month using    v_periode
                              changing v_date.
* Recherche de la constante utilisateur sur la decimal.
  perform p_decimal.
* Boucle sur la table interne.
  loop at itab_fichier_in.
*   Compteur de poste de piece.
    v_count = v_count + 1.
*   Gestion du cumul des montants.
    if itab_fichier_in-code_dc eq 'D'.
      v_total  = v_total  + itab_fichier_in-montantd.
      v_totald = v_totald + itab_fichier_in-montantd.
    else.
      v_total  = v_total  - itab_fichier_in-montantc.
      v_totalc = v_totalc + itab_fichier_in-montantc.
    endif.
*   -= Au changement de poste. =-
    at new poste.
*     Nouvelle entete
      perform p_entete_piece using itab_fichier_in-societe
                                   itab_fichier_in-poste
                                   v_date.
*     Initialisation compteur de poste de piece.
      v_count = 1.
    endat.
*   -= A la fin du poste. =-
    at end of poste.
*     Modifie l indicateur de dernier poste.
      v_flag_fin = 1.
    endat.
*   Si c est le dernier poste de la piece on ferme...
    if v_flag_fin = 1.
      if itab_fichier_in-code_dc eq 'D'.
        move 40 to v_clef.
        perform p_fermeture_piece using v_clef
                                        itab_fichier_in-compte
                                        itab_fichier_in-centre
                                        itab_fichier_in-montantd.
      else.
        move 50 to v_clef.
        perform p_fermeture_piece using v_clef
                                        itab_fichier_in-compte
                                        itab_fichier_in-centre
                                        itab_fichier_in-montantc.
      endif.
*     Gestion de l indicateur de fin de piece.
      move 0 to v_flag_fin.
*     Gestion de la table des pieces pour l edition.
      move : itab_fichier_in-poste  to itab_piece-typepiece ,
             v_totalc               to itab_piece-montantc ,
             v_totald               to itab_piece-montantd .
      append itab_piece.
      clear : v_totalc, v_totald, itab_piece.
*   Cas normal d un poste de la piece.
    else.
*     Recherche de la clef.
      if itab_fichier_in-code_dc eq 'D'.
        move 40 to v_clef.
        perform p_poste_piece using itab_fichier_in-societe
                                    v_clef
                                    itab_fichier_in-compte
                                    itab_fichier_in-centre
                                    itab_fichier_in-montantd
                                    v_date.
      else.
        move 50 to v_clef.
        perform p_poste_piece using itab_fichier_in-societe
                                    v_clef
                                    itab_fichier_in-compte
                                    itab_fichier_in-centre
                                    itab_fichier_in-montantc
                                    v_date.
      endif.
    endif.
*   -= Poste de piece. =-
*   Si plus de 900 postes dans la piece on equilibre et on contre-passe
*   dans une nouvelle piece.
    if v_count gt 900.
*     Recherche de la clef pour l'equilibrage (inverse de la normal).
      if v_total gt 0.
        move 50 to v_clef.
        v_montant = v_total.
      elseif v_total lt 0.
        move 40 to v_clef.
        v_montant = 0 - v_total.
      endif.
*     Equilibrage.
      perform p_fermeture_piece using v_clef
                                      '2122010900'
                                      v_montant.
*     Nouvelle entete de piece.
      perform p_entete_piece using itab_fichier_in-societe
                                   itab_fichier_in-poste
                                   v_date.
*     Initialization de la variable de poste de piece.
      v_count = 1.
*     Recherche de la clef pour la contre-partie.
      if v_total gt 0.
        move 40 to v_clef.
        v_montant = v_total.
      elseif v_total lt 0.
        move 50 to v_clef.
        v_montant = 0 - v_total.
      endif.
*     Contre-partie.
      perform p_poste_piece using itab_fichier_in-societe
                                  v_clef
                                  '2122010900'
                                  v_montant
                                  v_date.
*     Gestion de la table des pieces pour l edition.
      move : itab_fichier_in-poste  to itab_piece-typepiece ,
             v_totalc               to itab_piece-montantc ,
             v_totald               to itab_piece-montantd .
      append itab_piece.
      clear : v_totalc, v_totald, itab_piece.
    endif.                  " Supperieur 900 lignes.
  endloop.
endform.                               " P_CREATION_BATCH
*   Procédure P_LAST_DAY_OF_MONTH.                                     *
*   Calcul du dernier jour du mois.                                    *
form p_last_day_of_month using    i_datum
                         changing e_tt.
  data: datmm   type i ,
        datjj   type i ,
        year(4) type n ,
        date(8) type n ,
        rest    type i ,
        zw_tt   type i .
* Initialization
  clear e_tt.
* Recherche du mois.
  datmm = i_datum+2(2).
* Nombre de jour par mois.
  case datmm.
    when 1.  zw_tt = 31.
    when 2.  zw_tt = 28.
    when 3.  zw_tt = 31.
    when 4.  zw_tt = 30.
    when 5.  zw_tt = 31.
    when 6.  zw_tt = 30.
    when 7.  zw_tt = 31.
    when 8.  zw_tt = 31.
    when 9.  zw_tt = 30.
    when 10. zw_tt = 31.
    when 11. zw_tt = 30.
    when 12. zw_tt = 31.
  endcase.
* Cas particulier du mois de fevrier.
  if datmm = 2.
    move : '20'          to year(2) ,
            i_datum+0(2) to year+2(2) .
    datjj = year.
    rest  = datjj mod 4.
    if rest = 0.
      zw_tt = 29.
    endif.
  endif.
  move : '20'         to date+4(2) ,
         i_datum+0(2) to date+6(2) ,
         i_datum+2(2) to date+2(2) ,
         zw_tt        to date+0(2) .
  e_tt = date.
endform.
*   Procédure P_ENTETE_PIECE.                                          *
*   Regles :                                                           *
*            Si le poste est PR alors le type de piece est AC, sinon   *
*            il est SA.                                                *
form p_entete_piece using v_bukrs
                          poste
                          v_date.
* Lancement ecran en-tete de piece.
  perform bdc_dynpro using 'SAPMF05A' '0100'.
* Validation.
  perform bdc_field using 'BDC_OKCODE' '/00'.
* Date de piece.
  perform bdc_field using 'BKPF-BLDAT' v_date.
* Date comptable.
  perform bdc_field using 'BKPF-BUDAT' v_date.
* Type de piece.
  if poste eq 'PR'.
    perform bdc_field using 'BKPF-BLART' 'AC'.
  else.
    perform bdc_field using 'BKPF-BLART' 'SA'.
  endif.
* Société.
  perform bdc_field using 'BKPF-BUKRS' v_bukrs.
* Devise.
  perform bdc_field using 'BKPF-WAERS' p_waers.
endform.
*   Procédure P_POSTE_PIECE.                                           *
*   En fonction de la marque de decimale choisi par l'utilisateur      *
*   on passe les ',' en '.'  ou inversement.                           *
form p_poste_piece using v_bukrs
                         v_clef
                         v_compte
                         v_centre
                         v_total
                         v_date.
  data : v_data(25) type c ,           " data temporaire pour valeurs
         v_text like bseg-sgtxt ,      " Texte du poste de la piece
         v_fdlev like skb1-fdlev.      " Niveau trésorerie
* Vérifie que le compte est traité en trésorerie.
  select single fdlev
         into v_fdlev
         from skb1
         where bukrs eq v_bukrs
         and   saknr eq v_compte.
* Gestion de la zone texte de poste de la piece.
  move : v_compte to v_text ,
         '/'      to v_text+10 ,
         v_centre to v_text+11 ,
         '/'      to v_text+19 ,
         text-001 to v_text+22 .
* Gestion zone P -> C
  move v_total to v_data.
  shift v_data left deleting leading space.
* Test la constante utilisateur marquant la decimale.
  if v_decimal eq 'X'.
    replace ',' with '.' into v_data.
  else.
    replace '.' with ',' into v_data.
  endif.
* Test s il sagit du premier poste de la piece.
  if v_count eq 1.
*   Clé de comptabilisation.
    perform bdc_field using 'RF05A-NEWBS' v_clef.
*   Compte comptable.
    perform bdc_field using 'RF05A-NEWKO' v_compte.
  else.
    perform bdc_dynpro using 'SAPMF05A' '0300'.
    perform bdc_field using 'BDC_OKCODE' '/00'.
*   Clé de comptabilisation.
    perform bdc_field using 'RF05A-NEWBS' v_clef.
*   Compte comptable.
    perform bdc_field using 'RF05A-NEWKO' v_compte.
*   Inconnu ...
    perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
*   Indique de ne pas repasser sur la saisie des centres de couts ...
    perform bdc_field using 'DKACB-FMORE' ' '.
  endif.
* Lancement ecran poste de piece.
  perform bdc_dynpro using 'SAPMF05A' '0300'.
* Validation.
  perform bdc_field using 'BDC_OKCODE' '/00'.
* Si compte gestion tresorerie alors on positionne la date.
  if v_fdlev ne space.
    perform bdc_field using 'BSEG-VALUT' v_date.
  endif.
* Montant.
  perform bdc_field using 'BSEG-WRBTR' v_data.
* Texte du poste de la piece.
  perform bdc_field using 'BSEG-SGTXT' v_text.
* Inconnu ...
  perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
* Si le centre de couts est vide on ne traite pas l ecran
* de saisie du centre de couts.
  if v_centre ne space.
*   Indique de passer sur le dynpro de saisie centre de couts ...
    perform bdc_field using 'DKACB-FMORE' 'X'.
*   Ecran de saisie des centres de couts.
*   Saisie des données du poste de la piéce.
    perform bdc_dynpro using 'SAPLKACB' '0002'.
    perform bdc_field using 'BDC_OKCODE' '/EENTE'.
*   Centre de coûts.
    perform bdc_field using 'COBL-KOSTL' v_centre.
*   Encore un inconnu ...
    perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
  else.
*   Indique de passer sur le dynpro de saisie centre de couts ...
    perform bdc_field using 'DKACB-FMORE' ' '.
  endif.
endform.
*   Procédure P_FERMETURE_PIECE.                                       *
form p_fermeture_piece using v_clef
                             v_compte
                             v_centre
                             v_total.
  data : v_data(25) type c ,           " data temporaire pour valeurs
         v_text like bseg-sgtxt.
* Gestion de la zone texte de poste de la piece.
  move : v_compte to v_text ,
         '/'      to v_text+10 ,
         v_centre to v_text+11 ,
         '/'      to v_text+19 ,
         text-001 to v_text+22 .
* Gestion zone P -> C
  move v_total to v_data.
  shift v_data left deleting leading space.
* Test la constante utilisateur marquant la decimale.
  if v_decimal eq 'X'.
    replace ',' with '.' into v_data.
  else.
    replace '.' with ',' into v_data.
  endif.
  perform bdc_dynpro using 'SAPMF05A' '0300'.
  perform bdc_field using 'BDC_OKCODE' '/00'.
* Clé de comptabilisation.
  perform bdc_field using 'RF05A-NEWBS' v_clef.
* Compte comptable.
  perform bdc_field using 'RF05A-NEWKO' v_compte.
* Inconnu ...
  perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
* Indique de ne pas repasser sur la saisie des centres de couts ...
  perform bdc_field using 'DKACB-FMORE' ' '.
  perform bdc_dynpro using 'SAPMF05A' '0300'.
  perform bdc_field using 'BDC_OKCODE' '=BU'.
* Montant.
  perform bdc_field using 'BSEG-WRBTR' v_data.
* Texte du poste de la piece.
  perform bdc_field using 'BSEG-SGTXT' v_text.
* Inconnu ...
  perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
  if v_centre ne space.
*   Indique de passer sur la saisie des centres de couts ...
    perform bdc_field using 'DKACB-FMORE' 'X'.
*   Ecran de saisie des centres de couts.
*   Saisie des données du poste de la piéce.
    perform bdc_dynpro using 'SAPLKACB' '0002'.
    perform bdc_field using 'BDC_OKCODE' '/EENTE'.
*   Centre de coûts.
    perform bdc_field using 'COBL-KOSTL' v_centre.
*   Encore un inconnu ...
    perform bdc_field using 'BDC_SUBSCR' 'SAPLKACB'.
  else.
*   Indique de ne pas repasser sur la saisie des centres de couts ...
    perform bdc_field using 'DKACB-FMORE' ' '.
  endif.
* Transfert du dossier.
  perform insert_bdc using v_t_code.
  refresh bdc_tab.
  clear bdc_tab.
endform.
*   Form OPEN_BDC                                                      *
*   Ouverture du dossier Batch-Input.                                  *
form open_bdc using v_nom_dossier.
  call function 'BDC_OPEN_GROUP'
       exporting
            client              = sy-mandt          " Numéro de mandant
            group               = v_nom_dossier     " Nom dossier batch
            keep                = 'X'               " Code
            user                = sy-uname          " Nom utilisateur
       exceptions
            client_invalid      = 1
            destination_invalid = 2
            group_invalid       = 3
            group_is_locked     = 4
            holddate_invalid    = 5
            internal_error      = 6
            queue_error         = 7
            running             = 8
            system_lock_error   = 9
            user_invalid        = 10
            others              = 11.
  if sy-subrc ne 0.
    write : /1 text-001 ,
            /1 'Erreur :' , sy-subrc.
  endif.
  refresh bdc_tab.
  clear   bdc_tab.
  exit.
endform.                       " OPEN_BDC
*   Form CLOSE_BDC                                                     *
*   Fermeture du dossier BTCI                                          *
form close_bdc.
  call function 'BDC_CLOSE_GROUP'
       exceptions
            not_open    = 1
            queue_error = 2
            others      = 3.
  if sy-subrc ne 0.
    write : /1 text-002 ,
            /1 'Erreur :' , sy-subrc.
  endif.
endform.                     " CLOSE_BDC
*   Form BDC_DYNPRO                                                    *
*   Alimentation de la ligne d'entête de BDCTAB                        *
form bdc_dynpro using value(progname)
                      value(dynpronr).
* Efface la header-line.
  clear bdc_tab.
* Insertion des valeurs.
  bdc_tab-program  = progname.
  bdc_tab-dynpro   = dynpronr.
  bdc_tab-dynbegin = 'X'.
* Enregistrement des valeurs.
  append bdc_tab.
endform.                    " BDC_DYNPRO
*   Form BDC_FIELD                                                     *
*   Traitement des enregistrements de la structure BDCTAB              *
*      --> FIELDNAME  Nom du champ                                     *
*      --> FIELDVALUE Valeur du champ                                  *
form bdc_field using value(fieldname) value(fieldvalue).
* Efface la header-line.
  clear bdc_tab.
* Insertion des valeurs.
  bdc_tab-fnam = fieldname.
  bdc_tab-fval = fieldvalue.
* Enregistrement des valeurs.
  append bdc_tab.
endform.                " BDC_FIELD
* Form BDC_CURSOR                                                      *
* Positionnement du curseur sur un champ particulier                   *
form bdc_cursor using value(fieldname) value(fieldvalue).
* Efface la header-line.
  clear bdc_tab.
* Insertion des valeurs.
  bdc_tab-fnam = fieldname.
  bdc_tab-fval = fieldvalue.
* Enregistrement des valeurs.
  append bdc_tab.
endform.              " BDC_CURSOR
*   Form  INSERT_BDC                                                   *
*   Insertion dans le dossier BTCI                                     *
*   Attention : la transaction est codée en dur                        *
form insert_bdc using t_code.
  call function 'BDC_INSERT'
       exporting
            tcode            = t_code
       tables
            dynprotab        = bdc_tab
       exceptions
            internal_error   = 1
            not_open         = 2
            queue_error      = 3
            tcode_invalid    = 4
            printing_invalid = 5
            posting_invalid  = 6
            others           = 7.
  if sy-subrc ne 0.
    write : /1 text-003 ,
            /1 'Erreur :' , sy-subrc.
  endif.
endform.                  " INSERT_BDC
*   Procédure P_DECIMAL.                                               *
form p_decimal.
* Recherche de la constante utilisateur sur la virgule decimale.
  select single dcpfm
         into v_decimal
         from usr01
         where bname eq sy-uname.
endform.
*   Procédure P_EDITION.                                               *
*   Procédure d'edition du resultat de la génération du dossier        *
*   Batch-Input.                                                       *
form p_edition.
  data : v_solde(13) type p decimals 2.
  skip 1.
  write : /1 'Comptabilisation de la paie venant de Pléïades.'.
* Le mois.
  skip 2.
  case v_periode+2(2).
    when 01.
      write : /1 'Mois : Janvier'.
    when 02.
      write : /1 'Mois : Fevrier'.
    when 03.
      write : /1 'Mois : Mars'.
    when 04.
      write : /1 'Mois : Avril'.
    when 05.
      write : /1 'Mois : Mai'.
    when 06.
      write : /1 'Mois : Juin'.
    when 07.
      write : /1 'Mois : Juillet'.
    when 08.
      write : /1 'Mois : Aout'.
    when 09.
      write : /1 'Mois : Septembre'.
    when 10.
      write : /1 'Mois : Octobre'.
    when 11.
      write : /1 'Mois : Novembre'.
    when 12.
      write : /1 'Mois : Decembre'.
  endcase.
* La date comptable.
  skip 1.
  write : /1  'Date comptable :' ,
           18 v_date+0(2) ,
           20 '/' ,
           21 v_date+2(2) ,
           23 '/' ,
           24 v_date+4(4).
* Piece SA.
  skip 2.
  write : /1  'Piece(s) SA :' ,
          /10 'Montant Debit' ,
           40 'Montant Credit' ,
           70 'Solde'.
  loop at itab_piece where typepiece ne 'PR'.
    v_solde = itab_piece-montantd - itab_piece-montantc.
    write : /1  itab_piece-montantd ,
             31 itab_piece-montantc ,
             61 v_solde.
  endloop.
* Piece AC.
  skip 2.
  write : /1  'Piece(s) AC :' ,
          /10 'Montant Debit' ,
           40 'Montant Credit' ,
           70 'Solde'.
  loop at itab_piece where typepiece eq 'PR'.
    v_solde = itab_piece-montantd - itab_piece-montantc.
    write : /1  itab_piece-montantd ,
             31 itab_piece-montantc ,
             61 v_solde.
  endloop.
  skip 4.
  write : /1 'Anomalie :' ,
          /1 'Nombre de lignes dont le montant est nul :' ,
             v_nb_blanc no-zero.
endform.