How to not index characters combined with numbers?

Question

According to the Oracle Text Reference (10g or 11g) regarding a "stopclass", currently, only the NUMBERS class is supported and it is not possible to create a custom stopclass. So is there another way to not index text that contains characters combined with a number (such as "123ABC" or "ABC123")? If the text contains a number (anywhere in it) I don't want it indexed. Otherwise, I end up with a lot of junk representing 90% of my index and causes a maintenance pain...Essentially going from 300K rows in the index table to over 13 Million.

Answer 1

The only thing that I can think of is to use a user_datastore with a procedure that loops through each token in the row, eliminating those that have numbers. Please see the demonstration below.
SCOTT@orcl_11gR2> CREATE TABLE test_tab
  2    (test_col  VARCHAR2 (60))
  3  /
Table created.
SCOTT@orcl_11gR2> INSERT ALL
  2  INTO test_tab VALUES ('worda abc123 wordc')
  3  INTO test_tab VALUES ('worda 123abc wordc')
  4  INTO test_tab VALUES ('def456 wordb wordc')
  5  INTO test_tab VALUES ('worda wordb 789ghi')
  6  SELECT * FROM DUAL
  7  /
4 rows created.
SCOTT@orcl_11gR2> CREATE OR REPLACE PROCEDURE test_proc
  2    (p_rowid IN           ROWID,
  3       p_clob     IN OUT NOCOPY CLOB)
  4  AS
  5    v_clob            CLOB;
  6    v_token            VARCHAR2 (100);
  7  BEGIN
  8    SELECT test_col || ' '
  9    INTO   p_clob
10    FROM   test_tab
11    WHERE  ROWID = p_rowid;
12    WHILE INSTR (p_clob, '  ') > 0 LOOP
13        p_clob := REPLACE (p_clob, '  ', ' ');
14    END LOOP;
15    WHILE LENGTH (p_clob) > 1 LOOP
16        v_token := SUBSTR (p_clob, 1, INSTR (p_clob, ' '));
17        IF v_token = TRANSLATE (v_token, '1234567890', '        ') THEN
18          v_clob := v_clob || v_token;
19        END IF;
20        p_clob := LTRIM (SUBSTR (p_clob, INSTR (p_clob, ' ')));
21    END LOOP;
22    p_clob := v_clob;
23  END test_proc;
24  /
Procedure created.
SCOTT@orcl_11gR2> SHOW ERRORS
No errors.
SCOTT@orcl_11gR2> EXEC CTX_DDL.CREATE_PREFERENCE ('test_store', 'USER_DATASTORE')
PL/SQL procedure successfully completed.
SCOTT@orcl_11gR2> EXEC CTX_DDL.SET_ATTRIBUTE ('test_store', 'PROCEDURE', 'test_proc')
PL/SQL procedure successfully completed.
SCOTT@orcl_11gR2> CREATE INDEX test_idx
  2  ON test_tab (test_col)
  3  INDEXTYPE IS CTXSYS.CONTEXT
  4  PARAMETERS ('DATASTORE test_store')
  5  /
Index created.
SCOTT@orcl_11gR2> SELECT token_text FROM dr$test_idx$i
  2  /
TOKEN_TEXT
WORDA
WORDB
WORDC
3 rows selected.
SCOTT@orcl_11gR2>