Function to break up a string

Question

Hi ,
Please tell me the function name and its syntax to break a string into number of variables.....
Eg:
Variables: a,b,c
String: Hi,Rahul,ThisSide
The Result should be:
a=Hi
b=Rahul
c=ThisSide
The "," should be the breaking point...
Regards,
Rahul

Answer 1

SQL> create or replace type TStrings as table of varchar2(4000);
2 /
Type created.
SQL>
SQL>
SQL> create or replace function tokenise( cString varchar2, cSeparator varchar2 DEFAULT ',' )
return TStrings AUTHID CURRENT_USER is
2 strList TStrings;
3 str varchar2(4000);
4 i integer;
5 l integer;
6
7 procedure AddString( cLine varchar2 ) is
8 begin
9 strList.Extend(1);
10 strList( strList.Count ) := cLine;
11 end;
12
13 begin
14 strList := new TStrings();
15
16 str := cString;
17 loop
18 l := LENGTH( str );
19 i := INSTR( str, cSeparator );
20
21 if i = 0 then
22 AddString( str );
23 else
24 AddString( SUBSTR( str, 1, i-1 ) );
25 str := SUBSTR( str, i+1 );
26 end if;
27
28 -- if the separator was on the last char of the line, there is
29 -- a trailing null column which we need to add manually
30 if i = l then
31 AddString( null );
32 end if;
33
34 exit when str is NULL;
35 exit when i = 0;
36 end loop;
37
38 return( strList );
39 end;
40 /
Function created.
SQL>
SQL> select * from TABLE( tokenise('Hi,Rahul,ThisSide') );
COLUMN_VALUE
Hi
Rahul
ThisSide
SQL>