"Can't get folder 'a'" Error with Applescript

Question

Here is my complete applescript application. I am supposed to select a series folder, and it goes into the folder and for each season folder does something inside, including grabbing the name of the season folder. But it keep throwing an error on the line set folderName to name of folder aFolder saying it can't get name of folder "a", but the only folders inside the folder I select are Season 1, Season 2, and Season 3. Additionally, looking at the replies part of the script editor it looks like it does "M" first with no errors, and they goes to "a". I have no idea where this is coming from so help me if you can. Disregard the weird formatting, copying everything from the script editor into here messed everything up. Thanks.
set seriesFolder to (choose folder with prompt "Select TV Series Folder") as text
tell application "Finder" to set tvName to "list of " & (name of folder seriesFolder as text) & " episodes"
openWebpage(tvName)
repeat with aFolder in seriesFolder
  tell application "Finder"
  set folderName to name of folder aFolder
  set whichFile to every file of folder aFolder
  sort whichFile by name
  end tell
  set sNumber to "0" & ((characters -1 thru -1 of folderName) as string)
  set epNum to 1
  repeat with aFile in whichFile
  if epNum is less than 10 then
  set ifZero to "0"
  else
  set ifZero to ""
  end if
  set textBox to "What is episode title for S" & (sNumber as string) & "E" & ifZero & epNum & "?"
  tell application "Finder"
  set filename to name of aFile
  set nameEnding to ((characters -4 thru -1 of filename) as string)
  display dialog textBox default answer ""
  set text_returned to text returned of result
  set name of aFile to "S" & (sNumber as string) & "E" & ifZero & (epNum as string) & " - " & text_returned & nameEnding
  end tell
  set epNum to epNum + 1
  end repeat
end repeat
on openWebpage(input)
  set seriesName to input
  set needle to " "
  set replacement to "+"
  set searchName to search_replace(seriesName, needle, replacement)
  set address to "http://www.en.wikipedia.org/w/index.php?search=" & searchName & "&title=Special%3ASearch&go=Go"
  tell application "Safari" to open location address
end openWebpage
on search_replace(seriesName, needle, replacement)
  set old_delimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to needle
  set temp_list to every text item of seriesName
  set AppleScript's text item delimiters to replacement
  set return_value to temp_list as text
  set AppleScript's text item delimiters to old_delimiters
  return return_value
end search_replace

Answer 1

Try replacing the beginning of the script with:
set seriesFolder to (choose folder with prompt "Select TV Series Folder")
tell application "Finder"
set tvName to "list of " & (name of folder seriesFolder as text) & " episodes"
tell me to openWebpage(tvName)
repeat with aFolder in (get folders of seriesFolder)
set folderName to name of aFolder
(109908)