Help needed with Image Events problem

Question

Hi there I'm writing what I thought was a simple script to convert a folder full of images from jpg to tiff. But the script fails when trying to convert the first image in the folder. Instead of converting the image, Preview opens with the image shown and I get this error message: error "The variable ImageRef is not defined." number -2753 from "ImageRef".
I have seen some posts about other people having the same problem, but I haven't seen any solutions.
Here's the script.
on run
tell application "Finder"
set PicturesFolder to ((path to home folder) as string) & "Pictures:SenseCam" as alias
set Photographs to (get entire contents of PicturesFolder) as alias list
end tell
tell application "Image Events"
launch
repeat with Photo in Photographs
if (Photo as string) ends with "jpg" then
set ImageRef to open Photo
save ImageRef in Photographs as TIFF
close ImageRef
end if
end repeat
end tell
tell application "Finder"
repeat with Photo in Photographs
delete Photo
end repeat
end tell
end run
Thanks in advance for any help.
John

Answer 1

Hello
You may try something like the modified code below.
Noticiable changes :
#1 - Removed the parentheses. Your original code won't yield alias list but a list of finder objects, which is the reason why Preview opens the image. (The statment 'open finderObject' behaves the same as double clicking it in Finder)
#2 - Only delete the original jpeg files which are converted to tiff.
#3 - Build new path for converted image.
#4 - Save in new path. (When saving image in a format other than its original format, always save the image to a new file and do not attempt to overwrite the source file.)
cf.
http://www.macosxautomation.com/applescript/imageevents/08.html
on run
tell application "Finder"
set PicturesFolder to (path to home folder as string) & "Pictures:SenseCam:" as alias
set Photographs to get entire contents of PicturesFolder as alias list -- #1
end tell
set DonePhotos to {} -- #2
tell application "Image Events"
launch
repeat with Photo in Photographs
set Photo to Photo's contents
set oldPath to Photo as string
if oldPath ends with ".jpg" then
set newPath to oldPath's text 1 thru -5 & ".tif" -- #3
set ImageRef to open Photo
save ImageRef as TIFF in newPath -- #4
close ImageRef
set end of DonePhotos to Photo -- #2
end if
end repeat
end tell
tell application "Finder"
delete DonePhotos -- #2
end tell
end run
Hope this may help,
H