Compile Invalid Objects

Question

Hi friends,
how do i compile all the invalid objects in one time ???
thanks,
Raj

Answer 1

Hi,
Here's what I do when I need to recompile a user's schema. Don't say it's bullet proof, but so far it has worked for me. I use it after each deployment to a schema.
procedure recompile_schema
is
   l_type   user_objects.object_type%type;
   l_name   user_objects.object_name%type;
   l_stat   user_objects.status%type;
   compile_error exception;
   pragma exception_init(compile_error, -24344);
   cursor dep_cur
   is
          select object_id
            from (select o1.object_id
                        ,o1.object_name
                        ,o1.object_type
                        ,o1.status
                        ,d1.referenced_name
                        ,d1.referenced_type
                        ,case
                            when exists (select null
                                           from user_dependencies d2
                                          where d2.referenced_name = d1.name
                                            and d2.referenced_type = d1.type)
                            then
                               1
                            else
                               0
                         end
                            is_referenced
                    from user_dependencies d1, user_objects o1
                   where o1.object_type in
                               ('PACKAGE'
                               ,'PROCEDURE'
                               ,'FUNCTION'
                               ,'PACKAGE BODY'
                               ,'VIEW'
                               ,'MATERIALIZED VIEW'
                               ,'TRIGGER'
                               ,'SYNONYM')
                     and d1.name = o1.object_name
                     and d1.type = o1.object_type)
           where is_referenced = 1
      start with is_referenced = 0
      connect by object_name = prior referenced_name
             and object_type = prior referenced_type
        group by object_id
        order by max(level) desc, object_id;
   procedure do_compile(pi_object_type   in user_objects.object_type%type
                       ,pi_object_name   in user_objects.object_name%type)
   is
   begin
      --dbms_output.put_line('Compiling: ' || pi_object_name);
      if pi_object_type = 'PACKAGE BODY'
      then
         exe('ALTER PACKAGE ' || pi_object_name || ' COMPILE BODY');
      else
         exe('ALTER ' || pi_object_type || ' ' || pi_object_name || ' COMPILE');
      end if;
   exception
      when compile_error
      then
         dbms_output.put_line(sqlerrm);
   end do_compile;
begin
   dbms_output.put_line('recompiling invalid objects in schema ' || user);
   -- loop through all objects in order of dependancy.
   for rec in dep_cur
   loop
      -- select the objects attributes (type, name and status).
      select object_type, object_name, status
        into l_type, l_name, l_stat
        from user_objects
       where object_id = rec.object_id;
      -- if the object is invalid, recompile it.
      if l_stat = 'INVALID'
      then
         dbms_output.put_line('Compiling(1): ' || l_name);
         do_compile(l_type, l_name);
      end if;
   end loop;
   -- Recompile all remaining INVALID OBJECTS (all those without dependencies).
   for rec
   in (select object_type, object_name
         from user_objects
        where status = 'INVALID'
          and object_type in
                    ('PACKAGE'
                    ,'PROCEDURE'
                    ,'FUNCTION'
                    ,'TRIGGER'
                    ,'PACKAGE BODY'
                    ,'VIEW'
                    ,'MATERIALIZED VIEW'
                    ,'TRIGGER'
                    ,'SYNONYM'))
   loop
      dbms_output.put_line('Compiling(2): ' || rec.object_name);
      do_compile(rec.object_type, rec.object_name);
   end loop;
end recompile_schema;Regards
Peter