How to pass several Filters via SAPBEXfireCommand/SAPBEXcopyFilterValue

Question

Via VBA, I need to pass several filter values to a query.
Thanks to peter Knoer, I found out how to clear and set single filter value, but things are bit more difficult to set multiple values. Anyone who could review the following code ,especially on bloc nr 3 which does not set the proper value list:
<i>Sub Filter_Value()
'1 Clear all the filter values on BYBAT query
Dim filterRng As Range
Dim myFilter As String
Set filterRng = Range("SAPBEXqueries!SAPBEXq0001fZTB_PRCTR")
Run "SAPBEX.xla!SAPBEXsetFilterValue", "", "", filterRng
'2 set Single filter on Profit Center for BYBAT worksheet
'Sheets("BYBAT").Activate
'myFilter = "BCNF001"
'Application.Goto Reference:= _
'Range("SAPBEXqueries!SAPBEXq0001fZTB_PRCTR").Cells(1)
'Set myRange = Selection
'ReturnValue = Run("SAPBEX.XLA!SAPBEXSetFilterValue", myFilter, "", myRange)
' 2 set Multiple filters on Profit Center for BYBAT worksheet
Dim myRange As Range
Dim filterRng1 As Range, filterRng2 As Range
Set myRange = Sheets("Filters").Range("A1:B10") 'list containing Profit center key and name in result table
retVal = Run("SAPBEX.xla!SAPBEXfireCommand", "SELM", myRange) '"Keep filter value" for Profit center
Set filterRng1 = myRange
Set filterRng2 = Range("SAPBEXqueries!SAPBEXq0001fZTB_PRCTR")
retVal = Run("SAPBEX.xla!SAPBEXcopyFilterValue", filterRng1, filterRng2)
End Sub</i>
Thanks for your insights!

Answer 1

Hi Bernard,
OK.  First, a warning ... at some time in the future, a BW upgrade (or even a patch) could make this stop working.  I have not heard of any problems through BW3.5; but, some folks now using BW7.0 are finding that writing directly to SAPBEXfilters worksheet is not working for them.
Here are the steps:
1.  To work with the SAPBEXfilters worksheet, you must know three things:  the local query ID for the query you want to work with (something like "SAPBEXq0001"); which row number in Column "F" of the worksheet "SAPBEXqueries" this local query ID is found; and, the technical name of the characteristic for which you will set the filters
2.  Set a single filter value using SAPBEXsetFilterValue; the value you use is not important since you will delete it in a later step; this step will remove any old filter values and will also remove the characteristic from the drill-down; so, if including the characteristic in the drill-down is important, you will need to re-set the drill state
3. locate the filter value created in step 2 and make "n" copies of it
4.  paste the "n" filter values you want in place of the "n" copies
5. delete the filter value from step 2
From your earlier posting, I assume you know how to do steps 1 & 2.
Step 3 is no more than looking in column EZ of SAPBEXfilters to find the query row number; then, when you find a match, looking in column FF for the technical name of the characteristic the filter is set on.  Here is sample code for that:
    'locate the unique filter ID (fUID)
    'look in table starting in column EZ on sheet SAPBEXfilters
    fUID = ""
    With repoFilters
        numFilters = .Range("EZ2")
        For i = numFilters + 3 To 4 Step -1
            'entry in column EZ should match query row number
            If .Range("EZ" & i) = qRow Then
                'entry in column FF should match technical name of characteristic
                If .Range("FF" & i) = techName Then
                    'we found our match
                    'read the unique filter ID (fUID)
                    fUID = .Range("FA" & i)
                    'exit this loop
                    Exit For
                End If
            End If
        Next i
    End With
    'did we find anything?
    If fUID = "" Then GoTo leave
In the code above (and below), the "CodeName" of the worksheet "SAPBEXfilters" is "repoFilters".
Here is code for steps 3, 4, and 5:
    'locate this unique filter ID in the filter table, which
    'begins in column GX on sheet SAPBEXfilters
    Set rng = Nothing
    With repoFilters
        numFilters = .Range("GX2")
        numColumns = .Range("GX3")
        For i = numFilters + 3 To 4 Step -1
            'entry in column GX should match query row number
            If .Range("GX" & i) = qRow Then
                'entry in column GY should match unique filter ID (uFID)
                If .Range("GY" & i) = fUID Then
                    'we found a match
                    Set rng = Range(.Range("GX" & i), .Cells(i, .Range("GX2").Column + numColumns))
                    'copy to end of list
                    rng.Copy Destination:=Range(.Cells(numFilters + 4, .Range("GX2").Column), _
                        .Cells(numFilters + 3 + numList, .Range("GX2").Column + numColumns))
                    'replace filters with filter list
                    Range("FilterList").Copy Destination:=.Range("HH" & numFilters + 4)
                    'delete the original
                    rng.Delete Shift:=xlUp
                    setFiltersFromList = True
                    Exit For
                End If
            End If
        Next i
    End With
Hope this helps.
- Pete