How return parameter ref Cursor from procedure using dynamic SQL?

Question

I sorry, but i very need help.
I using Oracle 8.0.6
I need to return parameter of type ref Cursor from procedure.
create or replace package PlanExp is
type cursortype is ref cursor;
procedure ShowPlan (cursorparam out
cursortype.............);
end PlanExp;
create or replace package body PlanExp is
procedure ShowPlan (cursorparam out cursortype,
.............) Is
sql_str varchar2(1000);
sql_str_select varchar2(100);
sql_str_from varchar2(100);
sql_str_where varchar2(500);
Return_Code integer;
Num_Rows integer;
cur_id_sel integer;
tSum_Plan DBMS_SQL.NUMBER_TABLE;
tSum_Plan_Ch DBMS_SQL.NUMBER_TABLE;
tSum_Plan_Day DBMS_SQL.NUMBER_TABLE;
begin
/* calculating string variables ........... /*
sql_str := 'select ' || sql_str_select ||
'from ' || sql_str_from ||
'where ' || sql_str_where ||
'group by ' || sql_str_select;
cur_id_sel := dbms_sql.open_cursor;
dbms_sql.parse(cur_id_sel, sql_str, dbms_sql.native);
dbms_sql.define_array(cur_id_sel, 1, tSum_Plan, 20, 1);
dbms_sql.define_array(cur_id_sel, 2, tSum_Plan_Ch, 20, 1);
dbms_sql.define_array(cur_id_sel, 3, tSum_Plan_Day, 20, 1);
Return_Code := dbms_sql.execute(cur_id_sel);
delete from TEMP_SHOWPLAN;
Loop
Num_Rows := dbms_sql.Fetch_Rows(cur_id_sel);
dbms_sql.column_value(cur_id_sel, 1, tSum_Plan);
dbms_sql.column_value(cur_id_sel, 2, tSum_Plan_Ch);
dbms_sql.column_value(cur_id_sel, 3, tSum_Plan_Day);
if Num_Rows = 0 then
exit;
end if;
Exit When Num_Rows < 20;
End Loop;
dbms_sql.close_cursor(cur_id_sel);
end;
end PlanExp;
How return cursor (cursorparam) from 3 dbms_sql.column_value-s ?

Answer 1

I am using Oracle 8.1.7, so I don't know if this will work in
8.0.6 or not:
SQL> CREATE TABLE test
  2    (col1                    NUMBER,
  3     col2                    NUMBER,
  4     col3                    NUMBER)
  5  /
Table created.
SQL> INSERT INTO test
  2  VALUES (1,1,1)
  3  /
1 row created.
SQL> INSERT INTO test
  2  VALUES (2,2,2)
  3  /
1 row created.
SQL> INSERT INTO test
  2  VALUES (3,3,3)
  3  /
1 row created.
SQL> CREATE TABLE temp_showplan
  2    (tSum_Plan               NUMBER,
  3     tSum_Plan_Ch            NUMBER,
  4     tSum_Plan_Day           NUMBER)
  5  /
Table created.
SQL> EDIT planexp
CREATE OR REPLACE PACKAGE PlanExp
IS
  TYPE CursorType IS REF CURSOR;
  PROCEDURE ShowPlan
    (cursorparam    IN OUT CursorType,
     sql_str_select IN     VARCHAR2,
     sql_str_from   IN     VARCHAR2,
     sql_str_where  IN     VARCHAR2);
END PlanExp;
CREATE OR REPLACE PACKAGE BODY PlanExp
IS
  PROCEDURE ShowPlan
    (cursorparam    IN OUT CursorType,
     sql_str_select IN     VARCHAR2,
     sql_str_from   IN     VARCHAR2,
     sql_str_where  IN     VARCHAR2)
  IS
    sql_str                VARCHAR2 (1000);
    cur_id_sel             INTEGER;
    return_code            INTEGER;
  BEGIN
    DELETE FROM temp_showplan;
    sql_str := 'INSERT INTO   temp_showplan '
           || ' SELECT '   || sql_str_select
           || ' FROM '     || sql_str_from
           || ' WHERE '    || sql_str_where;
    cur_id_sel := DBMS_SQL.OPEN_CURSOR;
    DBMS_SQL.PARSE (cur_id_sel, sql_str, DBMS_SQL.NATIVE);
    return_code := DBMS_SQL.EXECUTE (cur_id_sel);
    DBMS_SQL.CLOSE_CURSOR (cur_id_sel);
    OPEN cursorparam FOR SELECT * FROM temp_showplan;
  END ShowPlan;
END PlanExp;
SQL> START planexp
Package created.
Package body created.
SQL> VARIABLE g_ref REFCURSOR
SQL> EXEC PlanExp.ShowPlan (:g_ref, 'col1, col2,
col3', 'test', ' 1 = 1 ')
PL/SQL procedure successfully completed.
SQL> PRINT g_ref
TSUM_PLAN TSUM_PLAN_CH TSUM_PLAN_DAY
         1            1             1
         2            2             2
         3            3             3