How open files respectively in a directory ?

Question

HELLO
I got this code from this forum to open files and run a macro then close them in a directory . But this code doesn`t execute as I need. I want open files and run macro and close themو respectively . ٍٍEven I numbered files in a sequece but it doesn`t work.
Can anyone help in this issue !? 
Sub ProcessFolder()
' Path of the workbooks; must end in \
Const strFolder = "F:\NEW DATA with 4 sheets - Copy\"
Dim strFile As String
Dim wbk As Workbook
' Don't update the screen for efficiency
Application.ScreenUpdating = False
' Get first filename
strFile = Dir(strFolder & "*.xls*")
' Loop through the files
Do While strFile <> ""
' Open the workbook
Set wbk = Workbooks.Open(strFolder & strFile)
' Do something with the workbook
Call Macro1
' Close the workbook - use False if you don't want to save it
wbk.Close SaveChanges:=False
' Get the next filename
strFile = Dir
Loop
' Update the screen again
Application.ScreenUpdating = True
End Sub
THANKs
ABBAS

Answer 1

'Don't forget to end the path With the \ character:
Private Const csFolder = "C:\Temp\1\"
'Private Const sFolder = "F:\NEW DATA with 4 sheets - Copy\"
Private Sub pProcessFolder()
Dim sDir As String
Dim avFiles() As Variant
Dim vFile As Variant
Dim lFile As Long
Dim wb As Excel.Workbook
sDir = Dir(csFolder & "*")
Do While sDir <> ""
lFile = lFile + 1
ReDim Preserve avFiles(1 To lFile)
avFiles(lFile) = csFolder & sDir
sDir = Dir
Loop
pQuickSort avFiles
Application.ScreenUpdating = False
For Each vFile In avFiles
Set wb = Workbooks.Open(vFile)
Debug.Print wb.Name
Call Macro1
wb.Close SaveChanges:=False
Next vFile
Application.ScreenUpdating = True
End Sub
Sub Macro1()
End Sub
Private Function pQuickSort(vSort As Variant, _
Optional vLow As Variant, _
Optional vHigh As Variant) As Variant
'Ordena um vetor utilizando um algoritmo do tipo Quick Sort.
Dim vPivot As Variant
Dim vSwitch As Variant
Dim lLow As Long
Dim lHigh As Long
If IsMissing(vLow) Then vLow = LBound(vSort)
If IsMissing(vHigh) Then vHigh = UBound(vSort)
lLow = vLow
lHigh = vHigh
vPivot = pTransform(vSort((vLow + vHigh) \ 2))
Do While lLow <= lHigh
Do While pTransform(vSort(lLow)) < vPivot And lLow < vHigh
lLow = lLow + 1
Loop
Do While vPivot < pTransform(vSort(lHigh)) And lHigh > vLow
lHigh = lHigh - 1
Loop
If lLow <= lHigh Then
vSwitch = vSort(lLow)
vSort(lLow) = vSort(lHigh)
vSort(lHigh) = vSwitch
lLow = lLow + 1
lHigh = lHigh - 1
End If
Loop
If vLow < lHigh Then pQuickSort vSort, vLow, lHigh
If lLow < vHigh Then pQuickSort vSort, lLow, vHigh
End Function
Private Function pTransform(vItem As Variant) As Long
Dim aux As String
aux = vItem
aux = Mid(aux, Len(csFolder) + 1)
aux = Split(aux, "-")(0)
pTransform = aux
End Function
Felipe Costa Gualberto - http://www.ambienteoffice.com.br