Calling a webservice from Pl/SQL

Question

Hi,
I have created a function to call a webservice but I am getting the following error
ORA-20000: soap:Client - System.Web.Services.Protocols.SoapException: Server
did not recognize the value of HTTP Header SOAPAction: ConversionRate.
at System.Web.Services.Protocols.Soap11ServerProtocolHelper.RouteRequest()
at
System.Web.Services.Protocols.SoapServerProtocol.RouteRequest(SoapServerMessage
message)
at System.Web.Services.Protocols.SoapServerProtocol.Initialize()
at System.Web.Services.Protocols.ServerProtocolFactory.Create(Type type,
HttpContext context, HttpRequest request, HttpResponse response, Boolean&
abortProcessing)
ORA-06512: at "APPS.SOAP_API", line 54
ORA-06512: at "APPS.SOAP_API", line 81
ORA-06512: at "APPS.PKG_MY_WEBSERVICE", line 12
The Packages code are as follow:
CREATE OR REPLACE PACKAGE soap_api AS
TYPE t_request IS RECORD (
method VARCHAR2(256),
namespace VARCHAR2(256),
body VARCHAR2(32767),
envelope_tag VARCHAR2(30)
TYPE t_response IS RECORD
doc XMLTYPE,
envelope_tag VARCHAR2(30)
FUNCTION new_request(p_method IN VARCHAR2,
p_namespace IN VARCHAR2,
p_envelope_tag IN VARCHAR2 DEFAULT 'SOAP-ENV')
RETURN t_request;
PROCEDURE add_parameter(p_request IN OUT NOCOPY t_request,
p_name IN VARCHAR2,
p_type IN VARCHAR2,
p_value IN VARCHAR2);
FUNCTION invoke(p_request IN OUT NOCOPY t_request,
p_url IN VARCHAR2,
p_action IN VARCHAR2)
RETURN t_response;
FUNCTION get_return_value(p_response IN OUT NOCOPY t_response,
p_name IN VARCHAR2,
p_namespace IN VARCHAR2)
RETURN VARCHAR2;
END soap_api;
CREATE OR REPLACE PACKAGE BODY soap_api AS
FUNCTION new_request(p_method IN VARCHAR2,
p_namespace IN VARCHAR2,
p_envelope_tag IN VARCHAR2 DEFAULT 'SOAP-ENV')
RETURN t_request AS
l_request t_request;
BEGIN
l_request.method := p_method;
l_request.namespace := p_namespace;
l_request.envelope_tag := p_envelope_tag;
RETURN l_request;
END;
PROCEDURE add_parameter(p_request IN OUT NOCOPY t_request,
p_name IN VARCHAR2,
p_type IN VARCHAR2,
p_value IN VARCHAR2) AS
BEGIN
p_request.body := p_request.body||'<'||p_name||' xsi:type="'||p_type||'">'||p_value||'</'||p_name||'>';
END;
PROCEDURE generate_envelope(p_request IN OUT NOCOPY t_request,
          p_env IN OUT NOCOPY VARCHAR2) AS
BEGIN
p_env := '<'||p_request.envelope_tag||':Envelope xmlns:'||p_request.envelope_tag||'="http://schemas.xmlsoap.org/soap/envelope/" ' ||
'xmlns:xsi="http://www.w3.org/1999/XMLSchema-instance" xmlns:xsd="http://www.w3.org/1999/XMLSchema">' ||
'<'||p_request.envelope_tag||':Body>' ||
'<'||p_request.method||' '||p_request.namespace||' '||p_request.envelope_tag||':encodingStyle="http://schemas.xmlsoap.org/soap/encoding/">' ||
p_request.body ||
'</'||p_request.method||'>' ||
'</'||p_request.envelope_tag||':Body>' ||
'</'||p_request.envelope_tag||':Envelope>';
END;
PROCEDURE show_envelope(p_env IN VARCHAR2) AS
i PLS_INTEGER;
l_len PLS_INTEGER;
BEGIN
i := 1; l_len := LENGTH(p_env);
WHILE (i <= l_len) LOOP
DBMS_OUTPUT.put_line(SUBSTR(p_env, i, 60));
i := i + 60;
END LOOP;
END;
PROCEDURE check_fault(p_response IN OUT NOCOPY t_response) AS
l_fault_node XMLTYPE;
l_fault_code VARCHAR2(256);
l_fault_string VARCHAR2(32767);
BEGIN
l_fault_node := p_response.doc.extract('/'||p_response.envelope_tag||':Fault',
'xmlns:'||p_response.envelope_tag||'="http://schemas.xmlsoap.org/soap/envelope/');
IF (l_fault_node IS NOT NULL) THEN
l_fault_code := l_fault_node.extract('/'||p_response.envelope_tag||':Fault/faultcode/child::text()',
'xmlns:'||p_response.envelope_tag||'="http://schemas.xmlsoap.org/soap/envelope/').getstringval();
l_fault_string := l_fault_node.extract('/'||p_response.envelope_tag||':Fault/faultstring/child::text()',
'xmlns:'||p_response.envelope_tag||'="http://schemas.xmlsoap.org/soap/envelope/').getstringval();
RAISE_APPLICATION_ERROR(-20000, l_fault_code || ' - ' || l_fault_string);
END IF;
END;
FUNCTION invoke(p_request IN OUT NOCOPY t_request,
p_url IN VARCHAR2,
p_action IN VARCHAR2)
RETURN t_response AS
l_envelope VARCHAR2(32767);
l_http_request UTL_HTTP.req;
l_http_response UTL_HTTP.resp;
l_response t_response;
BEGIN
generate_envelope(p_request, l_envelope);
show_envelope(l_envelope);
l_http_request := UTL_HTTP.begin_request(p_url, 'POST','HTTP/1.1');
UTL_HTTP.set_header(l_http_request, 'Content-Type', 'text/xml');
UTL_HTTP.set_header(l_http_request, 'Content-Length', LENGTH(l_envelope));
UTL_HTTP.set_header(l_http_request, 'SOAPAction', p_action);
UTL_HTTP.write_text(l_http_request, l_envelope);
l_http_response := UTL_HTTP.get_response(l_http_request);
UTL_HTTP.read_text(l_http_response, l_envelope);
UTL_HTTP.end_response(l_http_response);
l_response.doc := XMLTYPE.createxml(l_envelope);
l_response.envelope_tag := p_request.envelope_tag;
l_response.doc := l_response.doc.extract('/'||l_response.envelope_tag||':Envelope/'||l_response.envelope_tag||':Body/child::node()',
'xmlns:'||l_response.envelope_tag||'="http://schemas.xmlsoap.org/soap/envelope/"');
-- show_envelope(l_response.doc.getstringval());
check_fault(l_response);
RETURN l_response;
END;
FUNCTION get_return_value(p_response IN OUT NOCOPY t_response,
p_name IN VARCHAR2,
p_namespace IN VARCHAR2)
RETURN VARCHAR2 AS
BEGIN
RETURN p_response.doc.extract('//'||p_name||'/child::text()',p_namespace).getstringval();
END;
END soap_api;
SHOW ERRORS
CREATE OR REPLACE PACKAGE pkg_my_webservice IS
FUNCTION call_myfunction(vp_parameter1 VARCHAR2,vp_parameter2 VARCHAR2) RETURN VARCHAR2;
END pkg_my_webservice;
CREATE OR REPLACE PACKAGE BODY pkg_my_webservice IS
vg_funciton_fnc VARCHAR2(256):='ConversionRate';
vg_ws_address VARCHAR2(255):='http://www.webservicex.net/CurrencyConvertor.asmx';
FUNCTION call_myfunction(vp_parameter1 VARCHAR2,vp_parameter2 VARCHAR2)
RETURN VARCHAR2 AS
ol_req soap_api.t_request;
ol_resp soap_api.t_response;
BEGIN
ol_req:=soap_api.new_request(vg_funciton_fnc,'xmlns="'||vg_ws_address||'"');
soap_api.add_parameter(ol_req,'string1','partns:string',vp_parameter1);
soap_api.add_parameter(ol_req,'string2','partns:string',vp_parameter1);
ol_resp:=soap_api.invoke(ol_req,vg_ws_address,vg_funciton_fnc);
RETURN soap_api.get_return_value(ol_resp,'result','xmlns:m="'||vg_ws_address||'"');
END call_myfunction;
END pkg_my_webservice;
-----------------------------------------------------------------------------------------------------------------------------------

Answer 1

Hi,
The soap_api package internally uses the utl_http api. I used the utl_http package directly and it works for me. Below is the code for the call, you will have to substitute the variables to suit your setup..
Hope this Helps
Thanks
CREATE OR REPLACE FUNCTION get_webservice_dets(p_emp_number IN VARCHAR2
,p_eff_date IN DATE)
RETURN VARCHAR2
IS
lc_proc VARCHAR2(50) := 'get_webservice_dets';
ln_error_stg NUMBER := 0;
lc_eff_date VARCHAR2(50) := NULL;
soap_request VARCHAR2(32767);
soap_respond VARCHAR2(32767);
-- HTTP variables
req utl_http.req;
resp utl_http.resp;
-- Store the Webservice URL in a Profile Option and change for each environment
lc_wsdl_url VARCHAR2(32767) := FND_PROFILE.VALUE('XXERP_WEBSRVC_URL');
-- return Values
lc_retval VARCHAR2(32767);
lc_response VARCHAR2(32767);
lc_xml_ext_str VARCHAR2(100) := '/env:Envelope/env:Body/OutputParameters/';
lc_xml_ext_unit VARCHAR2(50) := '/text()';
lc_xmlns_ns1_url VARCHAR2(240) := 'xmlns:ns1="http://xmlns.oracle.com/pcbpel/adapter/db/APPS/XXERP_SOA_HCM_PKG/GET_SUPERVISOR_NO/"';
lc_xmlns_env_url VARCHAR2(240) := 'xmlns:env="http://schemas.xmlsoap.org/soap/envelope/"';
lc_xmlns_xsi_url VARCHAR2(240) := 'xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"';
lc_xmlns_url VARCHAR2(240) := 'xmlns="http://xmlns.oracle.com/pcbpel/adapter/db/APPS/XXERP_SOA_HCM_PKG/GET_SUPERVISOR_NO/"';
lc_xml_namespace VARCHAR2(5000) := lc_xmlns_env_url||' '||lc_xmlns_xsi_url||' '||lc_xmlns_url;
lc_xmlns_soap_url VARCHAR2(240) := 'xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"';
lx_Response XMLTYPE;
BEGIN
ln_error_stg := 10;
IF NVL(lc_wsdl_url,'X') <> 'X' THEN
-- Format the date received as required by the Webservice i.e. - 'YYYY-MM-DDTHH:MI:SS+01:00'
lc_eff_date := REPLACE(TRIM(TO_CHAR(TRUNC(p_eff_date),'YYYY-MM-DD HH:MI:SS')),' ','T')||'+01:00';
-- Form a SOAP Envelope - Exact envelope can be obtained by invoking the above EndPoint URL in a browser session with required
-- parameters and then clicking on the XML Source
soap_request:= '<soap:Envelope '||lc_xmlns_soap_url||'>
<soap:Body '||lc_xmlns_ns1_url||'>
<ns1:InputParameters>
<ns1:P_EMPLOYEE_NUMBER>'||p_emp_number||'</ns1:P_EMPLOYEE_NUMBER>
<ns1:P_DATE>'||lc_eff_date||'</ns1:P_DATE>
</ns1:InputParameters>
</soap:Body>
</soap:Envelope>';
-- Initiate the HTTP request, don't forget to pass in the POST and HTTP/1.1
req := UTL_HTTP.BEGIN_REQUEST(lc_wsdl_url, 'POST','HTTP/1.1');
ln_error_stg := 20;
-- Set the HTTP Request Headers
UTL_HTTP.SET_HEADER(req, 'Content-Type', 'text/xml'); -- since we are dealing with plain text in XML documents
ln_error_stg := 40;
UTL_HTTP.SET_HEADER(req, 'Content-Length', LENGTH(soap_request));
ln_error_stg := 50;
-- Set the SOAP Action to the Operation Name
-- The function Name <getSupervisorID> should match the Webservice Operation Name in SOA
UTL_HTTP.SET_HEADER(req, 'SOAPAction','getSupervisorID'); -- required to specify this is a SOAP communication
ln_error_stg := 60;
-- Append the SOAP Envelope to the HTTP request Header
UTL_HTTP.WRITE_TEXT(req, soap_request);
ln_error_stg := 70;
-- Fetch the HTTP response from the Webservice - This will contain the SOAP Envelope response
-- that needs to be processed downstream
resp := UTL_HTTP.GET_RESPONSE(req);
ln_error_stg := 80;
-- Extract the HTTP response and store in a String Variable
-- READ_TEXT is a specific method exposed to read the SOAP envelope returned from Webservice
-- READ_LINE will read the entire HTML response back from the Server..
UTL_HTTP.READ_TEXT(resp, lc_retval);
ln_error_stg := 90;
-- Create an XML Document from the String returned by the HTTP response..
lx_Response := SYS.XMLTYPE.CREATEXML(lc_retval);
ln_error_stg := 110;
-- If the response is not null then extract the string value of the required output parameter
-- the env: tag needs to be qualified with a corresponding namespace.
IF lx_Response IS NOT NULL THEN
lc_response := lx_Response.extract(lc_xml_ext_str||'PERSON_ID'||lc_xml_ext_unit,lc_xml_namespace).getstringval();
ELSE
DBMS_OUTPUT.PUT_LINE('XMLTYPE Doc returns NULL !!');
lc_response := NULL;
END IF;
ln_error_stg := 120;
-- End the response, otherwise you get
-- UTL_HTTP.TOO_MANY_REQUESTS exception after 5 tries
UTL_HTTP.END_RESPONSE(resp);
ELSE
DBMS_OUTPUT.PUT_LINE('Web Service URL not populated, please provide a value for the Profile Option XXERP: Web Service URL');
lc_response := NULL;
END IF;
RETURN lc_response;
EXCEPTION
WHEN UTL_HTTP.TOO_MANY_REQUESTS THEN
UTL_HTTP.END_RESPONSE(resp);
RETURN NULL;
WHEN UTL_HTTP.END_OF_BODY THEN
UTL_HTTP.END_RESPONSE(resp);
RETURN NULL;
WHEN OTHERS THEN
DBMS_OUTPUT.PUT_LINE('ERROR @'||ln_error_stg||': '||SQLERRM);
UTL_HTTP.END_RESPONSE(resp);
RETURN NULL;
END get_webservice_dets;