Gettting columns_names and their values

Question

Hi,
I need to write a query that takes all the columns of a table and store them on a collection of column_name, Column_value. The table name and the Where Clause may vary so i need to use dynamic sql.
My query will look like this;
SELECT *
   FROM xxx_table
WHERE xx_column = ?? AND yy_Column = ?? .... --Conditions are dynamic and available only the time of execution. After executing this statement i need to know colunmn_names and the values which returned from above query.
As far as i know * statement tells oracle that get all columns of that table from user_tab_columns table ordered by their column_id. So may achieve my goal like this;
DECLARE
   Key_Val_Arr IS TYPE OF VARCHAR2(50) INDEXED BY VARCHAR2;
   my_table_row_type xxx_table%rowtype; 
   SELECT * INTO my_table_row_type
     FROM xxx_table
  WHERE ......;
  For  rec IN  (SELECT column_name, column_id FROM user_tab_columns WHERE table_name = 'XXX_TABLE'  )
  LOOP
     Key_Val_Arr (rec.column_name ) = my_table_row_type(column_id); --Or something like that. Syntax may be incorrect, but please consider the idea
  END LOOP;
END;Any suggestions will help
Thanks in advance
Edited by: 991792 on Mar 5, 2013 3:44 AM

Answer 1

991792 wrote:
Hi,
I need to write a query that takes all the columns of a table and store them on a collection of column_name, Column_value.Why would you want to do that? That's not a good way to store data, and makes it a nightmare to access later.
The table name and the Where Clause may vary so i need to use dynamic sql.
My query will look like this;
SELECT *
FROM xxx_table
WHERE xx_column = ?? AND yy_Column = ?? .... --Conditions are dynamic and available only the time of execution.
After executing this statement i need to know colunmn_names and the values which returned from above query.
As far as i know * statement tells oracle that get all columns of that table from user_tab_columns table ordered by their column_id. So may achieve my goal like this;
DECLARE
Key_Val_Arr IS TYPE OF VARCHAR2(50) INDEXED BY VARCHAR2;
my_table_row_type xxx_table%rowtype;
SELECT * INTO my_table_row_type
FROM xxx_table
WHERE ......;
For rec IN (SELECT column_name, column_id FROM user_tab_columns WHERE table_name = 'XXX_TABLE' )
LOOP
Key_Val_Arr (rec.column_name ) = my_table_row_type(column_id); --Or something like that. Syntax may be incorrect, but please consider the idea
END LOOP;
END;Ok, you're right that you would need dynamic SQL for your dynamic conditions in your query, but if you also don't know the column names at design time, and it's important to find those out, then you'll need to get into the detail using the DBMS_SQL package. An example of using that, to take a query and output the columns and data as CSV (from my standard library of examples...)...
As sys user:
CREATE OR REPLACE DIRECTORY TEST_DIR AS '\tmp\myfiles'
GRANT READ, WRITE ON DIRECTORY TEST_DIR TO myuser
/As myuser:
CREATE OR REPLACE PROCEDURE run_query(p_sql IN VARCHAR2
                                     ,p_dir IN VARCHAR2
                                     ,p_header_file IN VARCHAR2
                                     ,p_data_file IN VARCHAR2 := NULL) IS
  v_finaltxt  VARCHAR2(4000);
  v_v_val     VARCHAR2(4000);
  v_n_val     NUMBER;
  v_d_val     DATE;
  v_ret       NUMBER;
  c           NUMBER;
  d           NUMBER;
  col_cnt     INTEGER;
  f           BOOLEAN;
  rec_tab     DBMS_SQL.DESC_TAB;
  col_num     NUMBER;
  v_fh        UTL_FILE.FILE_TYPE;
  v_samefile  BOOLEAN := (NVL(p_data_file,p_header_file) = p_header_file);
BEGIN
  c := DBMS_SQL.OPEN_CURSOR;
  DBMS_SQL.PARSE(c, p_sql, DBMS_SQL.NATIVE);
  d := DBMS_SQL.EXECUTE(c);
  DBMS_SQL.DESCRIBE_COLUMNS(c, col_cnt, rec_tab);
  FOR j in 1..col_cnt
  LOOP
    CASE rec_tab(j).col_type
      WHEN 1 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000);
      WHEN 2 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_n_val);
      WHEN 12 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_d_val);
    ELSE
      DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000);
    END CASE;
  END LOOP;
  -- This part outputs the HEADER
  v_fh := UTL_FILE.FOPEN(upper(p_dir),p_header_file,'w',32767);
  FOR j in 1..col_cnt
  LOOP
    v_finaltxt := ltrim(v_finaltxt||','||lower(rec_tab(j).col_name),',');
  END LOOP;
  --  DBMS_OUTPUT.PUT_LINE(v_finaltxt);
  UTL_FILE.PUT_LINE(v_fh, v_finaltxt);
  IF NOT v_samefile THEN
    UTL_FILE.FCLOSE(v_fh);
  END IF;
  -- This part outputs the DATA
  IF NOT v_samefile THEN
    v_fh := UTL_FILE.FOPEN(upper(p_dir),p_data_file,'w',32767);
  END IF;
  LOOP
    v_ret := DBMS_SQL.FETCH_ROWS(c);
    EXIT WHEN v_ret = 0;
    v_finaltxt := NULL;
    FOR j in 1..col_cnt
    LOOP
      CASE rec_tab(j).col_type
        WHEN 1 THEN DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
                    v_finaltxt := ltrim(v_finaltxt||',"'||v_v_val||'"',',');
        WHEN 2 THEN DBMS_SQL.COLUMN_VALUE(c,j,v_n_val);
                    v_finaltxt := ltrim(v_finaltxt||','||v_n_val,',');
        WHEN 12 THEN DBMS_SQL.COLUMN_VALUE(c,j,v_d_val);
                    v_finaltxt := ltrim(v_finaltxt||','||to_char(v_d_val,'DD/MM/YYYY HH24:MI:SS'),',');
      ELSE
        DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
        v_finaltxt := ltrim(v_finaltxt||',"'||v_v_val||'"',',');
      END CASE;
    END LOOP;
  --  DBMS_OUTPUT.PUT_LINE(v_finaltxt);
    UTL_FILE.PUT_LINE(v_fh, v_finaltxt);
  END LOOP;
  UTL_FILE.FCLOSE(v_fh);
  DBMS_SQL.CLOSE_CURSOR(c);
END;This allows for the header row and the data to be written to seperate files if required.
e.g.
SQL> exec run_query('select * from emp','TEST_DIR','output.txt');
PL/SQL procedure successfully completed.Output.txt file contains:
empno,ename,job,mgr,hiredate,sal,comm,deptno
7369,"SMITH","CLERK",7902,17/12/1980 00:00:00,800,,20
7499,"ALLEN","SALESMAN",7698,20/02/1981 00:00:00,1600,300,30
7521,"WARD","SALESMAN",7698,22/02/1981 00:00:00,1250,500,30
7566,"JONES","MANAGER",7839,02/04/1981 00:00:00,2975,,20
7654,"MARTIN","SALESMAN",7698,28/09/1981 00:00:00,1250,1400,30
7698,"BLAKE","MANAGER",7839,01/05/1981 00:00:00,2850,,30
7782,"CLARK","MANAGER",7839,09/06/1981 00:00:00,2450,,10
7788,"SCOTT","ANALYST",7566,19/04/1987 00:00:00,3000,,20
7839,"KING","PRESIDENT",,17/11/1981 00:00:00,5000,,10
7844,"TURNER","SALESMAN",7698,08/09/1981 00:00:00,1500,0,30
7876,"ADAMS","CLERK",7788,23/05/1987 00:00:00,1100,,20
7900,"JAMES","CLERK",7698,03/12/1981 00:00:00,950,,30
7902,"FORD","ANALYST",7566,03/12/1981 00:00:00,3000,,20
7934,"MILLER","CLERK",7782,23/01/1982 00:00:00,1300,,10The procedure allows for the header and data to go to seperate files if required. Just specifying the "header" filename will put the header and data in the one file.
Adapt to output different datatypes and styles are required.
As you can see, you can get details of the column names, datatypes and fetch the data explicitly by column position rather than name.