How to export several calendars simultaneously?

Question

How to export several calendars simultaneously? And I don't mean by grouping them into one group calendar.
I need it for operating iCalendar, and I do not have patience to do basically the same action seven times in a row. A group calendar is not a relevant solution either because I want to distinguish the individual calendars by their different colors.
Can you do it directly from the iCal Sources folder (the calendars carry crazy names)?
Can you do it by invoking the Terminal?
* This thread was first mistakenly (thanks Duane) posted in the Tiger session.

Answer 1

Hi Ken,
Here is a slightly more rigourously thought out version of this Applescript. It should not crash and gives some more feedback about what happened.
set theDestination to choose folder with prompt "Where do you want the files?"
set myPath to alias ((path to application support from user domain) & "iCal:Sources:" as string)
tell application "Finder"
activate
set myFolders to (folders of folder myPath)
set doneList to ""
repeat with myFolder in myFolders
set thePath to ((myFolder as alias) & "info.plist") as text
set theXML to read file thePath
repeat with myPara from 1 to count of paragraphs of theXML
if paragraph myPara of theXML contains "Title" then set theName to (characters 10 thru -10 of (paragraph (myPara + 1) of theXML) & ".ics") as string
end repeat
set name of file "corestorage.ics" of myFolder to theName
delay 0.5
try
duplicate file theName of myFolder to theDestination with replacing
set doneList to doneList & return & theName
on error theErr
display alert "File '" & theName & "' could not be copied." message theErr giving up after 30
end try
set name of file theName of myFolder to "corestorage.ics"
end repeat
display alert "iCal .ics file copy done." message "The following files were created in the folder:" & return & "'" & theDestination & "'" & return & doneList giving up after 30
end tell
Best wishes
John M