Creating layouts in ALV report

Question

Hi all,
I have created a report when a user creates a layout in the report it should save the variant(layout) and display in the selection-screen with alv_variant and search help.Its working properly.
But I have to create different layouts like the following:
Layout with sort and subtotals,
layout with sort and filter conditions like that.
Can anybody help me regarding this matter.
with regards
chandu

Answer 1

Sai,
Here is a little sample program which shows you how to recall saved ALV Layouts. It requires the user to run the report, create their own variants, and this program allwos them to recall it from the selection screen.
You can create gobal layouts (for your sorts, and totals) which canbe accessed by any user.
Hope this helps.
Cheers,
Pat.
*& Report  ZPATS_ALV                                                   *
REPORT  zpats_alv                     .
TABLES: kna1.
TYPE-POOLS: kkblo.
* structures *
DATA: st_fieldcat TYPE slis_fieldcat_alv.
DATA: st_variant1 LIKE disvariant.
DATA: st_variant2 LIKE disvariant.
* internal tables *
DATA: BEGIN OF tbl_kna1 OCCURS 0,
  kunnr LIKE kna1-kunnr,
  name1 LIKE kna1-name1,
  stras LIKE kna1-stras,
  telf1 LIKE kna1-telf1,
  ort01 LIKE kna1-ort01,
  pstlz LIKE kna1-pstlz,
  sortl LIKE kna1-sortl,
  ernam LIKE kna1-ernam,
  spras LIKE kna1-spras,
END OF tbl_kna1.
DATA: tbl_fieldcat TYPE slis_t_fieldcat_alv.
* global variables *
DATA: fieldname(30) TYPE c.
DATA: variant_exit(1) TYPE c,
      variant_save(1) TYPE c,
      variant_def(1)  TYPE c.
* Seelction Screen
PARAMETERS:      p_vari     LIKE disvariant-variant.
* Initialization Event
INITIALIZATION.
  PERFORM variant_init USING st_variant1.
  st_variant2 = st_variant1.
  CALL FUNCTION 'REUSE_ALV_VARIANT_DEFAULT_GET'
       EXPORTING
            i_save     = 'A'
       CHANGING
            cs_variant = st_variant2
       EXCEPTIONS
            not_found  = 2.
  IF sy-subrc = 0.
    p_vari = st_variant2-variant.
  ENDIF.
* At Selection Screen On Value Request
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_vari.
  PERFORM f4_for_variant.
* Start of Selection Event
START-OF-SELECTION.
  SELECT kunnr name1 stras telf1 ort01 pstlz sortl ernam spras
         INTO CORRESPONDING FIELDS OF TABLE tbl_kna1
         FROM kna1.
* End of Selection Event
END-OF-SELECTION.
  PERFORM get_fieldcat.
  PERFORM create_report.
*&      Form  get_fieldcat
*       text
*  -->  p1        text
*  <--  p2        text
FORM get_fieldcat.
  PERFORM write_fieldcat USING 'KUNNR' 'X' 1.
  PERFORM write_fieldcat USING 'NAME1' 'X' 2.
  PERFORM write_fieldcat USING 'STRAS' ' ' 3.
  PERFORM write_fieldcat USING 'TELF1' ' ' 4.
  PERFORM write_fieldcat USING 'ORT01' ' ' 5.
  PERFORM write_fieldcat USING 'PSTLZ' ' ' 6.
  PERFORM write_fieldcat USING 'SORTL' ' ' 7.
  PERFORM write_fieldcat USING 'ERNAM' ' ' 8.
  PERFORM write_fieldcat USING 'SPRAS' ' ' 9.
ENDFORM.                    " get_fieldcat
*&      Form  write_fieldcat
*       text
*      -->P_0060   text
*      -->P_0061   text
*      -->P_0062   text
*      -->P_0063   text
*      -->P_1      text
FORM write_fieldcat USING    name
                             key
                             pos.
  st_fieldcat-fieldname   = name.
  st_fieldcat-tabname     = 'TBL_KNA1'.
  st_fieldcat-ref_tabname = 'KNA1'.
  st_fieldcat-key         = key.
  st_fieldcat-col_pos     = pos.
  IF name = 'PSTLZ'.
    st_fieldcat-row_pos = '2'.
  ENDIF.
  APPEND st_fieldcat TO tbl_fieldcat.
  CLEAR st_fieldcat.
ENDFORM.                    " write_fieldcat
*&      Form  create_report
*       text
*  -->  p1        text
*  <--  p2        text
FORM create_report.
  CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
       EXPORTING
            i_interface_check       = ' '
            i_callback_program      = 'ZPATS_ALV'
            i_callback_user_command = 'USER_COMMANDS'
            it_fieldcat             = tbl_fieldcat
            i_default               = 'X'
            i_save                  = 'A'
            is_variant               = st_variant2
       TABLES
            t_outtab                = tbl_kna1
       EXCEPTIONS
            program_error           = 1
            OTHERS                  = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    " create_report
*&      Form  USER_COMMANDS
*       text
*  -->  p1        text
*  <--  p2        text
FORM user_commands USING syst-ucomm LIKE syst-ucomm
                         selfield TYPE slis_selfield.
  CASE syst-ucomm.
    WHEN '&IC1'.
      READ TABLE tbl_kna1 INDEX selfield-tabindex.
      SET PARAMETER ID 'KUN' FIELD tbl_kna1-kunnr.
      CALL TRANSACTION 'XD03' AND SKIP FIRST SCREEN.
    WHEN OTHERS.
  ENDCASE.
ENDFORM.                    " USER_COMMANDS
*&      Form  VARIANT_INIT
FORM variant_init USING g_variant LIKE disvariant.
* Initialise the Variant Structure
  CLEAR g_variant.
  g_variant-report = sy-repid.
ENDFORM.                               " VARIANT_INIT
*&      Form  f4_for_variant
FORM f4_for_variant.
  CLEAR st_variant1.
  st_variant1-report = sy-repid.
  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
       EXPORTING
            is_variant = st_variant1
            i_save     = 'A'
       IMPORTING
            e_exit     = variant_exit
            es_variant = st_variant2.
  IF variant_exit = space.
    p_vari = st_variant2-variant.
  ENDIF.
ENDFORM.                    " f4_for_variant