Fixing Geometry Errors

Question

Has anyone put together a list of "x error can be fixed by doing y" for geometry errors?
I ask this because I am in the middle of writting code to fix geometry errors within a database from imported ESRI-based data. Presently I have the code to find all errors, and can fix:
13349 and 13366
Fix with a self union (same geometry twice): SDO_GEOM.SDO_UNION
13356
Fix with the new SDO_UTIL.REMOVE_DUPLICATE_VERTICES function.
I started with these, since they are most pervasive.
Obviously, some errors like 13351 and 13350 are harder, since the code actually needs to slightly alter the original data (move the rings or touching points) to remove the errors.

Answer 1

Bryan,
I have a ShapeCheck routine in PL/SQL that I have deployed in the past databases as a dbms_job...
I have a number of versions depending on how you want the errors to be reported: one via SMTP_UTL for emailing, another writes answers to a table for visualisation with Application Express.
If you want a copy email me at simon at spatialdbadvisor dot com
Or.... here it is...
DEFINE defaultSchema='&1'
set serverout on SIZE 1000000
DROP PROCEDURE ShapeCheck;
DROP TABLE ALL_FEATURE_ERROR;
CREATE TABLE ALL_FEATURE_ERROR (
owner VARCHAR2(30),
table_name VARCHAR2(30),
column_name VARCHAR2(30),
feature_rowid VARCHAR2(20),
error_code VARCHAR2(10),
error_status CHAR(1),
error_context VARCHAR2(2000),
error_date DATE
grant insert,update,delete,select on all_feature_error to public;
CREATE PROCEDURE ShapeCheck( p_schema IN VARCHAR2,
p_tableName IN VARCHAR2,
p_shapeName IN VARCHAR2,
p_whereClause IN VARCHAR2)
AUTHID CURRENT_USER
IS
v_shape MDSYS.SDO_GEOMETRY;
c_shape MDSYS.SDO_GEOMETRY;
v_OwnerName VARCHAR2(30);
v_TableName VARCHAR2(30);
v_ColumnName VARCHAR2(30);
c_rowid ROWID;
v_error_code ALL_FEATURE_ERROR.ERROR_CODE%TYPE;
v_error_status ALL_FEATURE_ERROR.ERROR_STATUS%TYPE;
v_error_context ALL_FEATURE_ERROR.ERROR_CONTEXT%TYPE;
v_error_count number;
v_error_found number;
v_fixed_count number;
v_count number;
v_diminfo MDSYS.SDO_DIM_ARRAY;
v_start_date DATE;
v_end_date DATE;
v_tolerance number;
v_query varchar2(1024);
TYPE shapeCursorType IS REF CURSOR;
shapeCursor shapeCursorType;
BEGIN
v_TableName := UPPER(p_tablename);
v_OwnerName := UPPER(p_schema);
v_ColumnName := UPPER(p_ShapeName);
BEGIN -- In case get NO_DATA_FOUND
SELECT diminfo
INTO v_diminfo
FROM ALL_SDO_GEOM_METADATA
WHERE owner = v_OwnerName and table_name = v_TableName and column_name = v_ColumnName;
EXCEPTION
WHEN NO_DATA_FOUND THEN
dbms_output.put_line('No diminfo found in all_sdo_geom_metadata for '||v_OwnerName||'.'||v_TableName||'.'||v_ColumnName);
RETURN;
END;
v_tolerance := v_diminfo(1).sdo_tolerance;
v_count := 0;
v_error_count := 0;
v_fixed_count := 0;
IF ( p_whereClause is not null ) THEN
v_query := 'SELECT ROWID,' ||v_ColumnName|| ' FROM ' ||v_OwnerName|| '.' ||v_TableName|| ' WHERE ' ||p_whereClause;
ELSE
v_query := 'SELECT ROWID,' ||v_ColumnName|| ' FROM ' ||v_OwnerName|| '.' ||v_TableName;
END IF;
v_start_date := SYSDATE;
OPEN shapeCursor
FOR v_query;
LOOP
FETCH shapeCursor INTO c_rowid, c_shape;
EXIT WHEN shapeCursor%NOTFOUND;
IF ( c_shape IS NULL ) THEN
v_error_code := 'NULL';
ELSE
v_error_code := SUBSTR(MDSYS.SDO_GEOM.VALIDATE_GEOMETRY( c_shape, v_diminfo ),1,5);
END IF;
IF ( v_error_code <> 'TRUE' ) THEN
v_error_count := v_error_count + 1;
v_error_status := 'E'; -- if exception raised in following block this will remain 'E'
IF ( v_error_code <> 'NULL' ) THEN
BEGIN -- Exception block in case any of the functions trying to fix the shape fail...
IF ( v_error_code = '13356' ) THEN
v_shape := mdsys.sdo_util.remove_duplicate_vertices(c_shape,v_tolerance);
ELSIF c_shape.sdo_gtype in (2003,3007) THEN -- only try to fix bad polygons
v_shape := mdsys.sdo_geom.sdo_union(c_shape,v_diminfo,c_shape,v_diminfo);
IF ( v_shape.sdo_gtype = 2004 ) THEN
v_shape := &&defaultSchema..geom.ExtractPolygon(v_shape);
END IF;
END IF;
-- Update shape to reflect whatever happened...
EXECUTE IMMEDIATE 'UPDATE ' || v_OwnerName||'.'||v_TableName || ' A SET A.'||v_ColumnName||' = :1 WHERE rowid = :2 '
USING v_shape,c_rowid;
-- Check whether it was corrected or not...
v_error_context := SUBSTR(MDSYS.SDO_GEOM.VALIDATE_GEOMETRY_WITH_CONTEXT(v_shape,v_diminfo),1,2000);
v_error_code := SUBSTR(v_error_context,1,5);
v_error_context := SUBSTR(v_error_context,6,2000);
IF v_error_code = 'TRUE' THEN
v_error_status := 'F';
v_fixed_count := v_fixed_count + 1;
END IF;
EXCEPTION
WHEN OTHERS THEN
NULL;
END;
END IF; -- v_error_code = NULL
INSERT INTO &&defaultSchema..All_Feature_Error(owner,table_name,column_name,feature_rowid,error_code,error_status,error_context,error_date) VALUES (v_OwnerName,v_TableName,v_ColumnName,c_rowid,v_error_code,v_error_status,v_error_context,SYSDATE);
END IF;
END LOOP;
v_count := shapeCursor%ROWCOUNT;
CLOSE shapeCursor;
v_end_date := SYSDATE;
dbms_output.put_line('SHAPECHECK SUMMARY.');
dbms_output.put_line(' TABLE: ' || v_OwnerName||'.'||v_TableName||'.'||v_ColumnName);
dbms_output.put_line(' PROCESSING START: ' || to_char(v_start_date,'YYYY-MM-DD HH24:MM') );
dbms_output.put_line(' PROCESSING END: ' || to_char(v_end_date,'YYYY-MM-DD HH24:MM') );
dbms_output.put_line('FEATURES PROCESSED: ' || to_char(v_count) );
dbms_output.put_line('TOTAL ERRORS FOUND: ' || to_char(v_error_count) );
dbms_output.put_line('TOTAL ERRORS FIXED: ' || to_char(v_fixed_count) );
dbms_output.put_line('See table ALL_FEATURE_ERROR for list of errors');
END ShapeCheck;
show errors
grant execute on &&defaultSchema..ShapeCheck to public;
-- connect radtrain4@radtrain4@sdb1test
-- execute &&defaultSchema..shapecheck('RADTRAIN4','AB_LANDCLAIM','GEOMETRY',NULL);
-- VARIABLE jobno number;
-- BEGIN
-- DBMS_JOB.SUBMIT(:jobno,'&&defaultSchema..shapecheck(''RADTRAIN4'',''SP_PARCEL'',''GEOMETRY'',NULL)'',''[email protected],[email protected]'' );',SYSDATE,'next_day(sysdate,''SUNDAY'')' );
-- COMMIT;
-- END;
--