Free container and then use it again.

Question

Dear SAP friends!
I am working on Table Maintenance Program.
When the program starts - the user see a window with a toolbar on the top. The rest of the window is blank.
The toolbar on the top  has 2 buttons named "Maintain Table Z1" and "Maintain table Z2".
When User clicks button "Maintain Table Z1" - then the middle part of the window becomes an ALV grid populated with table Z1.
When User clicks button "Maintain Table Z2" - then the middle part of the window becomes an ALV grid populated with table Z2.
The bottom part of the window has another toolbar containing buttons "ok", "Edit", Save" and "cancel". The purpose of this buttons is to allow display or edit of the table.
In the program the top, middle and bottom areas are container objects "container_top", "container_middle", "container_bottom".
The containers are created using splitters.
So what I do in the program:
1. on click button "Maintain Table Z1" I create alv grid object "grid_z1" in  "container_middle".
  CREATE OBJECT grid_z1
    EXPORTING
      i_parent = container_middle.
2. on click "ok" button I free  "container_middle" so the middle part of the screen will be blank again:
CALL METHOD container_middle->free.
3. on click button "Maintain Table Z2" I create alv grid object "grid_z2" in  the same "container_middle" after the container was freed. I assume that when you free a container - then container becomes empty and you can place into this container another object.
4. on click "ok" button I free  "container_middle" again so the middle part of the screen will become blank again.
So the User ( me actually at this point) does 1, 2, 3, 4 - and the program dumps.
So the 1st free in step 2 is ok. But the 2nd free in step 4  - is not OK.
Method "Free" raise cntl_error:
METHOD FREE.
  DATA L_CHILD TYPE REF TO CL_GUI_CONTROL.
  LOOP AT CHILDREN INTO L_CHILD.
    CALL METHOD L_CHILD->FREE
         exceptions others = 1.
  ENDLOOP.
  CLEAR CHILDREN.
  CALL METHOD SUPER->FREE
       exceptions cntl_error        = 1
                  cntl_system_error = 2
                  others            = 3.
  case sy-subrc.
    when 0.
    when 1.
>>>>>      raise cntl_error.
    when others.
      raise cntl_system_error.
  endcase.
ENDMETHOD.
Please help me to understand what is going on...
Thank you,
Tatyana

Answer 1

Hi,
I tried to repaint ur scenario: I got one screen containing 2 buttons and 1 custom  container: the first one showing Sales data and Delivery data respectively in the Same container. Here is what i wrote..
*& Report  ZTEST_PRG1
REPORT  anirban.
TABLES: vbak, likp.
TYPES: BEGIN OF types_vbak ,
       vbeln TYPE vbeln,
       vkorg TYPE vkorg,
       netwr TYPE netwr,
       END OF types_vbak,
       BEGIN OF types_likp ,
       vbeln TYPE vbeln_vl,
       vstel TYPE vstel,
       vkorg TYPE vkorg,
       netwr TYPE netwr,
       END OF types_likp.
DATA: w_cntx_menu TYPE REF TO cl_rsdme_ui_context_menu_gen,
      t_vbak      TYPE STANDARD TABLE OF types_vbak,
      t_likp      TYPE STANDARD TABLE OF types_likp,
      w_sale      TYPE char01.
CONSTANTS: c_check TYPE c VALUE 'X'.
** ALV relavent Data
DATA: w_grid TYPE REF TO cl_gui_alv_grid,
      wl_ref_container TYPE REF TO cl_gui_custom_container,
      w_container      TYPE scrfname   VALUE 'C_CONTAINER',
      t_fcat TYPE lvc_t_fcat,
      t_sort TYPE lvc_t_sort.
SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE text-011.
SELECT-OPTIONS: s_vbeln FOR vbak-vbeln,
                s_delvr FOR likp-vbeln.
SELECTION-SCREEN: END OF BLOCK b1.
START-OF-SELECTION.
  SELECT vbeln
         vkorg
         netwr
         FROM vbak INTO TABLE t_vbak
         WHERE vbeln IN s_vbeln.
  IF sy-subrc = 0.
    SORT t_vbak BY vbeln.
  ENDIF.
  SELECT vbeln
         vstel
         vkorg
         netwr
         FROM likp INTO TABLE t_likp
         WHERE vbeln IN s_delvr.
  IF sy-subrc = 0.
    SORT t_likp BY vbeln.
  ENDIF.
  CALL SCREEN '9001'.
*&      Module  STATUS_9001  OUTPUT
*       text
MODULE status_9001 OUTPUT.
  SET PF-STATUS ' '.
*  SET TITLEBAR 'xxx'.
ENDMODULE.                 " STATUS_9001  OUTPUT
*&      Module  USER_COMMAND_9001  INPUT
*       text
MODULE user_command_9001 INPUT.
  CASE sy-ucomm.
    WHEN 'BACK' OR
         'CANC' OR
         '%EX'.
      LEAVE TO SCREEN 0.
    WHEN 'SALE'.
      w_sale = c_check.
      PERFORM sub_fill_fcat_sale.
      PERFORM sub_display_grid.
    WHEN 'DELV'.
      PERFORM sub_fill_fcat_delv.
      PERFORM sub_display_grid.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_9001  INPUT
*&      Form  sub_display_grid_sale
*       text
*  -->  p1        text
*  <--  p2        text
FORM sub_display_grid .
  IF w_grid IS INITIAL.
    PERFORM sub_create_grid.
  ELSE.
    CALL METHOD wl_ref_container->free
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3.
    IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
    CALL METHOD w_grid->free
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3.
    IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
    FREE: w_grid, wl_ref_container.
    PERFORM sub_create_grid.
  ENDIF.
ENDFORM.                    " sub_display_grid_sale
*&      Form  sub_fill_fcat
*       text
*  -->  p1        text
*  <--  p2        text
FORM sub_fill_fcat_sale .
  DATA: wa_fcat TYPE lvc_s_fcat.
  REFRESH t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 1.
  wa_fcat-fieldname = wa_fcat-rollname = 'VBELN'.
  APPEND wa_fcat TO t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 2.
  wa_fcat-fieldname = wa_fcat-rollname = 'VKORG'.
  APPEND wa_fcat TO t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 3.
  wa_fcat-fieldname = wa_fcat-rollname = 'NETWR'.
  APPEND wa_fcat TO t_fcat.
ENDFORM.                    " sub_fill_fcat
*&      Form  sub_fill_fcat_delv
*       text
*  -->  p1        text
*  <--  p2        text
FORM sub_fill_fcat_delv .
  DATA: wa_fcat TYPE lvc_s_fcat.
  REFRESH t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 1.
  wa_fcat-fieldname = 'VBELN'.
  wa_fcat-rollname  = 'VBELN_VL'.
  APPEND wa_fcat TO t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 2.
  wa_fcat-fieldname = wa_fcat-rollname =  'VKORG'.
  APPEND wa_fcat TO t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 3.
  wa_fcat-fieldname = wa_fcat-rollname =  'VSTEL'.
  APPEND wa_fcat TO t_fcat.
  CLEAR wa_fcat.
  wa_fcat-row_pos   = 4.
  wa_fcat-fieldname = wa_fcat-rollname =  'NETWR'.
  APPEND wa_fcat TO t_fcat.
ENDFORM.                    " sub_fill_fcat_delv
*&      Form  sub_create_grid
*       text
*  -->  p1        text
*  <--  p2        text
FORM sub_create_grid .
** Create the Container
  CREATE OBJECT wl_ref_container
        EXPORTING
          container_name    = w_container.
** Create the Grid object
  CREATE OBJECT w_grid
    EXPORTING
      i_parent          = wl_ref_container
    EXCEPTIONS
      error_cntl_create = 1
      error_cntl_init   = 2
      error_cntl_link   = 3
      error_dp_create   = 4
      OTHERS            = 5.
  CHECK sy-subrc = 0.
  IF w_sale = c_check.
    CALL METHOD w_grid->set_table_for_first_display
      CHANGING
        it_outtab                     = t_vbak
        it_fieldcatalog               = t_fcat
      EXCEPTIONS
        invalid_parameter_combination = 1
        program_error                 = 2
        too_many_lines                = 3
        OTHERS                        = 4.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ELSE.
    CALL METHOD w_grid->set_table_for_first_display
      CHANGING
        it_outtab                     = t_likp
        it_fieldcatalog               = t_fcat
      EXCEPTIONS
        invalid_parameter_combination = 1
        program_error                 = 2
        too_many_lines                = 3
        OTHERS                        = 4.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ENDIF.
  CLEAR w_sale.
ENDFORM.                    " sub_create_grid
Hope That Helps
Anirban M.