Error on procedure which using dblink

Question

Hi,
i am created an procedure under one (x) database .
CREATE OR REPLACE PROCEDURE IBSOIFC.Schedule_insert(period date) IS
      CURSOR c1 IS
      SELECT *
        FROM ibsoifc.ibs_x_t_schedule@testarch
       WHERE month_yr <= period; -- AND bpref_no = :cons;
      TYPE tsch IS TABLE OF c1%ROWTYPE;
      vtsch      tsch;
      cnt        NUMBER := 0;
      stime      NUMBER;
      etime      NUMBER;
      DURATION   NUMBER;
      rcount     NUMBER;
      errorsd   PLS_INTEGER;
      ecode     NUMBER;
      column1   VARCHAR2 (100);
      column2   VARCHAR2 (100);
      column3   VARCHAR2 (100);
      column4   VARCHAR2 (100);
BEGIN
         BEGIN
         stime := DBMS_UTILITY.get_time ();
         OPEN c1;
         LOOP
            FETCH c1
            BULK COLLECT INTO vtsch LIMIT 1000;
            IF vtsch.COUNT = 1000
            THEN
               cnt := cnt + 1;
            END IF;
            FORALL i IN 1 .. vtsch.COUNT SAVE EXCEPTIONS
               INSERT INTO ibs_x_t_schedule_x
                    VALUES vtsch (i);
            EXIT WHEN c1%NOTFOUND;
         END LOOP;
         etime := DBMS_UTILITY.get_time ();
         DURATION := ((etime - stime) / 100) / 60;
         rcount :=
             (cnt * 1000) + vtsch.COUNT - NVL (SQL%BULK_EXCEPTIONS.COUNT, 0);
         INSERT INTO process_stage_log
              VALUES (SYSDATE, 'IBS_X_T_SCHEDULE', DURATION, rcount);
         CLOSE c1;
         COMMIT;
      EXCEPTION
         WHEN OTHERS
         THEN
            errorsd := SQL%BULK_EXCEPTIONS.COUNT;
            IF errorsd > 0
            THEN
               FOR j IN 1 .. errorsd
               LOOP
                  ecode := SQL%BULK_EXCEPTIONS (j).ERROR_CODE;
                  column1 :=
                       vtsch (SQL%BULK_EXCEPTIONS (j).ERROR_INDEX).sch_code;
                  column2 :=
                       vtsch (SQL%BULK_EXCEPTIONS (j).ERROR_INDEX).bpref_no;
                  column3 :=
                       vtsch (SQL%BULK_EXCEPTIONS (j).ERROR_INDEX).month_yr;
                  column4 :=
                     vtsch (SQL%BULK_EXCEPTIONS (j).ERROR_INDEX).service_code;
                  INSERT INTO process_error_log
                       VALUES (SYSDATE, ecode, 'IBS_X_T_SCHEDULE', column1,
                               column2, column3, column4);
               END LOOP;
            END IF;
      END;
END;The above procedue is calling through form 6i on when-button-pressed event by using the following code
Declare
      errm varchar2(1000);
Begin
Begin
     Select process_dt into :period
       from ibs_m_archive_process
       where app_flag = 'Y'
         and process_status = 'L';
Exception
       When no_data_found Then
          :titl.msg_fld := ' No data found on ibs_m_archive_process !!!';          
          raise form_trigger_failure;
       When too_many_rows Then
          :titl.msg_fld := ' Two many process is available !!!';
          raise form_trigger_failure;
       When others Then
          :titl.msg_fld := ' Error on ibs_m_archive_process fetch !!!';
          raise form_trigger_failure;
end;               
      message(:period);
      break;
      Begin
      Schedule_insert(:period);
      exception
            when others then
              message('error'||sqlerrm);
              errm := sqlerrm;
              insert into test values(errm);
              commit;
              raise form_trigger_failure;
      end;        
end;The exception handler catch the following error.
ORA-06531: Reference to uninitialized collection
ORA-06512: at "IBSOIFC.SCHEDULE_INSERT", line 63
ORA-01017: invalid username/password; logon denied
ORA-02063: preceding line from TESTARCHThe same procedure invoked from database itself is working fine instead of from form 6i.
please guide me how to solve the problem.
kanish
Edited by: Kanish on Apr 28, 2012 11:57 PM

Answer 1

Hi Kanish,
SQL%BULK_EXCEPTION.COUNT is only initialized if FORALL statement is executed. Below is explained what happen if your program error
There are two possibilities.
1. DB link user/password is incorrect which raise ORA-01017 and wrongly catched in your exception block as Bulk Exception.
2. Cursor c1 retrieves zero record
CURSOR c1 IS
      SELECT *
        FROM ibsoifc.ibs_x_t_schedule@testarch
       WHERE month_yr <= period; -- AND bpref_no = :cons;# Suppose parameter period is given such a date value that cursor c1 pull 0 record
IF vtsch.COUNT = 1000
            THEN
               cnt := cnt + 1;
            END IF;
            FORALL i IN 1 .. vtsch.COUNT SAVE EXCEPTIONS
               INSERT INTO ibs_x_t_schedule_x
                    VALUES vtsch (i);
            EXIT WHEN c1%NOTFOUND;
         END LOOP;# In above code vtsch.COUNT = 0 and FORALL - INSERT statement will be never executed
rcount :=   (cnt * 1000) + vtsch.COUNT - NVL (SQL%BULK_EXCEPTIONS.COUNT, 0);# Going down you reference NVL (SQL%BULK_EXCEPTIONS.COUNT, 0) which will throw error code - ORA-06531 as bulk exceptions are not initialized
EXCEPTION
         WHEN OTHERS
         THEN
            errorsd := SQL%BULK_EXCEPTIONS.COUNT;# As a good practice you must use error code = -24381 for catching bulk bind exceptions and OTHERS for unknown exception.
# Now again you reference - SQL%BULK_EXCEPTIONS.COUNT which again throw ORA-06531 as bulk exceptions are not initialized. Hence you get message - "ORA-06512: at "IBSOIFC.SCHEDULE_INSERT", line 63"
Hope that helps