Can I bulk edit data for contacts in Maverick?

Question

Hello Community - First time poster!  This seems like a common problem, but I can't find any info on the boards.
A company moved and I need to change the phone and address for all of the employees there in my contacts. However, it's a big company and there are hundreds of employees so doing this one-by-one isn't feasible.
Is there a way - perhaps with Automator? Or Apple Script?  To change them all at once?
Also, my contacts are saved on gmail, not on my hard drive but I can import/export them in/out if that solves the problem.
Does anyone have a quick fix for such a simple problem?
Many thanks!
- Grace

Answer 1

Here's what I came up with. Tested a little, so make sure you have a backup.
It will ask you for the new address, then change all the work addresses of the selected contacts.
Open Applescript Editor and create a new Application.
Paste in this script and save it. When you need to change a company address, select all the contacts that need to be changed and run the application.
-- get new address
set newStreet to text returned of (display dialog "Enter new Street Address" default answer "" buttons {"Cancel", "Enter"} default button "Enter")
if newStreet is not "" then
          set newCity to text returned of (display dialog "Enter new City" default answer "" buttons {"Cancel", "Enter"} default button "Enter")
          if newCity is not "" then
                    set newState to text returned of (display dialog "Enter new State" default answer "" buttons {"Cancel", "Enter"} default button "Enter")
                    if newState is not "" then
                              set newZip to text returned of (display dialog "Enter new Zip" default answer "" buttons {"Cancel", "Enter"} default button "Enter")
                              if newZip is not "" then
  -- all values entered, but not validated
                                        tell application "Contacts"
                                                  set thePeople to selection
                                                  repeat with aPerson in thePeople
                                                            set workAddress to {}
                                                            set theAddresses to (the addresses of aPerson)
                                                            repeat with anAddress in theAddresses
  -- if there are multiple work addresses, this will change the last
                                                                      if the label of anAddress is "work" then
                                                                                set workAddress to anAddress
                                                                      end if
                                                            end repeat
                                                            if workAddress is {} then
  -- no work address found, create new
                                                                      set workAddress to make new address at end of addresses of aPerson with properties {label:"work", street:newStreet, city:newCity, state:newState, zip:newZip}
                                                            else
  -- change existing work address
                                                                      set properties of workAddress to {label:"work", street:newStreet, city:newCity, state:newState, zip:newZip}
                                                            end if
                                                  end repeat
                                                  save
                                        end tell
                              end if
                    end if
          end if
end if