Can a Compiled and saved AppleScript File be modified?

Question

What I mean is, If i were to create an AppleScript file with default variable, functions etc. Could I,say sometime in the future, edit those variables dynamically?
So for example, I have a script file that customizes an XCode project and  creates an .app file and an .ipa file. Would it be possible to edit the Applescript file, thereby generating a new .app and .ipa file?
Send  Parameters to -----> Default AppleScipt file ---> Modified AppleScript File ----> New .app and .ipa File

Answer 1

Hello
You can use "load script" command and modify the properties of loaded script. Something like this:
    [1] a.scpt is assumed to be coded :
property p : 0
tell application "SystemUIServer"
    activate
    display dialog "p = " & p
end tell
    [2] When b.scpt is opened in AppleScript Editor, decompiled source shows exactly the same as a.scpt
        although its property p's current value is not 0 but 1 as set in this script.
        In other words, decompiled source code shows static value as defined in source code
        whilst the loaded script stores and uses dynamic value at runtime.
-- load script
set f to (path to desktop)'s POSIX path & "a.scpt" -- [1]
set o to load script POSIX file f
-- run it (p = 0)
tell o to run
-- modify it
set o's p to 1
-- run it (p = 1)
tell o to run
-- store modified script to new file
set f1 to (path to desktop)'s POSIX path & "b.scpt" -- [2]
store script o in POSIX file f1 with replacing
-- load modified script from file
set o1 to load script POSIX file f1
-- run it (p = 1)
tell o1 to run
If you want to modify the source code, you may use osadecompile(1) and osacompile(1). Something like this:
#!/bin/bash
cd ~/desktop || exit
osadecompile a.scpt | perl -CSDA -lpe 's/property p : 0/property p : 2/' | osacompile -o c.scpt
osascript c.scpt
Or to run modified script without saving:
#!/bin/bash
cd ~/desktop || exit
osadecompile a.scpt | perl -CSDA -lpe 's/property p : 0/property p : 2/' | osascript -
* The above is true for plain AppleScript script. Don't know about AppleScriptObjC script. Also in recent OSes, applet might need to be re-signed after modification.
Regards,
H