Color of grid's row depending on it's content

Question

Hi. I'd like to ask You how to deretmine color of single grid's row? I have such situation that some records of itab have 2 fields equal, and consequently should be displayed in fifferent color. Could You give me some tips how to solve that? Greetings. P.

Answer 1

Hi ,
Check the below example .. u may get some idea.
* Macro definition
DEFINE m_fieldcat.
  add 1 to ls_fieldcat-col_pos.
  ls_fieldcat-fieldname   = &1.
  ls_fieldcat-ref_tabname = &2.
  append ls_fieldcat to lt_fieldcat.
END-OF-DEFINITION.
TYPE-POOLS: slis.                      " ALV Global types
TYPES:
  BEGIN OF ty_vbak,
    vkorg TYPE vbak-vkorg,             " Sales organization
    kunnr TYPE vbak-kunnr,             " Sold-to party
    vbeln TYPE vbak-vbeln,             " Sales document
    netwr TYPE vbak-netwr,             " Net Value of the Sales Order
    line_color(4),                     " Line color
  END OF ty_vbak.
DATA:
* Data displayed
  gt_vbak TYPE TABLE OF ty_vbak.
START-OF-SELECTION.
  PERFORM f_read_data.
  PERFORM f_fill_color.
  PERFORM f_display_data.
*      Form  f_read_data
FORM f_read_data.
  SELECT * INTO CORRESPONDING FIELDS OF TABLE gt_vbak
           FROM vbak UP TO 100 ROWS.
ENDFORM.                               " F_READ_DATA
*      Form  f_fill_color
FORM f_fill_color.
  DATA l_rnd_value TYPE integer2.
  FIELD-SYMBOLS <vbak> TYPE ty_vbak.
  LOOP AT gt_vbak ASSIGNING <vbak>.
*   Random value
    CALL FUNCTION 'RANDOM_I2'
      EXPORTING
        rnd_min   = 0
        rnd_max   = 3
      IMPORTING
        rnd_value = l_rnd_value.
    CASE l_rnd_value.
      WHEN 0.
        <vbak>-line_color = 'C100'.   " Blue.
      WHEN 1.
        <vbak>-line_color = 'C300'.   " Yellow.
      WHEN 2.
        <vbak>-line_color = 'C500'.   " Green.
      WHEN 3.
        <vbak>-line_color = 'C600'.   " Red.
    ENDCASE.
  ENDLOOP.
ENDFORM.                               " F_FILL_COLOR
*      Form  f_display_data
FORM f_display_data.
  DATA:
    ls_layout   TYPE slis_layout_alv,
    ls_fieldcat TYPE slis_fieldcat_alv,
    lt_fieldcat TYPE slis_t_fieldcat_alv.
* Build the field catalog
  m_fieldcat 'VKORG' 'VBAK'.
  m_fieldcat 'KUNNR' 'VBAK'.
  m_fieldcat 'VBELN' 'VBAK'.
  m_fieldcat 'NETWR' 'VBAK'.
* Fill Layout - Name of the field with color
  ls_layout-info_fieldname = 'LINE_COLOR'.
* Display the list
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      is_layout   = ls_layout
      it_fieldcat = lt_fieldcat
    TABLES
      t_outtab    = gt_vbak.
ENDFORM.
Reward Points if it is Useful.
Thanks,
Manjunath MS