Displaying the selected rows in ALV Grid output

Question

Hi Experts,
I am developing one interactive ALV Grid report where user can process the selected records/rows from the ALV Grid output.
for displaying the ALV Grid, I have used the class CL_GUI_ALV_GRID class. I am working on ECC 6.0 system.
when I select any records/rows from output and then press any Application Toolbar button, PAI and then PBO modules of the screen gets executed as per the normal flow.
however After PBO, when same ALV output comes, all the selected/highlighted rows appear as unselected, that means I want to retain the ALV
rows selection during the round trip.
please advise.
Regards,
Jagesh

Answer 1

Hi,
Feiyun Wu is correct.
Get_selected_rows and set_selected_rows are the methods to be used .
Some code:
Note the sequence of code:
FORM set_gui_alv_grid_1 .
  DATA: wa_layout TYPE lvc_s_layo ,
        wa_print TYPE lvc_s_prnt .
  DATA: it_sort TYPE lvc_t_sort ,
        wa_sort TYPE LINE OF lvc_t_sort .
  DATA: it_fieldcatalog TYPE lvc_t_fcat.
  IF gui_custom_container_1 IS INITIAL .
    CREATE OBJECT gui_custom_container_1
      EXPORTING
        container_name = 'GUI_CUSTOM_CONTAINER_1'
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5
        OTHERS                      = 6 .
    IF sy-subrc <> 0.
    ENDIF.
    PERFORM get_field_catalog
      USING gc_log_group_1
      CHANGING it_fieldcatalog  .
    CREATE OBJECT gui_alv_grid_1
      EXPORTING i_parent = gui_custom_container_1.
    CREATE OBJECT ob_event_receiver_1
      EXPORTING log_group = gc_log_group_1 .
* registers the event handlers
    SET HANDLER ob_event_receiver_1->handle_toolbar      FOR gui_alv_grid_1 .
    SET HANDLER ob_event_receiver_1->handle_user_command FOR gui_alv_grid_1 .
    SET HANDLER ob_event_receiver_1->print_top_of_page   FOR gui_alv_grid_1 .
    SET HANDLER ob_event_receiver_1->hotspot_click       FOR gui_alv_grid_1 .
    wa_layout-cwidth_opt = abap_true .
*   wa_layout-excp_fname = gc_excp_fname .
*   wa_layout-ctab_fname = gc_ctab_fname.
*   wa_layout-excp_led   = abap_true .
    CALL METHOD gui_alv_grid_1->set_table_for_first_display
      EXPORTING
        is_layout       = wa_layout
        is_print        = wa_print
        i_save          = 'A'
        is_variant      = gs_disvariant_1
      CHANGING
        it_sort         = it_sort
        it_fieldcatalog = it_fieldcatalog
        it_outtab       = it_alv_grid_1.
  ELSE .
    CALL METHOD gui_alv_grid_1->refresh_table_display.
* Restore selections
    CALL METHOD gui_alv_grid_1->set_selected_rows
      EXPORTING
        it_index_rows = ob_event_receiver_1->it_rows.
* Restore position
    CALL METHOD gui_alv_grid_1->set_scroll_info_via_id
      EXPORTING
        is_col_info = ob_event_receiver_1->wa_col
        is_row_no   = ob_event_receiver_1->wa_roid.
  ENDIF.
ENDFORM .                    "set_gui_alv_grid_1
Regards.