Cursor with IN CLAUSE in PACKAGE

Question

Hi
Hope someone can help and I'm really not sure why Oracle makes it so difficult.
To simplify, I have a package that takes an associative table - tabStr = {a,b,c}
as input.Based on this, it build a string variable varStr which is of type 'a','b','c'
I need to return a ref cursor
OPEN out_refCur for select * from tab where col in (varStr)
If I hardcode - varStr than out_refCur return data.
But the above does not.
I'm open to using even tabStr but could not find any example.
Any inputs? Please ignore syntax .... since that not the issue.
Thanks in advance

Answer 1

Declare a nested table collection in the procedure. SQL can query these and not associative arrays. Loop through the associative array copying each value into a corresponding element in the collection. Use the collection in the query. Very rough example:
DECLARE
    TYPE aa IS TABLE OF INTEGER INDEX BY PLS_INTEGER;
    p_batch_numbers AA;  -- This would be your parameter array
    i PLS_INTEGER; -- := p_batch_numbers.FIRST;
    v_batch_numbers_coll INTEGER_TT := INTEGER_TT();  -- Type defined with CREATE TYPE
BEGIN
    -- Sample values:
    p_batch_numbers(1) := 7369;
    p_batch_numbers(2) := 7521;
    p_batch_numbers(3) := 7839;
    -- Copy values into queriable collection:
    i := p_batch_numbers.FIRST;
    WHILE i IS NOT NULL LOOP
        v_batch_numbers_coll.EXTEND;
        v_batch_numbers_coll(v_batch_numbers_coll.COUNT) := p_batch_numbers(i);
        i := p_batch_numbers.NEXT(i);
    END LOOP;
    -- Cursor that uses the collection:
    FOR r IN (
        SELECT empno, ename FROM emp
        WHERE  empno IN
               ( SELECT column_value
                 FROM   TABLE(v_batch_numbers_coll) )
    LOOP
        DBMS_OUTPUT.PUT_LINE(r.empno || ': ' || r.ename);
    END LOOP;
END;
/