How do I automatically add email addresses to the address book?

Question

I'm trying to work out a way to ensure incoming messages to Mail with a specific phrase in the subject line will have their email addresses automatically added to a specific group in my address book. Any ideas?

Answer 1

I have one that is close, so I have made a couple of changes and it MIGHT do the job. I recommend backing up your address book before trying. You will need to change the script at line 3 to use whatever group name you want. The script will most likely fail if the group does not exist. This version has had very limited testing, and in particular there is no error handling built in - I don't know how it will behave if the sender of the mail has not provided a two-part personal name.
Store the script in your (not the system) Library/Scripts/Applications/Mail and point your rule at it. You will also be able to use it by selecting messages in mail and using the Scripts menu.
AK
click here to open this script in your editor<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">using terms from application "Mail"
on perform mail action with messages theMessages
set GroupName to "Test"
tell application "Mail"
repeat with ThisOne in theMessages
set TheSender to (extract name from sender of ThisOne)
set TheAddress to (extract address from sender of ThisOne)
set FName to word 1 of TheSender
set SName to word 2 of TheSender
tell application "Address Book"
if not (person TheSender exists) then
set theGroup to group named GroupName
set NewABEntry to make new person with properties {first name:FName, last name:SName}
tell NewABEntry
make new email at beginning of emails with properties {label:"work", value:TheAddress}
end tell
add NewABEntry to theGroup
save addressbook
end if
end tell
end repeat
end tell
end perform mail action with messages
end using terms from
using terms from application "Mail"
on run
tell application "Mail" to set sel to selection
tell me to perform mail action with messages (sel)
end run
end using terms from
</pre>