Downloading a file from a report link

Question

I have a report link that sends a couple parameters to a secondary page.
The secondary page has a process in it that selects a blob file from a table and then downloads that file.
However, there is no browser download file dialog window that pops-up when the link is clicked.
The file just displays in the browser. So, I'm thinking I have something wrong with my MIME header.
The process that downloads the file is:
<code>
DECLARE
l_length NUMBER;
l_lob_loc BLOB := EMPTY_BLOB();
l_mime_type warm_files.mime_type%TYPE;
BEGIN
apex_application.g_page_text_generated := true;
apex_application.g_unrecoverable_error := true;
select blob_content, dbms_lob.getlength(blob_content), mime_type
into l_lob_loc, l_length, l_mime_type
from WARM_FILES
where context_id = :P12_CONTEXT_ID
and file_id = :P12_FILE_ID
-- set up HTTP header
OWA_UTIL.mime_header (l_mime_type, FALSE);
-- set the size so the browser knows how much to download
HTP.p ('Content-length: ' || l_length);
-- close the headers
OWA_UTIL.http_header_close;
-- download the BLOB
wpg_docload.download_file (l_lob_loc);
END;
</code>
The :P12 variables are the parameters coming in from the link.
There are no errors. The file just displays in the browser window.
Any clues as to what I'm missing are greatly appreciated.
Thanks in advance.
alan.
Edited by: semaphore on Dec 11, 2009 9:14 AM

Answer 1

Hi Alan,
try this...
This is my procedure which I adapted to yours...
<code>
DECLARE
l_length NUMBER;
l_lob_loc BLOB := EMPTY_BLOB();
l_mime_type warm_files.mime_type%TYPE;
l_file_name VARCHAR2(2000);
BEGIN
apex_application.g_page_text_generated := true;
apex_application.g_unrecoverable_error := true;
SELECT null,
BLOB_CONTENT,
name,
DBMS_LOB.GETLENGTH(blob_content)
INTO l_mime_type,
l_lob_loc,
l_file_name,
l_length
from WARM_FILES
where context_id = :P12_CONTEXT_ID
and file_id = :P12_FILE_ID;
-- set up HTTP header
owa_util.mime_header( nvl(l_mime_type,'application/octet'), FALSE );
-- set the size so the browser knows how much to download
HTP.p ('Content-length: ' || l_length);
-- the filename will be used by the browser if the users does a save as
htp.p('Content-Disposition: attachment; filename="'||substr(l_file_name,instr(l_file_name,'/')+1)|| '"');
-- close the headers
OWA_UTIL.http_header_close;
-- download the BLOB
wpg_docload.download_file (l_lob_loc);
END;
</code>
Hope it helps.
Regards, Zlatko Matanic