Dynamic string

Question

Hi,
I need to extract values from string to variables as below.
declare
str varchar2(100):='Acknowledgment=1234,Order Requester=5678,Site Contact=9999,Other Contact=1456,Pre=1234,23445,56767';
l_a varchar2(100);
l_or  varchar2(100);
l_s  varchar2(100);
l_ot  varchar2(100);
l_pre  varchar2(100);
Begin
l_a:='1234';
l_or:='5678';
l_s:='9999';
l_ot:='1456';
l_pre:='1234,23445,56767';
end;
But here challenge is order of alignment change dynamically. ex as below.
str varchar2(100):='Order Requester=5678,Acknowledgment=1234,Site Contact=9999,Other Contact=1456,Pre=1234,23445,56767';
str varchar2(100):='Pre=1234,23445,56767,Order Requester=5678,Acknowledgment=1234,Site Contact=9999,Other Contact=1456';
So how to extract Acknowledgement to l_a,Order requester to l_or ....
Could you please help me on this scenario?
Thanks,
Senthil
Message was edited by: SenthilkumarS

Answer 1

One thing that I see in your input data is that the field delimiter is also present in your value. You need to eliminate that otherwise your code need to be doing lot of messy things to parse it.
I have replaced your delimiter comma (,) with pipe (|). Now you can get the output like this.
SQL> declare
  2    l_s1 varchar2(100) := 'Order Requester=5678|Acknowledgment=1234|Site Contact=9999|Other Contact=1456|Pre=1234,23445,56767';
  3    l_s2 varchar2(100) := 'Pre=1234,23445,56767|Order Requester=5678|Acknowledgment=1234|Site Contact=9999|Other Contact=1456';
  4
  5    l_a   varchar2(100);
  6    l_or  varchar2(100);
  7    l_s   varchar2(100);
  8    l_ot  varchar2(100);
  9    l_pre varchar2(100);
10  begin
11
12    select max(decode(field_name, 'Order Requester', field_val)) order_requester
13         , max(decode(field_name, 'Acknowledgment', field_val)) Acknowledgment
14         , max(decode(field_name, 'Site Contact', field_val)) site_contact
15         , max(decode(field_name, 'Other Contact', field_val)) other_contact
16         , max(decode(field_name, 'Pre', field_val)) pre
17      into l_or
18         , l_a
19         , l_s
20         , l_ot
21         , l_pre
22      from (
23              select trim(substr(str, 1, instr(str, '=')-1)) field_name
24                   , trim(substr(str, instr(str, '=')+1)) field_val
25                from (
26                        select regexp_substr(str, '[^|]+', 1, level) str
27                          from (
28                                 select l_s1 str from dual
29                               )t
30                        connect by level <= length(str) - length(replace(str, '|'))  + 1
31                     )
32           );
33
34    dbms_output.put_line('l_s1 = ' || l_s1);
35    dbms_output.put_line
36    (
37       'l_or = ' || l_or || chr(10) || chr(13) ||
38       'l_a  = ' || l_a  || chr(10) || chr(13) ||
39       'l_s  = ' || l_s  || chr(10) || chr(13) ||
40       'l_ot = ' || l_ot || chr(10) || chr(13) ||
41       'l_pre= ' || l_pre
42    );
43
44    select max(decode(field_name, 'Order Requester', field_val)) order_requester
45         , max(decode(field_name, 'Acknowledgment', field_val)) Acknowledgment
46         , max(decode(field_name, 'Site Contact', field_val)) site_contact
47         , max(decode(field_name, 'Other Contact', field_val)) other_contact
48         , max(decode(field_name, 'Pre', field_val)) pre
49      into l_or
50         , l_a
51         , l_s
52         , l_ot
53         , l_pre
54      from (
55              select trim(substr(str, 1, instr(str, '=')-1)) field_name
56                   , trim(substr(str, instr(str, '=')+1)) field_val
57                from (
58                        select regexp_substr(str, '[^|]+', 1, level) str
59                          from (
60                                 select l_s2 str from dual
61                               )t
62                        connect by level <= length(str) - length(replace(str, '|'))  + 1
63                     )
64           );
65
66    dbms_output.put_line('l_s2 = ' || l_s2);
67    dbms_output.put_line
68    (
69       'l_or = ' || l_or || chr(10) || chr(13) ||
70       'l_a  = ' || l_a  || chr(10) || chr(13) ||
71       'l_s  = ' || l_s  || chr(10) || chr(13) ||
72       'l_ot = ' || l_ot || chr(10) || chr(13) ||
73       'l_pre= ' || l_pre
74    );
75  end;
76  /
l_s1 = Order Requester=5678|Acknowledgment=1234|Site Contact=9999|Other Contact=1456|Pre=1234,23445,56767
l_or = 5678
l_a  = 1234
l_s  = 9999
l_ot = 1456
l_pre= 1234,23445,56767
l_s2 = Pre=1234,23445,56767|Order Requester=5678|Acknowledgment=1234|Site Contact=9999|Other Contact=1456
l_or = 5678
l_a  = 1234
l_s  = 9999
l_ot = 1456
l_pre= 1234,23445,56767
PL/SQL procedure successfully completed.
SQL>