Conflicting OnLoad javascript functions

Question

I am trying to implement two solutions in my application
1) Controlling window scroll position on a submit and redirect to the same page
which I have working successfully as per thread
Control window scroll position on a submit and redirect to the same page
This solution has the following code in the PAGE HTML Body Attribute
onload="javascript:ScrollIt()" onscroll="javascript:setcoords()"
I have 2 items on each page which hold the X,Y co-ords as I scroll. When the page reloads I return to these co-ords in the ScrollIt() onload process.
2) Sticky Hide and Show Regions as described in the instructions At
http://www.oracle.com/technology/products/database/application_express/packaged_apps/sample_code.html
It uses an onload Application process that calls the packaged proc
show_hide_memory.show_hide_collection_output();
In the proc the following javascript is called:
htp.prn('window.onload=function()
PROBLEM: I can't get both working at the same time! I'm assuming that the OnLoad proc is overriding that other one.
Any help please would be appreciated...
regards
Paul P

Answer 1

Hello,
Compile this as the Package Body. I will update the packaged code change in the next day or so.
create or replace PACKAGE BODY show_hide_memory AS
  PROCEDURE show_hide_collection AS
  l_arr apex_application_global.vc_arr2;
  l_found boolean := FALSE;
  l_collection_name VARCHAR2(255) := 'SHOW_HIDE_COLLECTION';
  BEGIN
    IF(wwv_flow_collection.collection_exists(p_collection_name => l_collection_name) = FALSE) THEN
      htmldb_collection.create_or_truncate_collection(p_collection_name => l_collection_name);
    END IF;
    l_arr := apex_util.string_to_table(p_string => v('TEMPORARY_ITEM'),   p_separator => ']');
    -- If the array member count of l_arr < 3, then the following code will raise an exception
    FOR c1 IN
      (SELECT seq_id
       FROM apex_collections
       WHERE collection_name = l_collection_name
       AND c001 = l_arr(1)
       AND c002 = l_arr(2)
       AND c003 = l_arr(3))
    LOOP
      -- It exists, so delete it
      apex_collection.delete_member(p_collection_name => l_collection_name,   p_seq => c1.seq_id);
      l_found := TRUE;
    END LOOP;
    IF l_found = FALSE THEN
      apex_collection.add_member(p_collection_name => l_collection_name,   p_c001 => l_arr(1),   p_c002 => l_arr(2),   p_c003 => l_arr(3));
    END IF;
    COMMIT;
  END show_hide_collection;
  PROCEDURE show_hide_collection_output AS
  BEGIN
    htp.prn('<script type="text/javascript">' || CHR(10));
    htp.prn('<!--' || CHR(10));
    htp.prn('function pg(){' || CHR(10));
    FOR c1 IN
      (SELECT c003
       FROM apex_collections
       WHERE collection_name = 'SHOW_HIDE_COLLECTION'
       AND c001 = wwv_flow.g_flow_id
       AND c002 = wwv_flow.g_flow_step_id)
    LOOP
      htp.prn('htmldb_ToggleWithImage(''' || c1.c003 || 'img'',''' || c1.c003 || 'body'');' || CHR(10));
    END LOOP;
    htp.prn('}' || CHR(10));
    htp.prn('addLoadEvent(pg)' || CHR(10));
    htp.prn('//-->' || CHR(10));
    htp.prn('</script>' || CHR(10));
  END show_hide_collection_output;
END;Carl