Date stamp for cell entry

Question

Hi, just reading the manuals for applescript but need some help. We have just changed from xl in windows to numbers and osx. One of the spreadsheets our admin used had a row where every time she added a new numerical value the cell above it would stamp the date of the entry. I have read through some old posts and it seems to be suggested that the only way is to "copy and paste" from, i guess, a cell containing the current date using applescript. Could someone give me a helpful nudge? I have only started looking at applescript today so its all a bit new.Either a point towards the appropriate tutorial or an example script would be great.
Thanks
rob

Answer 1

Here is a version in which the Help part was a bit enhanced.
--[SCRIPT storestring_anddate]
Enregistrer le script en tant que Script : storestring_anddate.scpt
déplacer le fichier créé dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Placez le curseur dans la cellule que vous souhaitez alimenter.
aller au menu Scripts , choisir Numbers puis choisir storestring_anddate
La cellule pointée reçoit la chaîne saisie
La cellule située à sa droite reçoit la date_heure de l'intervention.
Si la chaîne saisie est vide, les deux cellules sont vidées.
Il est possible de modifier le comportement du script en éditant les properties.
Avec
property offsetVertical : -1
property offsetHorizontal : 0
la date sera placée dans la cellule qui est juste au-dessus de la valeur insérée.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as Script : storestring_anddate.scpt
Move the newly created file into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Put the cursor in the cell which must receive your entry.
go to the Scripts Menu, choose Numbers, then choose storestring_anddate
The pointed cell receives the entered string.
The cell on its right receive the current date_time.
If the entered string is empty, the two cells are cleared.
We may change the script behavior thru some edit of the properties.
With
property offsetVertical : -1
property offsetHorizontal : 0
the date will be stored just above the inserted value.
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
--=====
Yvan KOENIG (Vallauris, FRANCE)
2009/02/16
2011/01/07
2011/01/29 added some comments in the help.
property theApp : "Numbers"
property offsetVertical : 0
property offsetHorizontal : 1
--=====
on run
set {dName, sName, tName, rname, rowNum1, colNum1, rowNum2, colNum2} to my getSelParams()
if rowNum2 > rowNum1 then set offsetVertical to rowNum2 - rowNum1
if colNum2 > colNum1 then set offsetHorizontal to colNum2 - colNum1
tell application (path to frontmost application as string)
if my parleAnglais() then
set rate to text returned of (display dialog "Cell's contents" default answer "blabla bla")
else
set rate to text returned of (display dialog "Contenu de la cellule…" default answer "blabla bla")
end if
end tell
my doYourDuty(rowNum1, colNum1, dName, sName, tName, rate)
end run
--=====
on doYourDuty(r, c, d, s, t, txt) (*
r = rowIndex
c = columnIndex
d = document's name
s = sheet's name
t = table's name
txt = new cell's contents *)
local cdt, r_date, c_date
set cdt to my cleanThisDate(current date) (* the new date_time as a clean date_time *)
tell application "Numbers" to tell document d to tell sheet s to tell table t
set r_date to r + offsetVertical
set c_date to c + offsetHorizontal
if r_date > row count then
repeat (r_date - row count) times
add row below row -1
end repeat
end if
if c_date > column count then
repeat (c_date - column count) times
add column after column -1
end repeat
end if
if txt is "" then
clear cell r of column c
clear cell r_date of column c_date
else
set value of cell r of column c to txt
set value of cell r_date of column c_date to (cdt as text)
end if
end tell -- application …
end doYourDuty
--=====
on cleanThisDate(dt)
(* ugly code but once I got date_time with milliseconds so if necessary, I drop them *)
local l
set l to my decoupe(dt as text, ":")
if (count of l) = 4 then
set dt to date (my recolle(items 1 thru 3 of l, ":"))
end if
return dt
end cleanThisDate
--=====
on getSelParams()
local r_Name, t_Name, s_Name, d_Name, col_Num1, row_Num1, col_Num2, row_Num2
set {d_Name, s_Name, t_Name, r_Name} to my getSelection()
if r_Name is missing value then
if my parleAnglais() then
error "No selected cells"
else
error "Il n'y a pas de cellule sélectionnée !"
end if
end if
set two_Names to my decoupe(r_Name, ":")
set {row_Num1, col_Num1} to my decipher(item 1 of two_Names, d_Name, s_Name, t_Name)
if item 2 of two_Names = item 1 of two_Names then
set {row_Num2, col_Num2} to {row_Num1, col_Num1}
else
set {row_Num2, col_Num2} to my decipher(item 2 of two_Names, d_Name, s_Name, t_Name)
end if
return {d_Name, s_Name, t_Name, r_Name, row_Num1, col_Num1, row_Num2, col_Num2}
end getSelParams
--=====
on decipher(n, d, s, t)
tell application "Numbers" to tell document d to tell sheet s to tell table t to return {address of row of cell n, address of column of cell n}
end decipher
--=====
on getSelection()
local _, theRange, theTable, theSheet, theDoc, errMsg, errNum
tell application "Numbers" to tell document 1
repeat with i from 1 to the count of sheets
tell sheet i
set x to the count of tables
if x > 0 then
repeat with y from 1 to x
try
(selection range of table y) as text
on error errMsg number errNum
set {_, theRange, _, theTable, _, theSheet, _, theDoc} to my decoupe(errMsg, quote)
return {theDoc, theSheet, theTable, theRange}
end try
end repeat -- y
end if -- x>0
end tell -- sheet
end repeat -- i
end tell -- document
return {missing value, missing value, missing value, missing value}
end getSelection
--=====
on decoupe(t, d)
local oTIDs, l
set oTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to oTIDs
return l
end decoupe
--=====
on recolle(l, d)
local oTIDs, t
set oTIDs to AppleScript's text item delimiters
set AppleScript's text item delimiters to d
set t to l as text
set AppleScript's text item delimiters to oTIDs
return t
end recolle
--=====
on parleAnglais()
local z
try
tell application theApp to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z is not "Annuler")
end parleAnglais
--=====
--[/SCRIPT]
Yvan KOENIG (VALLAURIS, France) samedi 29 janvier 2011 16:35:59