Had a problem about function which includes bitand, decode, etc..

Question

Hi everyone,
As I said at topic, I need some help on function. First of all, I will explain what kind of data I need to have. I had a table which has a column called FLAG1, this column gives me an information about a meter's situation. But this column only have numbers I need to look at it bit by bit. Here is my query;
create or replace
function FLAG1_CONTROL(F1 varchar2) return varchar2 is
result varchar2(250);
vF1 integer;
begin
vF1:= TO_NUMBER(F1, 'XX');
result:= '';
SELECT result|| DECODE(BITAND(vF1,1), 0, 'close,', 'open,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,2), 0, '', 'dafds,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,4), 0, '', 'jkf,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,8), 0, '', 'rewrw,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,16), 0, '', 'fdsfsa,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,32), 0, '', 'dfas,') into result from dual;
SELECT result|| DECODE(BITAND(vF1,64), 0, '', 'jjll,') into result from dual;
return(Result);
end FLAG1_CONTROL;
When I run this query, I had exception like
ORA-01422: exact fetch returns more than requested number of rows
ORA-06512: at "AKSAPROC.FLAG1_CONTROL", line 11
ORA-06512: at line 7
Process exited.
Can anyone help me about that topic?
Regards,
Edited by: sedcal on Aug 9, 2010 5:19 PM

Answer 1

Hi,
You're referencing a table called dualI that, apparantly, has more than 1 row:
SELECT result|| DECODE(BITAND(vF1,2), 0, '', 'dafds,') into result from dualI;If you use CASE (or IF ... THEN .. ELSE) instead of DECODE, you won't need SELECT INTO.
create or replace
function FLAG1_CONTROL     (F1     IN     varchar2)
return       varchar2
is
     vF1    integer          := TO_NUMBER (F1, 'XX');
begin
     RETURN  CASE WHEN BITAND (vF1,  1)  = 0 THEN 'close,'  ELSE 'open,'   END
     ||       CASE WHEN BITAND (vF1,  2) != 0 THEN 'dafds,'                  END
     ||       CASE WHEN BITAND (vF1,  4) != 0 THEN 'jkf,'                       END
     ||       CASE WHEN BITAND (vF1,  8) != 0 THEN 'rewrw,'                END
     ||       CASE WHEN BITAND (vF1, 16) != 0 THEN 'fdsfsa,'                END
     ||       CASE WHEN BITAND (vF1, 32) != 0 THEN 'dfas,'                END
     ||       CASE WHEN BITAND (vF1, 64) != 0 THEN 'jjll,'                END
end     FLAG1_CONTROL;
/Edited by: Frank Kulash on Aug 9, 2010 10:44 AM
Added code for SELECT-free function