How to get the specified serarch term from the complete url? - Help

Question

Hello,
I have a table in which some columns. One of the column is storing the complete url for the search given by the user.
For Example:
1.
I give search like "oracle" on the Google, the column will store the complete url as
"http://www.google.com/search?hl=en&q=oracle".
I want the search word "oracle" to be returned from the column.
2.
I give search like "new + features + in + oracle + 10g", the column will store the url as
"http://www.google.com/search?hl=en&lr=&q=new+%2B+features+%2B+in+%2B+oracle+%2B+10g"
I want "new + features + in + oracle + 10g" search word to returned from the column.
Can anyone tell me how to achieve this task? I have tried for a long time also I tried the sys.utl_url.unescape() function, but could not got the desired result.
Please help, its really urgent!!!
Thanks in advance.

Answer 1

Hi,
you can have a look into this code:SET ESCAPE ON
DECLARE
        ref1 VARCHAR2(1000 CHAR) := 'http://www.google.com/search?hl=en\&q=oracle';
        ref2 VARCHAR2(1000 CHAR) := 'http://www.google.com/search?hl=en\&lr=\&q=new+%2B+features+%2B+in+%2B+oracle+%2B+10g';
        FUNCTION hextodec( h IN VARCHAR ) RETURN NUMBER
        AS
                h2 VARCHAR2( 150 );
                i NUMBER( 10 );
                j NUMBER( 2 );
                d NUMBER;
        BEGIN
                h2 := LTRIM( h, '0' );
                d := 0;
                FOR i IN 1 .. LENGTH( h2 )
                LOOP
                        SELECT DECODE( SUBSTR( h2, i, 1 )
                                , '0', 0, '1', 1, '2', 2, '3', 3, '4', 4, '5', 5
                                , '6', 6, '7', 7, '8', 8, '9', 9, 'A', 10
                                , 'B', 11, 'C', 12, 'D', 13, 'E', 14, 'F', 15 )
                                INTO j
                                FROM DUAL;
                        d := 16 * d + j;
                END LOOP;
                RETURN d;
        END hextodec;
        FUNCTION strip(samplevalue IN VARCHAR2) RETURN VARCHAR2
        AS
                finalvalue VARCHAR2(1000 CHAR) := samplevalue;
                decimalvalue NUMBER(2);
                pospct NUMBER;
                extract VARCHAR2(2 CHAR);
        BEGIN
                finalvalue := SUBSTR(finalvalue ,INSTR(finalvalue ,'\&q='));
                finalvalue := SUBSTR(finalvalue ,4);
                if (INSTR(finalvalue ,'\&')-1 > 0) then
                        finalvalue := SUBSTR(finalvalue ,1,INSTR(finalvalue ,'\&')-1);
                end if;
                finalvalue := REPLACE(finalvalue ,'+',' ');
                LOOP
                        pospct := INSTR(finalvalue ,'%');
                        EXIT WHEN pospct = 0;
                        extract := SUBSTR(finalvalue ,pospct+1,2);
                        finalvalue  := SUBSTR(finalvalue ,1,pospct-1) || chr(hextodec(extract)) || SUBSTR(finalvalue ,pospct+3);
                END LOOP;
                RETURN finalvalue;
        END;
BEGIN
        DBMS_OUTPUT.PUT_LINE( hextodec('2B'));
        DBMS_OUTPUT.PUT_LINE(strip(ref1));
        DBMS_OUTPUT.PUT_LINE(strip(ref2));
END;
/Regards,
Yoann.