For your reference: A real life AppleScript script regarding custom tags

Question

I'm working through a collection of photographs from iPhoto. One problem I have is that I have more than one set of the photographs and trying to eradicate duplicates and identify the true original images is rather difficult.
One thing that can help is referring to the complete EXIF data from the image file. Unfortunately, Aperture doesn't give us the complete EXIF set, only a subset. In addition, Aperture doesn't allow us to see the File date/time; only the Image date/time.
So I wrote this script. Before running the script, I batch renamed all of the images in my subject project using '<counter 4>—<Master Name>' to be sure that every image had a unique name. I then exported the masters from the subject project using '<Version Name>', the reason being that Aperture doesn't allow access to the file name via AppleScript. GraphicConverter will read the EXIF data from this exported set and the script will write most of the EXIF data back to the image in Aperture via custom tags.
One caveat: Aperture is *slow*. It requires almost 4 seconds to write each custom tag. With 6000+ images in my subject project, this script will take a while to complete.
The script:
tell application "Aperture"
activate
tell project "untitled Project" of folder ""
-- set theImages to every image version
-- move through the images one by one, deleting and creating the appropriate
-- custom tags from exif text obtained from exported versions via GraphicConverter.
repeat with i from 1 to theImages's length
tell theImages's item i
-- tell image version id "++s5iIgRT1uKC8lrxd5bMg" -- test image
delete (every custom tag whose name begins with "GC–")
set exifdata to getEXIF(name) of me
repeat with i from 1 to exifdata's length
copy ("GC– " & exifdata's item i's first item) to tName
copy (exifdata's item i's second item) to tValue
make new custom tag with properties {name:tName, value:tValue}
end repeat
end tell
end repeat
end tell
end tell
return
property exportedImagesFolder : alias "Bulbul:- exported from Aperture -:Canon IXUS 2:"
property exifTagsToIgnore : {"Make", ¬
"Model", ¬
"Resolution unit", ¬
"Y and C positioning", ¬
"Exposure time", ¬
"F number", ¬
"Exif version", ¬
"Meaning of each component", ¬
"Shutter speed", ¬
"Aperture", ¬
"Exposure bias", ¬
"Maximum lens aperture", ¬
"Metering mode", ¬
"Flash", ¬
"Lens focal length", ¬
"Unknown tag (1)", ¬
"Owner Name", ¬
"Color Space", ¬
"Interoperability Index", ¬
"Focal plane resolution unit", ¬
"White balance", ¬
"Resolution unit", ¬
"Offset to JPEG SOI", ¬
"Bytes of JPEG data"}
to getEXIF(vName)
copy alias ((exportedImagesFolder as string) & vName & ".jpg") to vFile
tell application "GraphicConverter"
copy (get file exif of vFile) to theEXIF
end tell
set AppleScript's text item delimiters to ","
repeat with i from 1 to theEXIF's length
set theEXIF's item i to ¬
{text item 3 of theEXIF's item i, text from text item 4 to -1 of theEXIF's item i}
end repeat
set AppleScript's text item delimiters to ""
set newEXIF to {}
set fileDate to ""
set imageDate to ""
repeat with i from 1 to theEXIF's length
copy theEXIF's item i's first item to tName
if tName is not in exifTagsToIgnore and ¬
tName does not start with "Unknown" then
set end of newEXIF to theEXIF's item i
if tName begins with "File date and time" then
set fileDate to date (theEXIF's item i's second item)
else if tName begins with "Date and time of original" then
set imageDate to date (theEXIF's item i's second item)
end if
end if
end repeat
if fileDate is not "" and imageDate is not "" then
if fileDate is less than (imageDate + 24 * 60 * 60) then
set end of newEXIF to {"File & Image Same Date", "True"}
else
set end of newEXIF to {"File & Image Same Date", "False"}
end if
end if
return newEXIF
end getEXIF

Answer 1

Correction 1:
please uncomment the line near the top of the script that reads:
-- set theImages to every image version
Correction 2:
writing the custom tags via AppleScript gets faster after Aperture's done it a few times.