How to define map of maps?

Question

Hello,
i want to do something like that in pl/sql:
TYPE map_type
   IS
      TABLE OF NUMBER
         INDEX BY VARCHAR2 (1);
   --    map: 1 -> 'a'
   --         2 -> 'b'
   --         11 -> 'A'
   --         22 -> 'B'
   TYPE map_of_map_type
   IS
      TABLE OF map_type%TYPE
         INDEX BY VARCHAR (15);
   --          map: 'onedigit' -> { {1 -> 'a'}, {2 -> 'b'} }
   --               'twodigit' -> { {11 -> 'A'}, {22 -> 'B'} } Is something like that possible?
Thanks!

Answer 1

And to illustrate how you work with two dimensional associative array:
SET SERVEROUTPUT ON FORMAT WRAPPED
DECLARE
    TYPE map_type
      IS
        TABLE OF NUMBER
          INDEX BY VARCHAR2(1);
    TYPE map_of_map_type
      IS
        TABLE OF map_type
          INDEX BY VARCHAR(15);
    v_map1 map_type;
    v_map2 map_type;
    v_map_of_maps map_of_map_type;
    v_idx1 varchar2(10);
    v_idx2 varchar2(1);
BEGIN
    v_map1('a') := 1;
    v_map1('b') := 2;
    v_map2('A') := 11;
    v_map2('B') := 22;
    v_map_of_maps('onedigit') := v_map1;
    v_map_of_maps('twodigit') := v_map2;
    v_idx1 := v_map_of_maps.FIRST;
    FOR i IN 1..v_map_of_maps.COUNT LOOP
      DBMS_OUTPUT.PUT_LINE('Map of maps: ' || v_idx1);
      v_idx2 := v_map_of_maps(v_idx1).FIRST;
      FOR j IN 1..v_map_of_maps(v_idx1).COUNT LOOP
        DBMS_OUTPUT.PUT_LINE('     Map: ' || v_idx2 || ' = ' || v_map_of_maps(v_idx1)(v_idx2));
        v_idx2 := v_map_of_maps(v_idx1).NEXT(v_idx2);
      END LOOP;
      v_idx1 := v_map_of_maps.NEXT(v_idx1);
    END LOOP;
END;
Map of maps: onedigit
     Map: a = 1
     Map: b = 2
Map of maps: twodigit
     Map: A = 11
     Map: B = 22
PL/SQL procedure successfully completed.
SQL> SY.