Extracting info from info window OTHER THAN the usual properties

Question

Hi, the info window's property list does not include what's in the "more info" section: I am specifically looking for the "dimensions" property of a jpeg file. Is there some way to access it in a script?
thanks
  Mac OS X (10.4.6)  

Answer 1

I don't believe Finder exposes that information to AppleScript directly. There are many other ways to get image info, however. Here are three of them…
click here to open this script in your editor<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">set hfs_image to choose file
tell application "Image Events" to tell (open hfs_image)
set {w, h} to get dimensions
close
end tell
{w, h}
-- UNIX METHODS
set posix_image to POSIX path of hfs_image
-- Using MDLS (Metadata List, AKA Spotlight)
set w to last word of (do shell script "mdls -name kMDItemPixelWidth " & quoted form of posix_image)
set h to last word of (do shell script "mdls -name kMDItemPixelHeight " & quoted form of posix_image)
{w, h}
-- Using SIPS (Scriptable Image Processing System)
set w to last word of (do shell script "sips -g pixelWidth " & quoted form of posix_image)
set h to last word of (do shell script "sips -g pixelHeight " & quoted form of posix_image)
{w, h}
</pre>