Database SQL SAP B1

Question

Good morning,
Anyone know what query is used to display only the databases of SAP B1 without showing the others that are in SQL Server?
Thank's

Answer 1

Hi Andres,
When you click on the Refresh button in the Choose Company screen in SBO, the system runs a check against all databases on the SQL Server and looks for a CINF table in each database. If CINF exists then SBO assumes the database is a SBO database. The queries suggested above should work fine most of the time but if you want to perform the same check that SBO uses then the following will work:
create table #Databases(idx int identity(1, 1), DbName nvarchar(100), compName nvarchar(100) null)
declare @Count int
declare @Total int
declare @DbName nvarchar(100)
set nocount on
insert into #Databases
     select name, null from master..sysdatabases  where has_dbaccess(name) = 1
set @Total = @@ROWCOUNT
set @Count = 1
while @Count <= @Total
     begin
          select @DbName = DBName from #Databases where idx = @Count
               declare @sql nvarchar(400)
               set @sql = 'if exists(select name from ' + + QUOTENAME(@DbName) + '..sysobjects where name = ''CINF'' and xtype = ''U'')
                              update #Databases set compName = (select CompnyName from ' + + QUOTENAME(@DbName) + '..CINF) where idx = ' + cast(@Count as nvarchar)
               exec(@sql)
          set @Count = @Count + 1
     end
set nocount off
select DbName, compName from #Databases where compName is not null
drop table #Databases
Kind Regards,
Owen