How to create simple equation automation

Question

Hello,
Is it possible to create a calculator automation? I have to do this same simple equation many times in the day and would love if there was an automation to make things faster. Any thoughts would be very apprecaited! 
(inputed number) divided by 1.074 = 
Thanks,
Anthony

Answer 1

Something like this?
property previous : {return, return, return} -- a list of previous equations
property theNumber : 0 -- the previous number
repeat -- forever
   set goodNumber to false
   repeat until goodNumber
      try
         set theNumber to text returned of (display dialog "Previous equations: " & return & (previous as text) & return & "Enter a number:" default answer theNumber as text) as number
         set theAnswer to theNumber / 1.074
         set goodNumber to true
      on error errmess number errnum -- not a number
         log errmess
         if errnum is -128 then error errmess number errnum -- user canceled, pass it on
      end try
   end repeat
   -- display dialog (theNumber as text) & " / 1.074 = " & theAnswer with title "The Answer" buttons {"OK"} default button 1 giving up after 2
   set end of previous to (tab & (theNumber as text) & " / 1.074 = " & theAnswer & return)
   if (count previous) > 3 then set previous to items -3 thru -1 of previous -- just the last 3
end repeat