Building Field-Catalog for dynamic internal tables

Question

Hi All,
I  created a dynamic internal table(<fs_final>,<fs_final_line>)  and populated data into it.Now I want to provide field catalog to these dynamic internal table.
Can anyone suggest me the how to create a field catalog for existing dynamic internal table.Thanks in advance.
Regards,
Chakradhar.
Moderator message - Please use proper subject line in future.
Message was edited by: Suhas Saha

Answer 1

Use this code to get all components of internal table.
Then build fieldcatlog.
DATA: tab_return type abap_compdescr_tab,
          components like line of tab_return.
perform get_int_table_fields using    <fs_it> changing  tab_return.
loop at tab_return into components.
  wa_fldcat-fieldname  = components-name.               "Field Name
  wa_fldcat-scrtext_m  = components-name.              "Column Heading
  wa_fldcat-inttype    = components-type_kind.     "Data Type
  wa_fldcat-intlen      = components-length.          "Data Lenght
  wa_fldcat-decimals = components-decimals.     "Data Decimal Places
append wa_fldcat to it_fldcat.
endloop.
form get_int_table_fields  using    t_data type any table
                            changing t_return type abap_compdescr_tab.
   data:
   oref_table type ref to cl_abap_tabledescr,
   oref_struc type ref to cl_abap_structdescr,
   oref_error type ref to cx_root,
   text type string.
*Get the description of data object type
   try.
       oref_table ?=
       cl_abap_tabledescr=>describe_by_data( t_data ).
     catch cx_root into oref_error.
       text = oref_error->get_text( ).
       write: / text.
       exit.
   endtry.
*Get the line type
   try.
       oref_struc ?= oref_table->get_table_line_type( ).
     catch cx_root into oref_error.
       text = oref_error->get_text( ).
       write: / text.
       exit.
   endtry.
   append lines of oref_struc->components to t_return.
endform.
Regards
Sreekanth