Eject Disk Image at logout with AppleScipt?

Question

Hello, I would like to know how to use AppleScript to write a script that automatically ejects a disk image whenever the user logs out of their account.
This script would be the complementary inverse to a login item I have setup wherein a specific disk image is mounted upon login.
Because the disk image to be unmounted will be the same one every time, a script that simply uses the path to the image to accomplish the task will be fine (as opposed to a script that would scan for and unmount any mounted images found).

Answer 1

Check this one out.
I found this on MacScripter. You should check out that site too, as there are a lot of applescripts there.
-- Adjust these values to your own requirements:
property initialInterval : 5 * minutes -- The initial time to wait before starting the checks to see if the app has quit.
property checkInterval : 10 -- The time (in seconds) between checks after that.
property appName : "My App" -- The name of the app to watch.
property diskName : "My Disk" -- The name of the disk to eject.
global justOpened
on run
          set justOpened to true -- Tells the 'idle' handler that this script applet's just started running.
end run
on idle
          if (justOpened) then
  -- Reverse the flag for next time and ask for the next 'idle' to come after the intial wait period.
                    set justOpened to false
                    return initialInterval
          else
  -- Otherwise check if the application is (still) running.
                    tell application "System Events" to set appRunning to (application process appName exists)
                    if (appRunning) then
  -- If it is, request the next 'idle' to come after the specified check interval.
                              return checkInterval
                    else
  -- Otherwise eject the disk (if it's mounted).
                              tell application "Finder"
                                        if (disk diskName exists) then eject disk diskName
                              end tell
  -- Issue the log out command. (There'll be a 1-minute count-down dialog).
                              tell application "System Events" to log out
  -- Tell this stay-open script application to quit. (It will only do so on the next 'idle'.)
  quit
  -- Request the next 'idle' to come after the shortest possible time.
                              return 1
                    end if
          end if
end idle