Error Updating field

Question

Hi to everyone,
Can you please look at the code below and see what I’m doing wrong?
On form Invoices I have a button to create Direct Debit transactions
The code for the button should do the following:
Select all unique Clients that have the direct debit checkbox checked
Cycle through those Clients and:
Select all transaction records for the Client that have not been invoiced already
Sum the TxAmount field of all the transaction records for the Client that have not been invoiced already
Create a new record in the invoice table using the current ClientID, current date, sum from the previous amount, and calculated tax.
Cycle back through the transaction records for the Client and insert the newly created invoice number into each transaction involved in creating the invoice.
I seem to be getting different errors when I click on the button, the most common being No Current Record Selected in the last step “'Add newly created invoice number to
transactions used to create invoice”.
Thanks for your help
Dante
Tables
tblClient (ClientID(key), Address, DirectDebit, ProductCount)
tblProduct (ProductID(Key), fkClientID, Productype, EnrolmentDate, Isactive)
tblInvoice (InvoiceID(Key), fkClientID, InvoiceDate, Amount, Tax, Paid)
tblTransaction (TxID(Key), fkProductID, TxDate, TxType, TxAmount, TxInvoice)
Code button
Dim db As DAO.Database
Dim rstClient As DAO.Recordset
Dim rstTrans As DAO.Recordset
Dim rstInvoice As DAO.Recordset
Dim rstSum As DAO.Recordset
Dim strSQL As String
Dim strSQLClient As String
Dim strSQLSum As String
Set db = CurrentDb
'Select all unique Clients that have provided direct debit information
strSQLClient = "SELECT DISTINCT ClientID " _
& "FROM tblClient " _
& "WHERE (tblClient.DirectDebit = 40);"
Set rstClient = db.OpenRecordset(strSQLClient)
rstClient.MoveFirst
Do While Not rstClient.EOF
'Select all transactions that have not previously been invoiced
strSQL = "SELECT * " _
& "FROM (tblTransaction " _
& "INNER JOIN tblProduct ON tblTransaction.fkProductID = tblProduct.ProductID) " _
& "INNER JOIN tblClient ON tblProduct.fkClientID = tblClient.ClientID " _
& "WHERE (((tblTransaction.TxInvoice) IS NULL) " _
& "AND ((tblClient.ClientID) = '" & rstClient!ClientID & "'))"
Set rstTrans = db.OpenRecordset(strSQL)
'Sum all transactions that are Fees and have not been previously invoiced
strSQLSum = "SELECT SUM(tblTransaction.TxAmount) As InvoiceSum " _
& "FROM (tblTransaction " _
& "INNER JOIN tblProduct ON tblTransaction.fkProductID = tblProduct.ProductID) " _
& "INNER JOIN tblClient ON tblProduct.fkClientID = tblClient.ClientID " _
& "WHERE (((tblTransaction.TxInvoice) IS NULL) " _
& "AND ((tblTransaction.TxType) = 'Fee') " _
& "AND ((tblClient.ClientID) = '" & rstClient!ClientID & "'))"
Set rstSum = db.OpenRecordset(strSQLSum)
'Add a new record to the invoice table with the sum of the amount and tax fields of all transactions not previously invoiced
Set rstInvoice = db.OpenRecordset("tblInvoice")
rstInvoice.AddNew
rstInvoice("fkClientID").Value = rstClient("ClientID")
rstInvoice("InvoiceDate").Value = Format(Now, "m/dd/yyyy")
rstInvoice("Amount").Value = rstSum("InvoiceSum")
rstInvoice("Tax").Value = rstInvoice("Amount") * 0.05
rstInvoice.Update
'Add newly created invoice number to transactions used to create invoice
rstTrans.MoveFirst
Do While Not rstTrans.EOF
rstTrans.Edit
rstTrans("TxInvoice").Value = rstInvoice("InvoiceID")
rstTrans.Update
rstTrans.MoveNext
Loop
Set rstTrans = Nothing
rstClient.MoveNext
Loop
Set rstClient = Nothing
Set rstInvoice = Nothing
Set db = Nothing
Forms!frmInvoices.Refresh

Answer 1

'Add a new record to the invoice table with the sum of the amount and tax fields of all transactions not previously invoiced
Set rstInvoice = db.OpenRecordset("tblInvoice")
rstInvoice.AddNew
rstInvoice("fkClientID").Value = rstClient("ClientID")
rstInvoice("InvoiceDate").Value = Format(Now, "m/dd/yyyy")
rstInvoice("Amount").Value = rstSum("InvoiceSum")
rstInvoice("Tax").Value = rstInvoice("Amount") * 0.05
new_invoice_id = rstInvoice!InvoiceID
rstInvoice.Update
'Add newly created invoice number to transactions used to create invoice
rstTrans.MoveFirst
Do While Not rstTrans.EOF
rstTrans.Edit
rstTrans("TxInvoice").Value = rstInvoice("InvoiceID")
rstTrans("TxInvoice") = new_invoice_id
rstTrans.Update
rstTrans.MoveNext
Loop
Hi Dante,
Perhaps you can try this.
After the Update of a new rstInvoice record the rstInvoice.InvoiceID is not available anymore. So catch it before the Update, and use that value.
See the "corrections" in the above part.
Imb.